LGMD with 3D morphology and active dendrites (Dewell & Gabbiani 2018)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:195666
This is a model of the locust LGMD looming sensitive neuron from Dewell & Gabbiani 2018. The morphology was constructed based on 2-photon imaging, and active conductances throughout the neuron were based on sharp electrode recordings in vivo.
Reference:
1 . Dewell RB, Gabbiani F (2018) Biophysics of object segmentation in a collision-detecting neuron. Elife [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Locust Lobula Giant Movement Detector (LGMD) neuron;
Channel(s): I M; I h; Ca pump; I K,Ca; I T low threshold; I_KD;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Active Dendrites; Synaptic Integration; Spatio-temporal Activity Patterns; Vision;
Implementer(s): Dewell, Richard Burkett [dewell at bcm.edu]; Gabbiani, F;
Search NeuronDB for information about:  I T low threshold; I M; I h; I K,Ca; I_KD; Ca pump;
TITLE NaP channel from RBD

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(S) = (siemens)
}

NEURON {
    THREADSAFE
    : note - every variable accessible in NEURON will be having the suffix _NaP

        SUFFIX NaP
        USEION na READ ena WRITE ina
        RANGE gmax,g
        GLOBAL tnmax,tlmax
}

PARAMETER {
: all values can be adjusted in hoc files
	gmax=0.001 (mho/cm2)
	vhalfn=-51	(mV)
	vhalfl=-58	(mV)
	zn=8.5		(mV)
	zl=-4.4   	(mV)
	vn2=-52		(mV)
	vl2=-55		(mV)
	
	tlmax=400	(ms)
	tlmin=0.5	(ms)
	tls=6.5		(mV)
	tnmax=20	(ms)
	tnmin=3		(ms)
	tns=-8.5	(mV)
}

STATE {
        n
        l
}

ASSIGNED {
    v (mV)
    ena (mV)

	ina (mA/cm2)
	ninf3
	linf      
	taul (ms)
	taun (ms)
	g (S/cm2)
}

BREAKPOINT {
	SOLVE states METHOD cnexp
	g = gmax*n*l
	ina = g*(v-ena)
}

INITIAL {
	rates(v)
	n=ninf3
	l=linf
}


FUNCTION alpn(v(mV)) {
  alpn = exp((vhalfn-v)/zn)
}

FUNCTION betn(v(mV)) {
  betn = exp((vn2-v)/tns) 
}

FUNCTION alpl(v(mV)) {
  alpl = exp((vhalfl-v)/zl)
}

DERIVATIVE states {  
	rates(v)
	n' = (ninf3 - n)/taun
	l' = (linf - l)/taul
}

PROCEDURE rates(v (mV)) { :callable from hoc
	LOCAL a, ninf
	TABLE ninf3, taun, linf, taul DEPEND tlmax, tnmax
		FROM -100 TO 50 WITH 1500

	a = alpn(v)
	ninf = 1/(1 + a)
	ninf3=ninf^3
	taun = 4*tnmax/(1+betn(v))*ninf+tnmin
	a = alpl(v)
	linf = (1/(1+ a))
	taul = 2*tlmax/(1+exp((vl2-v)/tls))*linf + tlmin
}


Loading data, please wait...