CA1 pyramidal neuron: as a 2-layer NN and subthreshold synaptic summation (Poirazi et al 2003)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:20212
We developed a CA1 pyramidal cell model calibrated with a broad spectrum of in vitro data. Using simultaneous dendritic and somatic recordings, and combining results for two different response measures (peak vs. mean EPSP), two different stimulus formats (single shock vs. 50 Hz trains), and two different spatial integration conditions (within vs. between-branch summation), we found the cell's subthreshold responses to paired inputs are best described as a sum of nonlinear subunit responses, where the subunits correspond to different dendritic branches. In addition to suggesting a new type of experiment and providing testable predictions, our model shows how conclusions regarding synaptic arithmetic can be influenced by an array of seemingly innocuous experimental design choices.
References:
1 . Poirazi P, Brannon T, Mel BW (2003) Arithmetic of subthreshold synaptic summation in a model CA1 pyramidal cell. Neuron 37:977-87 [PubMed]
2 . Poirazi P, Brannon T, Mel BW (2003) Pyramidal neuron as two-layer neural network. Neuron 37:989-99 [PubMed]
3 . Poirazi P, Brannon T, Mel BW (2003ab-sup) Online Supplement: About the Model Neuron 37 Online:1-20
4 . Polsky A, Mel BW, Schiller J (2004) Computational subunits in thin dendrites of pyramidal cells. Nat Neurosci 7:621-7 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Hippocampus CA1 pyramidal GLU cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I T low threshold; I A; I K; I M; I h; I K,Ca; I Calcium;
Gap Junctions:
Receptor(s): GabaA; GabaB; NMDA; Glutamate;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Activity Patterns; Dendritic Action Potentials; Active Dendrites; Influence of Dendritic Geometry; Detailed Neuronal Models; Action Potentials; Depression; Delay;
Implementer(s): Poirazi, Panayiota [poirazi at imbb.forth.gr];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; GabaA; GabaB; NMDA; Glutamate; I Na,p; I Na,t; I L high threshold; I T low threshold; I A; I K; I M; I h; I K,Ca; I Calcium;
/
CA1_multi
mechanism
not-currently-used
abbott.mod
abbott_nmda.mod
borgkm.mod
ca.mod
cachan.mod
cacum.mod
cad_trunk.mod
cad3.mod
cadecay.mod *
cadifusl.mod
cagk.mod
cal.mod
calH.mod
can2.mod
canKev.mod
capump.mod
cat.mod
h.mod
hh3.mod
hh3_flei.mod
hha.mod
ht.mod
ican.mod
iq.mod
it.mod
it1.mod
ITGHK.mod *
kad.mod *
kap.mod *
kc.mod
kca.mod
kdr.mod
kdr_inac.mod
kdrca1.mod
kv.mod *
My_cal.mod
My_can.mod
My_cat.mod
my_kca.mod
Myca.mod
Mykca.mod
na.mod *
na3.mod
namir.mod
nax.mod
ourca_old.mod
vkca.mod
abbott.o
abbott_nmda.c
h.pl
ITGHK.o
mod_func.c
test.hoc
test2.hoc
testh.hoc
VClamp.omod *
                            
TITLE transient and low threshold calcium current (T-current)

COMMENT
        *********************************************
        reference:      Huguenard & McCormick (1992) 
                        J.Neurophysiology 68(4), 1373-1383
        found in:       thalamic relay neurons
        *********************************************
        Assembled for MyFirstNEURON by Arthur Houweling
ENDCOMMENT

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
        SUFFIX cat
        USEION ca READ cai,cao
        USEION Ca WRITE iCa VALENCE 2
        : The T-current does not activate calcium-dependent currents.
        : The construction with dummy ion Ca prevents the updating of the 
        : internal calcium concentration. 
        RANGE pcabar, m_inf, h_inf, tau_m, tau_h, iCa
}

UNITS {
        (mA)    = (milliamp)
        (mV)    = (millivolt)
        (mM)    = (milli/liter)
        FARADAY = 96480 (coul/mol)
        R       = 8.314 (volt-coul/degC)
}

PARAMETER {
        v               (mV)
        celsius         (degC)
        dt              (ms)
        cai = 5.e-05     (mM)
        cao = 2         (mM)
: maximum permiability!!! 
        pcabar= 0.0001  (cm/s)          
}

STATE {
        m h
}

ASSIGNED {
        iCa             (mA/cm2)
        tau_m           (ms)
        tau_h           (ms)
        m_inf 
        h_inf
        tadjm
        tadjh
}

BREAKPOINT { 
        SOLVE state :METHOD euler
        iCa = pcabar * m*m*h * ghk(v,cai,cao,2)
}

:DERIVATIVE state {
:       rates(v)
:   
:       m'= (m_inf-m) / tau_m
:       h'= (h_inf-h) / tau_h
:}
 
PROCEDURE state() {
        rates(v)

        m= m + (1-exp(-dt/tau_m))*(m_inf-m)
        h= h + (1-exp(-dt/tau_h))*(h_inf-h)
}

UNITSOFF
INITIAL {
        tadjm= 3.55^((celsius-23.5)/10)
        tadjh= 2.8^((celsius-23.5)/10)
        rates(v)
        m = m_inf
        h = h_inf
:        iCa = pcabar * m*m*h * ghk(v,cai,cao,2)
}

FUNCTION ghk( v(mV), ci(mM), co(mM), z)  (millicoul/cm3) { LOCAL e, w
        w = v * (.001) * z*FARADAY / (R*(celsius+273.16))
        if (fabs(w)>1e-4) 
          { e = w / (exp(w)-1) }
        else : denominator is small -> Taylor series
          { e = 1-w/2 }
        ghk = - (.001) * z*FARADAY * (co-ci*exp(w)) * e
}
UNITSOFF

PROCEDURE rates(v(mV)) { 
        tau_m = (1/(exp((v+131.6)/-16.7)+exp((v+16.8)/18.2)) + 0.612) / tadjm 
:        m_inf = 1 / (1+exp((v+60.5)/-6.2))
        m_inf = 1 / (1+exp((v+32)/-7.0))
        if (v<-80) 
          { tau_h = exp((v+467)/66.6) / tadjh }
        else  
          { tau_h = (exp((v+21.88)/-10.52)+28) / tadjh }
:        h_inf = 1 / (1+exp((v+84)/4.03)) 
         h_inf = 1 / (1+exp((v+67)/6.5)) 
}

UNITSON







Loading data, please wait...