Cerebellum granule cell FHF (Dover et al. 2016)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:206267
"Neurons in vertebrate central nervous systems initiate and conduct sodium action potentials in distinct subcellular compartments that differ architecturally and electrically. Here, we report several unanticipated passive and active properties of the cerebellar granule cell's unmyelinated axon. Whereas spike initiation at the axon initial segment relies on sodium channel (Nav)-associated fibroblast growth factor homologous factor (FHF) proteins to delay Nav inactivation, distal axonal Navs show little FHF association or FHF requirement for high-frequency transmission, velocity and waveforms of conducting action potentials. ...'
Reference:
1 . Dover K, Marra C, Solinas S, Popovic M, Subramaniyam S, Zecevic D, D'Angelo E, Goldfarb M (2016) FHF-independent conduction of action potentials along the leak-resistant cerebellar granule cell axon. Nat Commun 7:12895 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Axon; Dendrite;
Brain Region(s)/Organism: Cerebellum;
Cell Type(s): Cerebellum interneuron granule GLU cell;
Channel(s): I A; I Calcium; I K; I K,Ca; I M; I Na,p; I Na,t; I Potassium; I Sodium; Kir;
Gap Junctions:
Receptor(s): AMPA; Gaba; NMDA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s):
Implementer(s): Solinas, Sergio [solinas at unipv.it]; Subramaniyam, Sathyaa [sakthisathyaa at gmail.com]; D'Angelo, Egidio [dangelo at unipv.it]; Goldfarb, Mitchell goldfarb at genectr.hunter.cuny.edu];
Search NeuronDB for information about:  Cerebellum interneuron granule GLU cell; AMPA; NMDA; Gaba; I Na,p; I Na,t; I A; I K; I M; I K,Ca; I Sodium; I Calcium; I Potassium; Kir;
/
GrC_FHF_ModelDB
images
README.html
AmpaCOD.mod
GRC_CA.mod *
GRC_CALC.mod *
GRC_GABA.mod *
GRC_KA.mod *
GRC_KCA.mod *
GRC_KIR.mod *
GRC_KM.mod
GRC_KV.mod *
GRC_LKG1.mod *
GRC_LKG2.mod *
GRC_LKG3.mod
GRC_NA.mod
Grc_sine.mod
NmdaS.mod
Pregen.mod *
CClamp_soma.ses
ComPanel.hoc
Fig5.ses
Grc_Cell.hoc
helper_procedures.hoc
Ina.ses
KOFHF.DAPF.slowalfabeta.REV5.30.2016.ses
modComPanel.hoc
mosinit.hoc
Parametri.hoc
Start.hoc
WTFHF.DAPF.slowalfabeta.REV5.30.2016.ses
                            
TITLE AMPACOD  

COMMENT
	Modello AMPA dell'articolo (versione 15 settembre 2004).
	Adattato per approx il deterministico
ENDCOMMENT

NEURON {
	POINT_PROCESS AmpaCOD	
	NONSPECIFIC_CURRENT i	
	RANGE r1FIX,r2,r3,r4,r5,r1,r6,r6FIX
	RANGE g,gmax,kB,Cdur,Erev 
	RANGE gg1,gg2,gg3,Tdiff
	RANGE T,Tmax,Trelease 	
	RANGE tau_1,tau_rec,tau_facil,U,u0	
	RANGE A1,A2,A3,tau_dec1,tau_dec2,tau_dec3		: comes from fit 
	RANGE tdelay,ton	 
}

UNITS {
	(nA) = (nanoamp)
	(mV) = (millivolt)	
	(mM) = (milli/liter)
	(pS) = (picosiemens)
	(nS) = (nanosiemens)
	(um) = (micrometer)
	PI   = (pi)(1)
}

PARAMETER {
	: Parametri Postsinaptici
	r1FIX		= 5.4		(/ms/mM) 	 
	r2		= 0.82		(/ms)		 
	r3		= 0		(/ms)		 
	r4		= 0		(/ms)		 
	r5		= 0.013		(/ms)		
	r6FIX		= 1.12		(/ms/mM)	
	gmax		= 700 		(nS)		 
	Cdur		= 0.3		(ms)		 
	Erev		= 0		(mV)
	kB		= 0.44		(mM)
		
	: Diffusion: M=21500, R=1.033, D=0.223, lamd=0.02			
	A1 			= 0.131837 
	A2			= 0.0555027	 
	A3 			= 0.0135232	 
	tau_dec1 		= 3.4958	 
	tau_dec2 		= 16.6317	 
	tau_dec3 		= 128.983	

	: Parametri Presinaptici
	tau_1 		= 3 (ms) 	< 1e-9, 1e9 >
	tau_rec 	= 35.1 (ms) 	< 1e-9, 1e9 > 	
	tau_facil 	= 10.8 (ms) 	< 0, 1e9 > 	

	U 		= 0.416 (1) 	< 0, 1 >
	u0 		= 0 (1) 	< 0, 1 >	: se u0=0 al primo colpo y=U
	Tmax		= 1  (mM)
}


ASSIGNED {
	v		(mV)		: postsynaptic voltage
	i 		(nA)		: current = g*(v - Erev)
	g 		(pS)		: conductance
	r1		(/ms)
	r6		(/ms)
	T		(mM)
	Trelease	(mM)
	Tdiff		(mM)
	tdelay		(ms)
	Tdiff_0		(mM)
	ton		(ms)	
	
	x
	PRE
}

STATE {	
	C
	O
	D
	gg1
	gg2
	gg3
	sink
}	
	

INITIAL {
	C		=	1
	O		=	0
	D		=	0
	T		=	0 	(mM)
	Tdiff		=	0	(mM)
	Trelease	=	0 	(mM)
	Tdiff_0		=	0	(mM)
	gg1		=	0
	gg2		=	0
	gg3		=	0   
	ton		=  	-1   (ms)
	PRE		=	0
}

FUNCTION SET_tdelay(R,D){ tdelay=0.25*R*R/D } 

BREAKPOINT {
	if( (t-ton)>tdelay  ){
		Tdiff=gg1+gg2+gg3
		Tdiff_0 = Tdiff
	}else{
		Tdiff=Tdiff_0+(A1+A2+A3)*PRE*(t-ton)/tdelay
	}
	Trelease=T+Tdiff
	SOLVE kstates METHOD sparse
	g =gmax * O
	i = (1e-6) * g * (v - Erev) 
}


KINETIC kstates {
	: Postsynaptic scheme
	r1 = r1FIX * Trelease^2 / (Trelease + kB)^2
	r6 = r6FIX * Trelease^2 / (Trelease + kB)^2
	~ C  <-> O	(r1,r2)
	~ O  <-> D	(r3,r4)
	~ D  <-> C	(r5,r6)
	CONSERVE C+O+D = 1
	: Glutamate diffusion wave
	~ gg1 <-> sink (1/tau_dec1,0)
	~ gg2 <-> sink (1/tau_dec2,0)
	~ gg3 <-> sink (1/tau_dec3,0)
}


NET_RECEIVE(weight, on, nspike, flagtdel,t0 (ms),y, z, u, tsyn (ms)) {
	INITIAL {
		flagtdel=1
		nspike = 1
		Tdiff=0
		y=0
		z=0
		u=u0
		tsyn=t
	}
   	if (flag == 0) { 
		nspike = nspike + 1
		if (!on) {
			ton=t
			t0=t
			on=1				
			z=z*exp(-(t-tsyn)/tau_rec)
			z=z+(y*(exp(-(t - tsyn)/tau_1)-exp(-(t-tsyn)/tau_rec))/(tau_1/tau_rec-1))
			y=y*exp(-(t-tsyn)/tau_1)			
			x=1-y-z
			if(tau_facil>0){ 
				u=u*exp(-(t-tsyn)/tau_facil)
				u=u+U*(1-u)							
			}else{u=U}
			y=y+x*u
			PRE=y
			T=Tmax*y
			tsyn=t						
		}
		net_send(Cdur,nspike)
		net_send(tdelay,flagtdel)						
    	}
	if(flag==nspike){ 		
		T = 0
		on = 0
	}
	if (flag == flagtdel){
		flagtdel = flagtdel+1
		state_discontinuity(gg1,gg1+A1*x*u)	 
		state_discontinuity(gg2,gg2+A2*x*u)	 
		state_discontinuity(gg3,gg3+A3*x*u)	 
	}
}	 

 

Loading data, please wait...