A detailed Purkinje cell model (Masoli et al 2015)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:229585
The Purkinje cell is one of the most complex type of neuron in the central nervous system and is well known for its massive dendritic tree. The initiation of the action potential was theorized to be due to the high calcium channels presence in the dendritic tree but, in the last years, this idea was revised. In fact, the Axon Initial Segment, the first section of the axon was seen to be critical for the spontaneous generation of action potentials. The model reproduces the behaviours linked to the presence of this fundamental sections and the interplay with the other parts of the neuron.
Reference:
1 . Masoli S, Solinas S, D'Angelo E (2015) Action potential processing in a detailed Purkinje cell model reveals a critical role for axonal compartmentalization. Front Cell Neurosci 9:47 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Axon;
Brain Region(s)/Organism: Cerebellum;
Cell Type(s): Cerebellum Purkinje GABA cell;
Channel(s): I Sodium; I Calcium; I Na,t; I K;
Gap Junctions:
Receptor(s):
Gene(s): Cav2.1 CACNA1A; Cav3.1 CACNA1G; Cav3.2 CACNA1H; Cav3.3 CACNA1I; Nav1.6 SCN8A; Kv1.1 KCNA1; Kv1.5 KCNA5; Kv3.3 KCNC3; Kv3.4 KCNC4; Kv4.3 KCND3; KCa1.1 KCNMA1; KCa2.2 KCNN2; KCa3.1 KCNN4; Kir2.1 KCNJ2; HCN1;
Transmitter(s):
Simulation Environment: NEURON; Python;
Model Concept(s): Bursting; Detailed Neuronal Models; Action Potentials; Action Potential Initiation; Axonal Action Potentials;
Implementer(s): Masoli, Stefano [stefano.masoli at unipv.it]; Solinas, Sergio [solinas at unipv.it];
Search NeuronDB for information about:  Cerebellum Purkinje GABA cell; I Na,t; I K; I Sodium; I Calcium;
: HH TEA-sensitive Purkinje potassium current
: Created 8/5/02 - nwg

: Suffix from kpkj to Kv3_4

NEURON {
	SUFFIX Kv3_4
	USEION k READ ek WRITE ik
	RANGE gkbar, ik
	RANGE minf, hinf, mtau, htau
}

UNITS {
	(mV) = (millivolt)
	(mA) = (milliamp)
}

CONSTANT {
	q10 = 3
}

PARAMETER {
	v (mV)

	gkbar = .004	(mho/cm2)

	mivh = -24	(mV)
	mik = 15.4	(1)
	mty0 = .00012851 	
	mtvh1 = 100.7	(mV)
	mtk1 = 12.9	(1)
	mtvh2 = -56.0	(mV)
	mtk2 = -23.1	(1)
	
	hiy0 = .31	
	hiA = .69
	hivh = -5.802	(mV)
	hik = 11.2	(1)

	ek
}

ASSIGNED {
	ik		(mA/cm2)
	minf
	mtau		(ms)
	hinf
	htau		(ms)
        qt
}

STATE {
	m
	h
}

INITIAL {
	rates(v)
	m = minf
	h = hinf

	qt = q10^((celsius-37 (degC))/10 (degC))
}

BREAKPOINT {
	SOLVE states METHOD cnexp
	ik = gkbar * m^3 * h * (v - ek)
}

DERIVATIVE states {
	rates(v)
	m' = (minf - m) / mtau
	h' = (hinf - h) / htau
}

PROCEDURE rates( Vm (mV)) {
	LOCAL v
	v = Vm + 11	: Account for Junction Potential
	minf = 1/(1+exp(-(v-mivh)/mik)) 
	mtau = (1000) * mtau_func(v) /qt
	hinf = hiy0 + hiA/(1+exp((v-hivh)/hik))
	htau = 1000 * htau_func(v) / qt
}

FUNCTION mtau_func (v (mV)) (ms) {
	if (v < -35) {
		mtau_func = (3.4225e-5+.00498*exp(-v/-28.29))*3
	} else {
		mtau_func = (mty0 + 1/(exp((v+mtvh1)/mtk1)+exp((v+mtvh2)/mtk2)))
	}
}

FUNCTION htau_func(Vm (mV)) (ms) {
	if ( Vm > 0) {
		htau_func = .0012+.0023*exp(-.141*Vm)
	} else {
		htau_func = 1.2202e-05 + .012 * exp(-((Vm-(-56.3))/49.6)^2)
	}
}
	

Loading data, please wait...