L5 PFC pyramidal neurons (Papoutsi et al. 2017)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:230811
" ... Here, we use a modeling approach to investigate whether and how the morphology of the basal tree mediates the functional output of neurons. We implemented 57 basal tree morphologies of layer 5 prefrontal pyramidal neurons of the rat and identified morphological types which were characterized by different response features, forming distinct functional types. These types were robust to a wide range of manipulations (distribution of active ionic mechanisms, NMDA conductance, somatic and apical tree morphology or the number of activated synapses) and supported different temporal coding schemes at both the single neuron and the microcircuit level. We predict that the basal tree morphological diversity among neurons of the same class mediates their segregation into distinct functional pathways. ..."
Reference:
1 . Papoutsi A, Kastellakis G, Poirazi P (2017) Basal tree complexity shapes functional pathways in the prefrontal cortex. J Neurophysiol 118:1970-1983 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Prefrontal cortex (PFC);
Cell Type(s): Neocortex L5/6 pyramidal GLU cell;
Channel(s): I A; I h; I L high threshold; I T low threshold; I N; I R; I K,Ca; I_AHP; I_Ks; I Na,p; I Na,t; I K;
Gap Junctions:
Receptor(s): AMPA; NMDA; GabaA; GabaB;
Gene(s):
Transmitter(s): Glutamate; Gaba;
Simulation Environment: NEURON;
Model Concept(s): Active Dendrites; Detailed Neuronal Models;
Implementer(s): Papoutsi, Athanasia [athpapoutsi at gmail.com];
Search NeuronDB for information about:  Neocortex L5/6 pyramidal GLU cell; GabaA; GabaB; AMPA; NMDA; I Na,p; I Na,t; I L high threshold; I N; I T low threshold; I A; I K; I h; I K,Ca; I_Ks; I R; I_AHP; Gaba; Glutamate;
/
PapoutsiEtAl2017
mod_files
ampa.mod
ampain.mod
cad.mod
cal.mod
can.mod *
car.mod *
cat.mod *
gabaa.mod *
gabaain.mod
gabab.mod *
h.mod
iks_in.mod
kadist.mod *
kca.mod *
kct.mod *
kd.mod
kdr_in.mod
kdrD.mod *
naf.mod
naf_in.mod
nap.mod *
NMDA.mod
NMDA_syn.mod
vecstim.mod
                            
TITLE simple NMDA receptors

COMMENT
-----------------------------------------------------------------------------

Essentially the same as /examples/nrniv/netcon/ampa.mod in the NEURON
distribution - i.e. Alain Destexhe's simple AMPA model - but with
different binding and unbinding rates and with a magnesium block.
Modified by Andrew Davison, The Babraham Institute, May 2000


	Simple model for glutamate AMPA receptors
	=========================================

  - FIRST-ORDER KINETICS, FIT TO WHOLE-CELL RECORDINGS

    Whole-cell recorded postsynaptic currents mediated by AMPA/Kainate
    receptors (Xiang et al., J. Neurophysiol. 71: 2552-2556, 1994) were used
    to estimate the parameters of the present model; the fit was performed
    using a simplex algorithm (see Destexhe et al., J. Computational Neurosci.
    1: 195-230, 1994).

  - SHORT PULSES OF TRANSMITTER (0.3 ms, 0.5 mM)

    The simplified model was obtained from a detailed synaptic model that 
    included the release of transmitter in adjacent terminals, its lateral 
    diffusion and uptake, and its binding on postsynaptic receptors (Destexhe
    and Sejnowski, 1995).  Short pulses of transmitter with first-order
    kinetics were found to be the best fast alternative to represent the more
    detailed models.

  - ANALYTIC EXPRESSION

    The first-order model can be solved analytically, leading to a very fast
    mechanism for simulating synapses, since no differential equation must be
    solved (see references below).



References

   Destexhe, A., Mainen, Z.F. and Sejnowski, T.J.  An efficient method for
   computing synaptic conductances based on a kinetic model of receptor binding
   Neural Computation 6: 10-14, 1994.  

   Destexhe, A., Mainen, Z.F. and Sejnowski, T.J. Synthesis of models for
   excitable membranes, synaptic transmission and neuromodulation using a 
   common kinetic formalism, Journal of Computational Neuroscience 1: 
   195-230, 1994.

Kiki Sidiropoulou
Adjusted Cdur and Beta for better nmda spikes

-----------------------------------------------------------------------------
ENDCOMMENT



NEURON {
	POINT_PROCESS NMDA
	RANGE g, Alpha, Beta, e, gmax, ica
	USEION ca WRITE ica
	NONSPECIFIC_CURRENT  iNMDA            
	GLOBAL Cdur, mg, Cmax
}
UNITS {
	(nA) = (nanoamp)
	(mV) = (millivolt)
	(umho) = (micromho)
	(mM) = (milli/liter)
}

PARAMETER {
	Cmax	= 1	 (mM)           : max transmitter concentration
	Cdur	= 1	 (ms)		: transmitter duration (rising phase) (1) :increase by kiki 5/2/08
:	Cdur	= 20	 (ms)		: transmitter duration (rising phase) :Nassi
:	Alpha	= 10	 (/ms /mM)	: forward (binding) rate
	Alpha	= 4	 (/ms /mM)	: forward (binding) rate (4)
	Beta	= 0.015 (/ms)		: backward (unbinding) rate THIS IS VALIDATED
:	Beta	=0.03	(/ms)		: kiki, july2008, nmda was too slow, used until March 2010
:	e	= 45	 (mV)		: reversal potential
	e	= 0	 (mV)		: reversal potential
        mg      = 1      (mM)           : external magnesium concentration

}


ASSIGNED {
	v		(mV)		: postsynaptic voltage
	iNMDA 		(nA)		: current = g*(v - e)
	g 		(umho)		: conductance
	Rinf				: steady state channels open
	Rtau		(ms)		: time constant of channel binding
	synon
        B 
	gmax                              : magnesium block
	ica
}

STATE {Ron Roff}

INITIAL {
	Rinf = Cmax*Alpha / (Cmax*Alpha + Beta)
	Rtau = 1 / (Cmax*Alpha + Beta)
	synon = 0
}

BREAKPOINT {
	SOLVE release METHOD cnexp
        B = mgblock(v)
	g = (Ron + Roff)*1(umho) * B
	iNMDA = g*(v - e)
        ica = 7*iNMDA/10   :(5-10 times more permeable to Ca++ than Na+ or K+, Ascher and Nowak, 1988)
:       ica = 0
        iNMDA = 3*iNMDA/10

}

DERIVATIVE release {
	Ron' = (synon*Rinf - Ron)/Rtau
	Roff' = -Beta*Roff
}

FUNCTION mgblock(v(mV)) {
        TABLE 
        DEPEND mg
        FROM -140 TO 80 WITH 1000

        : from Jahr & Stevens

      
	 mgblock = 1 / (1 + exp(0.072 (/mV) * -v) * (mg / 3.57 (mM)))  :was 0.062, changed to 0.072 to get a better voltage-dependence of NMDA currents, july 2008, kiki
	
}

: following supports both saturation from single input and
: summation from multiple inputs
: if spike occurs during CDur then new off time is t + CDur
: ie. transmitter concatenates but does not summate
: Note: automatic initialization of all reference args to 0 except first

			
NET_RECEIVE(weight, on, nspike, r0, t0 (ms)) {
	: flag is an implicit argument of NET_RECEIVE and  normally 0
        if (flag == 0) { : a spike, so turn on if not already in a Cdur pulse
		nspike = nspike + 1
		if (!on) {
			r0 = r0*exp(-Beta*(t - t0))
			t0 = t
			on = 1
			synon = synon + weight
			state_discontinuity(Ron, Ron + r0)
			state_discontinuity(Roff, Roff - r0)
		}
:		 come again in Cdur with flag = current value of nspike
		net_send(Cdur, nspike)
       }
	if (flag == nspike) { : if this associated with last spike then turn off
		r0 = weight*Rinf + (r0 - weight*Rinf)*exp(-(t - t0)/Rtau)
		t0 = t
		synon = synon - weight
		state_discontinuity(Ron, Ron - r0)
		state_discontinuity(Roff, Roff + r0)
		on = 0
	}
gmax = weight
}



Loading data, please wait...