2D model of olfactory bulb gamma oscillations (Li and Cleland 2017)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:232097
This is a biophysical model of the olfactory bulb (OB) that contains three types of neurons: mitral cells, granule cells and periglomerular cells. The model is used to study the cellular and synaptic mechanisms of OB gamma oscillations. We concluded that OB gamma oscillations can be best modeled by the coupled oscillator architecture termed pyramidal resonance inhibition network gamma (PRING).
Reference:
1 . Li G, Cleland TA (2017) A coupled-oscillator model of olfactory bulb gamma oscillations. PLoS Comput Biol 13:e1005760 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism:
Cell Type(s): Olfactory bulb main mitral cell; Olfactory bulb main interneuron granule MC cell; Olfactory bulb main interneuron periglomerular cell;
Channel(s):
Gap Junctions:
Receptor(s): AMPA; NMDA; GabaA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Olfaction;
Implementer(s): Li, Guoshi [guoshi_li at med.unc.edu];
Search NeuronDB for information about:  Olfactory bulb main mitral cell; Olfactory bulb main interneuron periglomerular cell; Olfactory bulb main interneuron granule MC cell; GabaA; AMPA; NMDA;
/
OBGAMMA
celldata
connection
data0
input
README
cadecay.mod *
cadecay2.mod *
Caint.mod *
Can.mod *
CaPN.mod *
CaT.mod *
GradeAMPA.mod *
GradeGABA.mod *
GradNMDA.mod *
hpg.mod *
kAmt.mod *
KCa.mod *
KDRmt.mod *
kfasttab.mod *
kM.mod *
KS.mod
kslowtab.mod *
LCa.mod *
nafast.mod *
NaP.mod *
Naxn.mod *
Nicotin.mod *
nmdanet.mod *
OdorInput.mod *
SineInput.mod
Background.hoc
Cal_Synch.hoc
Connect.hoc
Figure.hoc
GC_def.hoc
GC_save.hoc *
GC_Stim.hoc
Input.hoc
mathslib.hoc
MC_def.hoc
MC_save.hoc
MC_Stim.hoc
mosinit.hoc
OBNet.hoc
Parameter.hoc
PG_def.hoc
PG_save.hoc *
PG_Stim.hoc
SaveData.hoc
tabchannels.dat *
tabchannels.hoc
                            
COMMENT
-----------------------------------------------------------------------------

hpg.mod	
Mechanism for hyperpolarization-activated cation channel ("H-channel")

Based on a mechanism written by Cadetti & Belluzzi (2001) for H-current
in rat olfactory bulb juxtaglomerular cells (i.e., primarily periglomerular
and external tufted cells), as described in:
  
	Cadetti L, Belluzzi O (2001) Hyperpolarisation-activated current in
	glomerular cells of the rat olfactory bulb.  Neuroreport 12(14):3117-20.

Slightly modified for redistribution by

	Thomas A. Cleland (tac29@cornell.edu) and Praveen Sethupathy
	Cornell University
	Summer 2003, January 2004

-----------------------------------------------------------------------------
ENDCOMMENT

TITLE I-h channel for juxtaglomerular cells 

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
}

PARAMETER {
	v 			(mV)
  	eh  			(mV)        
	celsius 		(degC)
	ghbar  = 5e-05 	(mho/cm2)
      vhalft=-65   	(mV)
      a0t=0.00085      	(/ms)
      zetat=0.085    	(1)
      gmt=.5   		(1)
	q10=4.5
}

NEURON {
	SUFFIX hpg
	NONSPECIFIC_CURRENT i
      RANGE ghbar, eh, g
      GLOBAL linf,taul
}

STATE { l }

ASSIGNED {
	i (mA/cm2)
      linf      
      taul
	g
}

INITIAL {
	rate(v)
	l=linf
	g=10
}

BREAKPOINT {
	SOLVE states METHOD cnexp
	g = ghbar*l
	i = g*(v-eh)
}

FUNCTION alpt(v(mV)) {
  	alpt = exp(zetat*(v-vhalft)) 
}

FUNCTION bett(v(mV)) {
  	bett = exp(zetat*gmt*(v-vhalft)) 
}

DERIVATIVE states {     : exact when v held constant; integrates over dt step
      rate(v)
      l' =  (linf - l)/taul
}

PROCEDURE rate(v (mV)) { :callable from hoc
      LOCAL qt
      qt=q10^((celsius-30)/10)
      linf = 1/(1+ exp((v+80)/10))
      taul = bett(v)/(qt*a0t*(1+alpt(v)))
}















Loading data, please wait...