SCZ-associated variant effects on L5 pyr cell NN activity and delta osc. (Maki-Marttunen et al 2018)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:237469
" … Here, using computational modeling, we show that a common biomarker of schizophrenia, namely, an increase in delta-oscillation power, may be a direct consequence of altered expression or kinetics of voltage-gated ion channels or calcium transporters. Our model of a circuit of layer V pyramidal cells highlights multiple types of schizophrenia-related variants that contribute to altered dynamics in the delta frequency band. Moreover, our model predicts that the same membrane mechanisms that increase the layer V pyramidal cell network gain and response to delta-frequency oscillations may also cause a decit in a single-cell correlate of the prepulse inhibition, which is a behavioral biomarker highly associated with schizophrenia."
Reference:
1 . Mäki-Marttunen T, Krull F, Bettella F, Hagen E, Næss S, Ness TV, Moberget T, Elvsåshagen T, Metzner C, Devor A, Edwards AG, Fyhn M, Djurovic S, Dale AM, Andreassen OA, Einevoll GT (2019) Alterations in Schizophrenia-Associated Genes Can Lead to Increased Power in Delta Oscillations. Cereb Cortex 29:875-891 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Neocortex;
Cell Type(s): Neocortex L5/6 pyramidal GLU cell;
Channel(s): Ca pump; I A, slow; I h; I K; I K,Ca; I K,leak; I L high threshold; I M; I Na,p; I Na,t; I T low threshold;
Gap Junctions: Gap junctions;
Receptor(s): AMPA; NMDA; Gaba;
Gene(s): Cav1.2 CACNA1C; Cav1.3 CACNA1D; Cav3.3 CACNA1I; HCN1; Kv2.1 KCNB1; Nav1.1 SCN1A; PMCA ATP2B2;
Transmitter(s): Glutamate; Gaba;
Simulation Environment: NEURON; Python; LFPy;
Model Concept(s): Schizophrenia; Oscillations;
Implementer(s): Maki-Marttunen, Tuomo [tuomo.maki-marttunen at tut.fi];
Search NeuronDB for information about:  Neocortex L5/6 pyramidal GLU cell; AMPA; NMDA; Gaba; I Na,p; I Na,t; I L high threshold; I T low threshold; I K; I K,leak; I M; I h; I K,Ca; I A, slow; Ca pump; Gaba; Glutamate;
/
scznet
haymod
models
morphologies
README.html
Ca_HVA.mod *
Ca_LVAst.mod *
CaDynamics_E2.mod *
epsp.mod *
Ih.mod *
Im.mod *
K_Pst.mod *
K_Tst.mod *
Nap_Et2.mod *
NaTa_t.mod *
SK_E2.mod *
SKv3_1.mod *
calcifcurves.py
calcifcurves_comb.py
collectppispthrcoeff300_relthr.py
collectscalings_cs.py
collectthresholddistalamps300.py
copydata.sh
drawppiranges.py
drawsubthppiamps_comb.py
findsubthppi300_relthr.py
findsubthppi300_relthr_comb_one.py
findthresholddistalamp300_control.py
findthresholddistalamps300.py
findthresholddistalamps300_comb.py
mutation_stuff.py *
mutation_stuff.pyc
mutindexlist.sav
mytools.py *
mytools.pyc
ppi300_relthr_comb_recordSK.py
presaved.tar.gz
runcontrol.py
savesynapselocations300.py
scalemutations_cs.py
testsubthppi300_comb_fixed.py
                            
:Comment : The persistent component of the K current
:Reference : :		Voltage-gated K+ channels in layer 5 neocortical pyramidal neurones from young rats:subtypes and gradients,Korngreen and Sakmann, J. Physiology, 2000
:Comment : shifted -10 mv to correct for junction potential
:Comment: corrected rates using q10 = 2.3, target temperature 34, orginal 21


NEURON	{
	SUFFIX K_Pst
	USEION k READ ek WRITE ik
	RANGE gK_Pstbar, gK_Pst, ik, offm, slom, offmt, slomt, taummin, taumdiff1, taumdiff2, offh, sloh, offht1, offht2, sloht, tauhmean, tauhdiff1, tauhdiff2
}

UNITS	{
	(S) = (siemens)
	(mV) = (millivolt)
	(mA) = (milliamp)
}

PARAMETER	{
	gK_Pstbar = 0.00001 (S/cm2)
	offm = -11 (mV)
	slom = 12 (mV)
	offmt = -10 (mV)
	slomt = 38.46153846 (mV)
	taummin = 1.25 (ms)
        taumdiff1 = 175.03 (ms)
        taumdiff2 = 13 (ms)
	offh = -64 (mV)
	sloh = 11 (mV)
	offht1 = -65 (mV)
	offht2 = -85 (mV)
	sloht = 48 (mV)
	tauhmean = 360 (ms)
	tauhdiff1 = 1010 (ms)
        tauhdiff2 = 24 (ms/mV)

}

ASSIGNED	{
	v	(mV)
	ek	(mV)
	ik	(mA/cm2)
	gK_Pst	(S/cm2)
	mInf
	mTau
	hInf
	hTau
}

STATE	{
	m
	h
}

BREAKPOINT	{
	SOLVE states METHOD cnexp
	gK_Pst = gK_Pstbar*m*m*h
	ik = gK_Pst*(v-ek)
}

DERIVATIVE states	{
	rates()
	m' = (mInf-m)/mTau
	h' = (hInf-h)/hTau
}

INITIAL{
	rates()
	m = mInf
	h = hInf
}

PROCEDURE rates(){
  LOCAL qt, thresh
  qt = 2.3^((34-21)/10)
  thresh = offmt-slomt/2*log(taumdiff1/taumdiff2)
	UNITSOFF
		mInf =  (1/(1 + exp((offm-v)/slom)))
                if(v<thresh){
		    mTau =  (taummin+taumdiff1*exp(-(offmt-v)/slomt))/qt
                } else {
                    mTau = ((taummin+taumdiff2*exp((offmt-v)/slomt)))/qt
                }
		hInf =  1/(1 + exp(-(offh-v)/sloh))
		hTau =  (tauhmean+(tauhdiff1-tauhdiff2*(offht1-v))*exp(-((offht2-v)/sloht)^2))/qt
	UNITSON
}

Loading data, please wait...