Olfactory Mitral Cell (Davison et al 2000)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:2487
A four-compartment model of a mammalian olfactory bulb mitral cell, reduced from the complex 286-compartment model described by Bhalla and Bower (1993). The compartments are soma/axon, secondary dendrites, primary dendrite shaft and primary dendrite tuft. The reduced model runs 75 or more times faster than the full model, making its use in large, realistic network models of the olfactory bulb practical.
Reference:
1 . Davison AP, Feng J, Brown D (2000) A reduced compartmental model of the mitral cell for use in network models of the olfactory bulb. Brain Res Bull 51:393-9 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Olfactory bulb main mitral GLU cell;
Channel(s): I Na,t; I L high threshold; I A; I K; I K,leak; I K,Ca; I Sodium; I Calcium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Parameter Fitting; Simplified Models; Olfaction;
Implementer(s): Davison, Andrew [Andrew.Davison at iaf.cnrs-gif.fr];
Search NeuronDB for information about:  Olfactory bulb main mitral GLU cell; I Na,t; I L high threshold; I A; I K; I K,leak; I K,Ca; I Sodium; I Calcium; I Potassium;
/
mit4
README.html
cadecay.mod *
kA.mod *
kca3.mod
kfasttab.mod
kslowtab.mod *
lcafixed.mod *
nafast.mod *
abstract.hoc
kfast_k.inf *
kfast_k.tau *
kfast_n.inf *
kfast_n.tau *
kslow_k.inf *
kslow_k.tau *
kslow_n.inf *
kslow_n.tau *
mit2_gi_0p2.dat
mit2_gi_1p6.dat
mit2_si_0p2.dat
mit2_si_1p6.dat
mit4.hoc
mit4.ses
mit4_init.hoc
mosinit.hoc
screenshot.jpg
tabchannels.hoc
                            
TITLE Calcium dependent potassium channel
: KCa channel with parameters from US Bhalla and JM Bower,
: J. Neurophysiol. 69:1948-1983 (1993)
: Adapted from /usr/local/neuron/demo/release/nachan.mod - squid
: by Andrew Davison, The Babraham Institute.
: 24-08-98

NEURON {
	SUFFIX kca3
	USEION k READ ek WRITE ik
	USEION ca READ cai
	RANGE gkbar, ik, Yconcdep, Yvdep
	GLOBAL Yalpha, Ybeta
}

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(molar) = (1/liter)
	(mM) = (millimolar)
}

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

PARAMETER {
	v (mV)
	dt (ms)
	gkbar= 0.120 (mho/cm2) <0,1e9>
	ek = -80 (mV)
	Ybeta = 0.05 (/ms)
	cai (mM) := 1e-5 (mM)
}


STATE {
	Y
}

ASSIGNED {
	ik (mA/cm2)
	Yalpha   (/ms)
	Yvdep    
	Yconcdep (/ms)
}

INITIAL {
	rate(v,cai)
	Y = Yalpha/(Yalpha + Ybeta)
}

BREAKPOINT {
	SOLVE state METHOD cnexp
	ik = gkbar*Y*(v - ek)
}

DERIVATIVE state {
	rate(v,cai)
	Y' = Yalpha*(1-Y) - Ybeta*Y
}

PROCEDURE rate(v(mV),cai(mM)) {
	vdep(v)
	concdep(cai)
	Yalpha = Yvdep*Yconcdep
}

PROCEDURE vdep(v(mV)) {
	TABLE Yvdep FROM -100 TO 100 WITH 100
	Yvdep = exp((v*1(/mV)+70)/27)
}

PROCEDURE concdep(cai(mM)) {
	TABLE Yconcdep FROM 0 TO 0.01 WITH 1000
	if (cai < 0.01) {
		Yconcdep = 500(/ms)*( 0.015-cai*1(/mM) )/( exp((0.015-cai*1(/mM))/0.0013) -1 )
	} else {
		Yconcdep = 500(/ms)*0.005/( exp(0.005/0.0013) -1 )
	}
}

Loading data, please wait...