The APP in C-terminal domain alters CA1 neuron firing (Pousinha et al 2019)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:256388
"The amyloid precursor protein (APP) is central to AD pathogenesis and we recently showed that its intracellular domain (AICD) could modify synaptic signal integration. We now hypothezise that AICD modifies neuron firing activity, thus contributing to the disruption of memory processes. Using cellular, electrophysiological and behavioural techniques, we showed that pathological AICD levels weakens CA1 neuron firing activity through a gene transcription-dependent mechanism. Furthermore, increased AICD production in hippocampal neurons modifies oscillatory activity, specifically in the gamma frequency range, and disrupts spatial memory task. Collectively, our data suggest that AICD pathological levels, observed in AD mouse models and in human patients, might contribute to progressive neuron homeostatic failure, driving the shift from normal ageing to AD."
Reference:
1 . Pousinha PA, Mouska X, Bianchi D, Temido-Ferreira M, Rajão-Saraiva J, Gomes R, Fernandez SP, Salgueiro-Pereira AR, Gandin C, Raymond EF, Barik J, Goutagny R, Bethus I, Lopes LV, Migliore M, Marie H (2019) The Amyloid Precursor Protein C-Terminal Domain Alters CA1 Neuron Firing, Modifying Hippocampus Oscillations and Impairing Spatial Memory Encoding. Cell Rep 29:317-331.e5 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Hippocampus CA1 pyramidal GLU cell;
Channel(s): I Na,t; I A; I K; I M; I h; I L high threshold; I_AHP;
Gap Junctions:
Receptor(s): NMDA;
Gene(s):
Transmitter(s): Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Aging/Alzheimer`s; Oscillations; Action Potentials; Memory;
Implementer(s): Bianchi, Daniela [danielabianchi12 -at- gmail.com];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; NMDA; I Na,t; I L high threshold; I A; I K; I M; I h; I_AHP; Glutamate;
/
PousinhaMouskaBianchiEtAl2019
readme.txt
ANsyn.mod *
bgka.mod *
burststim2.mod *
cad.mod *
cagk.mod
cal.mod *
calH.mod *
car.mod *
cat.mod *
ccanl.mod *
d3.mod *
gskch.mod *
h.mod *
IA.mod
ichan2.mod *
Ih.mod *
kadist.mod *
kaprox.mod *
Kaxon.mod *
kca.mod *
Kdend.mod *
kdr.mod *
kdrax.mod *
km.mod *
Ksoma.mod *
LcaMig.mod *
my_exp2syn.mod *
na3.mod *
na3dend.mod *
na3notrunk.mod *
Naaxon.mod *
Nadend.mod *
nap.mod *
Nasoma.mod *
nax.mod *
nca.mod *
nmdanet.mod *
regn_stim.mod *
somacar.mod *
STDPE2Syn2.mod *
mosinit.hoc
pyramidal_cell4b.hoc
ranstream.hoc *
ses.ses
stim_cell.hoc *
testcell.hoc
                            
TITLE T-calcium channel



UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(molar) = (1/liter)
	(mM) = (millimolar)

	FARADAY = 96520 (coul)
	R = 8.3134 (joule/degC)
	KTOMV = .0853 (mV/degC)
}



NEURON {
	SUFFIX cat
	USEION ca READ cai,cao 
        USEION Ca WRITE iCa VALENCE 2
        : The T-current does not activate calcium-dependent currents.
        : The construction with dummy ion Ca prevents the updating of the 
        : internal calcium concentration. 
        RANGE gcatbar, hinf, minf, taum, tauh, iCa
}

PARAMETER {
	v (mV)
	
      tBase = 23.5  (degC)
	celsius = 22  (degC)
	gcatbar = 0   (mho/cm2)  : initialized conductance
	ki = 0.001    (mM)
	cai = 5.e-5   (mM)       : initial internal Ca++ concentration
	cao = 2       (mM)       : initial external Ca++ concentration
       tfa = 1                  : activation time constant scaling factor
       : tfi = 0.68 
        tfi = 0.68               : inactivation time constant scaling factor
        eca = 140                : Ca++ reversal potential

}


STATE {
	m h 
}

ASSIGNED {
      iCa (mA/cm2)
      gcat (mho/cm2)
	hinf
	tauh
	minf
	taum
}

INITIAL {
	rates(v)
	m = minf
	h = hinf
     gcat = gcatbar*m*m*h*h2(cai)

}

BREAKPOINT {
	SOLVE states METHOD cnexp
	gcat = gcatbar*m*m*h*h2(cai)
	iCa = gcat*ghk(v,cai,cao)

}

DERIVATIVE states {	: exact when v held constant
	rates(v)
	m' = (minf - m)/taum
	h' = (hinf - h)/tauh
}


UNITSOFF
FUNCTION h2(cai(mM)) {
	h2 = ki/(ki+cai)
}

FUNCTION ghk(v(mV), ci(mM), co(mM)) (mV) {
        LOCAL nu,f

        f = KTF(celsius)/2
        nu = v/f
        ghk=-f*(1. - (ci/co)*exp(nu))*efun(nu)
}

FUNCTION KTF(celsius (DegC)) (mV) {
        KTF = ((25./293.15)*(celsius + 273.15))
}


FUNCTION efun(z) {
	if (fabs(z) < 1e-4) {
		efun = 1 - z/2
	}else{
		efun = z/(exp(z) - 1)
	}
}


FUNCTION alph(v(mV)) {
	TABLE FROM -150 TO 150 WITH 200
	alph = 1.6e-4*exp(-(v+57)/19)
}

FUNCTION beth(v(mV)) {
        TABLE FROM -150 TO 150 WITH 200
	:beth = 1/(exp((-v+15)/10)+1.0)
      beth = 1/(exp((-v+15)/10)+1.0)
}

FUNCTION alpm(v(mV)) {
	TABLE FROM -150 TO 150 WITH 200
	alpm = 0.1967*(-1.0*v+19.88)/(exp((-1.0*v+19.88)/10.0)-1.0)
}

FUNCTION betm(v(mV)) {
	TABLE FROM -150 TO 150 WITH 200
	betm = 0.046*exp(-v/22.73)
}


PROCEDURE rates(v (mV)) { :callable from hoc
        LOCAL a
        a = alpm(v)
        taum = 1/(tfa*(a + betm(v))) : estimation of activation tau
        minf =  a/(a+betm(v))        : estimation of activation steady state
        a = alph(v)
        tauh = 1/(tfi*(a + beth(v))) : estimation of inactivation tau
        hinf = a/(a+beth(v))         : estimation of inactivation steady state
        
}

Loading data, please wait...