Olfactory Mitral Cell (Bhalla, Bower 1993)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:2733
This is a conversion to NEURON of the mitral cell model described in Bhalla and Bower (1993). The original model was written in GENESIS and is available by joining BABEL, the GENESIS users' group here http://www.genesis-sim.org/GENESIS/babel.html
Reference:
1 . Bhalla US, Bower JM (1993) Exploring parameter space in detailed single neuron models: simulations of the mitral and granule cells of the olfactory bulb. J Neurophysiol 69:1948-65 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Olfactory bulb main mitral GLU cell;
Channel(s): I Na,t; I L high threshold; I A; I K; I K,leak; I K,Ca; I Sodium; I Calcium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Parameter Fitting; Influence of Dendritic Geometry; Detailed Neuronal Models; Olfaction;
Implementer(s): Davison, Andrew [Andrew.Davison at iaf.cnrs-gif.fr];
Search NeuronDB for information about:  Olfactory bulb main mitral GLU cell; I Na,t; I L high threshold; I A; I K; I K,leak; I K,Ca; I Sodium; I Calcium; I Potassium;
/
bbmit
README
cadecay.mod *
kA.mod *
kca3.mod *
kfasttab.mod
kslowtab.mod *
lcafixed.mod *
nafast.mod *
fig5a.dat
kfast_k.inf *
kfast_k.tau *
kfast_n.inf *
kfast_n.tau *
kslow_k.inf *
kslow_k.tau *
kslow_n.inf *
kslow_n.tau *
mit_init.hoc
mit_memb.hoc
mit_morph.hoc
mit_param.hoc
mitral.connect
mitral.ses
mitral.xyzd
mosinit.hoc
                            
TITLE Calcium dependent potassium channel
: KCa channel with parameters from US Bhalla and JM Bower,
: J. Neurophysiol. 69:1948-1983 (1993)
: Adapted from /usr/local/neuron/demo/release/nachan.mod - squid
: by Andrew Davison, The Babraham Institute.
: 24-08-98

NEURON {
	SUFFIX kca3
	USEION k READ ek WRITE ik
	USEION ca READ cai
	RANGE gkbar, ik, Yconcdep, Yvdep
	GLOBAL Yalpha, Ybeta, vshift
}

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(molar) = (1/liter)
	(mM) = (millimolar)
}

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

PARAMETER {
	v (mV)
	dt (ms)
	gkbar= 0.120 (mho/cm2) <0,1e9>
	ek = -70 (mV)
	Ybeta = 0.05 (/ms)
	cai (mM) := 1e-5 (mM)
	vshift = -10 (mV)
}


STATE {
	Y
}

ASSIGNED {
	ik (mA/cm2)
	Yalpha   (/ms)
	Yvdep    
	Yconcdep (/ms)
}

INITIAL {
	rate(v,cai)
	Y = Yalpha/(Yalpha + Ybeta)
}

BREAKPOINT {
	SOLVE state METHOD cnexp
	ik = gkbar*Y*(v - (ek+vshift))
}

DERIVATIVE state {
	rate(v,cai)
	Y' = Yalpha*(1-Y) - Ybeta*Y
}

PROCEDURE rate(v(mV),cai(mM)) {
	vdep(v)
	concdep(cai)
	Yalpha = Yvdep*Yconcdep
}

PROCEDURE vdep(v(mV)) {
	TABLE Yvdep FROM -100 TO 100 WITH 100
	Yvdep = exp((v*1(/mV)+70)/27)
}

PROCEDURE concdep(cai(mM)) {
	TABLE Yconcdep FROM 0 TO 0.01 WITH 1000
	if (cai < 0.01) {
		Yconcdep = 500(/ms)*( 0.015-cai*1(/mM) )/( exp((0.015-cai*1(/mM))/0.0013) -1 )
	} else {
		Yconcdep = 500(/ms)*0.005/( exp(0.005/0.0013) -1 )
	}
}

Loading data, please wait...