MNTB Neuron: Kv3.1 currents (Wang et al 1998)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:3454
Model of Medial Nucleus of the Trapezoid Body (MNTB) neurons described in Lu-Yang Wang, Li Gan, Ian D. Forsythe and Leonard K. Kaczmarek. Contribution of the Kv3.1 potassium channel to high-frequency firing in mouse auditory neurones. J. Physiol (1998) 509.1 183-194. Created by David Kornfeld, Byram Hills High School, Armonk NY. Please email dbk1@mindspring.com for questions about the model. See Readme.txt below for more info.
Reference:
1 . Wang LY, Gan L, Forsythe ID, Kaczmarek LK (1998) Contribution of the Kv3.1 potassium channel to high-frequency firing in mouse auditory neurones. J Physiol 509 ( Pt 1):183-94 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Medial Nucleus of the Trapezoid Body (MNTB) neuron;
Channel(s): I Na,t; I K; I Sodium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s):
Implementer(s): Kornfeld, David [dbk1 at mindspring.com];
Search NeuronDB for information about:  I Na,t; I K; I Sodium; I Potassium;
: 	Low threshold potassium chanel from 
:	Contribution of the Kv3.1 potassium channel to high-frequency firing in mouse auditory neurones
:	Lu-Yang Wang, Li Gan, Ian D. Forsythe and Leonard K. Kaczmarek
:	J. Physiol (1998), 501.9, pp. 183-194

NEURON {
	SUFFIX LT
	USEION k READ ek WRITE ik
	RANGE gbar, g, ik
	GLOBAL linf, ltau, rinf, rtau, al, bl, ar, br
}

: area in paper is 1000 (um2) so divide our density parameters by 10

UNITS {
	(mV) = (millivolt)
	(S) = (mho)
	(mA) = (milliamp)
}

PARAMETER {
	gbar = .002 (S/cm2) : .02 (uS)
	gamma = .1

	kal = 1.2 (/ms)
	eal = .03512 (/mV)
	kbl = .2248 (/ms)
	ebl = -.0319 (/mV)

	kar = .0438 (/ms)
	ear = -.0053 (/mV)
	kbr = .0562 (/ms)
	ebr = -.0047 (/mV)
}

ASSIGNED {
	v (mV)
	ek (mV)
	ik (mA/cm2)

	linf
	ltau (ms)
	rinf
	rtau (ms)

	al (/ms)
	bl (/ms)
	ar (/ms)
	br (/ms)
}

STATE {
	l r
}

INITIAL {
	rates(v)
	l = linf
	r = rinf
}

BREAKPOINT {
	SOLVE state METHOD cnexp
	ik = gbar*l*r*(v - ek) : pemdas may be a problem
}

DERIVATIVE state {
	rates(v)
	l' = (linf - l)/ltau
	r' = (rinf - r)/rtau
}

PROCEDURE rates(v(mV)) {
	al = kal*exp(eal*v)
	bl = kbl*exp(ebl*v)

	ar = kar*exp(ear*v)
	br = kbr*exp(ebr*v)

	linf = al/(al + bl)
	ltau = 1/(al + bl)
	rinf = ar/(ar + br)
	rtau = 1/(ar + br)
}


Loading data, please wait...