MNTB Neuron: Kv3.1 currents (Wang et al 1998)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:3454
Model of Medial Nucleus of the Trapezoid Body (MNTB) neurons described in Lu-Yang Wang, Li Gan, Ian D. Forsythe and Leonard K. Kaczmarek. Contribution of the Kv3.1 potassium channel to high-frequency firing in mouse auditory neurones. J. Physiol (1998) 509.1 183-194. Created by David Kornfeld, Byram Hills High School, Armonk NY. Please email dbk1@mindspring.com for questions about the model. See Readme.txt below for more info.
Reference:
1 . Wang LY, Gan L, Forsythe ID, Kaczmarek LK (1998) Contribution of the Kv3.1 potassium channel to high-frequency firing in mouse auditory neurones. J Physiol 509 ( Pt 1):183-94 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Medial Nucleus of the Trapezoid Body (MNTB) neuron;
Channel(s): I Na,t; I K; I Sodium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s):
Implementer(s): Kornfeld, David [dbk1 at mindspring.com];
Search NeuronDB for information about:  I Na,t; I K; I Sodium; I Potassium;
: 	Sodium chanel from 
:	Contribution of the Kv3.1 potassium channel to high-frequency firing in mouse auditory neurones
:	Lu-Yang Wang, Li Gan, Ian D. Forsythe and Leonard K. Kaczmarek
:	J. Physiol (1998), 501.9, pp. 183-194

NEURON {
	SUFFIX NaCh
	USEION na READ ena WRITE ina
	RANGE gbar, g, ina
	GLOBAL minf, mtau, hinf, htau, am, bm, ah, bh
}

: area in paper is 1000 (um2) so divide our density parameters by 10

UNITS {
	(mV) = (millivolt)
	(S) = (mho)
	(mA) = (milliamp)
}

PARAMETER {
	gbar = .05 (S/cm2) : .5 (uS)
	gamma = .1

	kam = 76.4 (/ms)
	eam = .037 (/mV)
	:kbm = .0381 (/ms)	: typo in paper
	kbm = 6.930852 (/ms)	: personal communication from L. Kaczmarek
	ebm = -.043 (/mV)

	kah = .00013 (/ms)
	eah = -.1216 (/mV)
	kbh = 1.999 (/ms)
	ebh = .0384 (/mV)
}

ASSIGNED {
	v (mV)
	ena (mV)
	ina (mA/cm2)

	minf
	mtau (ms)
	hinf
	htau (ms)

	am (/ms)
	bm (/ms)
	ah (/ms)
	bh (/ms)
}

STATE {
	m h
}

INITIAL {
	rates(v)
	m = minf
	h = hinf
}

BREAKPOINT {
	SOLVE state METHOD cnexp
	ina = gbar*m^3*h*(v - ena)
}

DERIVATIVE state {
	rates(v)
	m' = (minf - m)/mtau
	h' = (hinf - h)/htau
}

PROCEDURE rates(v(mV)) {
	am = kam*exp(eam*v)
	bm = kbm*exp(ebm*v)

	ah = kah*exp(eah*v)
	bh = kbh*exp(ebh*v)

	minf = am/(am + bm)
	mtau = 1/(am + bm)
	hinf = ah/(ah + bh)
	htau = 1/(ah + bh)
}


Loading data, please wait...