Dynamical model of olfactory bulb mitral cell (Rubin, Cleland 2006)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:64296
This four-compartment mitral cell exhibits endogenous subthreshold oscillations, phase resetting, and evoked spike phasing properties as described in electrophysiological studies of mitral cells. It is derived from the prior work of Davison et al (2000) and Bhalla and Bower (1993). See readme.txt for details.
Reference:
1 . Rubin DB, Cleland TA (2006) Dynamical mechanisms of odor processing in olfactory bulb mitral cells. J Neurophysiol 96:555-68 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Olfactory bulb main mitral GLU cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I A; I K; I K,leak; I h; I K,Ca; I Sodium; I Calcium; I Potassium; I A, slow;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Bursting; Temporal Pattern Generation; Oscillations; Synchronization; Simplified Models; Delay; Olfaction;
Implementer(s): Rubin, Daniel B ;
Search NeuronDB for information about:  Olfactory bulb main mitral GLU cell; I Na,p; I Na,t; I L high threshold; I A; I K; I K,leak; I h; I K,Ca; I Sodium; I Calcium; I Potassium; I A, slow;
/
mitral
readme.txt *
cadecay.mod *
Ih.mod *
INaP.mod
kA.mod
kca3.mod
kfasttab.mod *
kO.mod *
kslowtab.mod *
lcafixed.mod *
nafast.mod
kfast_k.inf *
kfast_k.tau *
kfast_n.inf *
kfast_n.tau *
kslow_k.inf *
kslow_k.tau *
kslow_n.inf *
kslow_n.tau *
mitral.hoc
mosinit.hoc *
tabchannels.hoc *
                            
TITLE HH fast sodium channel
: Implemented in Rubin and Cleland (2006) J Neurophysiology
: Parameters from Bhalla and Bower (1993) J Neurophysiology
: Adapted from /usr/local/neuron/demo/release/nachan.mod - squid
:   by Andrew Davison, The Babraham Institute  [Brain Res Bulletin, 2000]

NEURON {
	SUFFIX nafast
	USEION na READ ena WRITE ina
	RANGE gnabar, ina
	GLOBAL minf, hinf, mtau, htau
}

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
}

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}
PARAMETER {
	v (mV)
	dt (ms)
	gnabar = 0.120 (mho/cm2) <0,1e9>
	ena = 45 (mV)
}
STATE {
	m h
}
ASSIGNED {
	ina (mA/cm2)
	minf
	hinf
	mtau (ms)
	htau (ms)
}

INITIAL {
	rates(v)
	m = minf
	h = hinf
}

BREAKPOINT {
	SOLVE states METHOD cnexp
	ina = gnabar*m*m*m*h*(v - ena)
}

DERIVATIVE states {
	rates(v)
	m' = (minf - m)/mtau
	h' = (hinf - h)/htau
}

FUNCTION alp(v(mV),i) (/ms) {
	if (i==0) {
		alp = 0.32(/ms)*expM1(-(v *1(/mV) + 42), 4)
	}else if (i==1){
		alp = 0.128(/ms)/(exp((v *1(/mV) + 38)/18))
	}
}

FUNCTION bet(v(mV),i)(/ms) {
	if (i==0) {
		bet = 0.28(/ms)*expM1(v *1(/mV) + 15, 5)
	}else if (i==1){
		bet = 4(/ms)/(exp(-(v* 1(/mV) + 15)/5) + 1)
	}
}

FUNCTION expM1(x,y) {
	if (fabs(x/y) < 1e-6) {
		expM1 = y*(1 - x/y/2)
	}else{
		expM1 = x/(exp(x/y) - 1)
	}
}

PROCEDURE rates(v(mV)) {LOCAL a, b
	:TABLE minf, hinf, mtau, htau FROM -100 TO 100 WITH 200
	a = alp(v,0)  b=bet(v,0)
	mtau = 1/(a + b)
	minf = a/(a + b)
	a = alp(v,1)  b=bet(v,1)
	htau = 1/(a + b)
	hinf = a/(a + b)
}

Loading data, please wait...