Modulation of temporal integration window (Migliore, Shepherd 2002)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:7659
Model simulation file from the paper M.Migliore and Gordon M. Shepherd Emerging rules for distributions of active dendritic properties underlying specific neuronal functions. Nature Rev. Neurosci. 3, 362-370 (2002).
Reference:
1 . Migliore M, Shepherd GM (2002) Emerging rules for the distributions of active dendritic conductances. Nat Rev Neurosci 3:362-70 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s):
Channel(s): I h;
Gap Junctions:
Receptor(s): AMPA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Coincidence Detection; Simplified Models;
Implementer(s): Migliore, Michele [Michele.Migliore at Yale.edu];
Search NeuronDB for information about:  AMPA; I h;
/
window
README.txt
distr.mod *
h.mod
fig1a.hoc
mosinit.hoc
                            
TITLE I-h channel from Magee 1998 for distal dendrites

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)

}

PARAMETER {
	v 		(mV)
        ehd  		(mV)        
	celsius 	(degC)
	ghdbar=.0001 	(mho/cm2)
        vhalfl=-90   	(mV)
        vhalft=-75   	(mV)
        a0t=0.011      	(/ms)
        zetal=4    	(1)
        zetat=2.2    	(1)
        gmt=.4   	(1)
	q10=4.5
	qtl=1
}


NEURON {
	SUFFIX hd
	NONSPECIFIC_CURRENT i
        RANGE ghdbar, ehd
        GLOBAL linf,taul
}

STATE {
        l
}

ASSIGNED {
	i (mA/cm2)
        linf      
        taul
        ghd
}

INITIAL {
	rate(v)
	l=linf
}


BREAKPOINT {
	SOLVE states METHOD cnexp
	ghd = ghdbar*l
	i = ghd*(v-ehd)

}


FUNCTION alpl(v(mV)) {
  alpl = exp(1.e-3*zetal*(v-vhalfl)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION alpt(v(mV)) {
  alpt = exp(1.e-3*zetat*(v-vhalft)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION bett(v(mV)) {
  bett = exp(1.e-3*zetat*gmt*(v-vhalft)*9.648e4/(8.315*(273.16+celsius))) 
}

DERIVATIVE states {     : exact when v held constant; integrates over dt step
        rate(v)
        l' =  (linf - l)/taul
}

PROCEDURE rate(v (mV)) { :callable from hoc
        LOCAL a,qt
        qt=q10^((celsius-33)/10)
        a = alpt(v)
        linf = 1/(1+ alpl(v))
        taul = bett(v)/(qtl*qt*a0t*(1+a))
}















Loading data, please wait...