Models of Na channels from a paper on the PKC control of I Na,P (Baker 2005)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:85112
"The tetrodotoxin-resistant (TTX-r) persistent Na(+) current, attributed to Na(V)1.9, was recorded in small (< 25 mum apparent diameter) dorsal root ganglion (DRG) neurones cultured from P21 rats and from adult wild-type and Na(V)1.8 null mice. ... Numerical simulation of the up-regulation qualitatively reproduced changes in sensory neurone firing properties. ..." Note: models of NaV1.8 and NaV1.9 and also persistent and transient Na channels that collectively model Nav 1.1, 1.6, and 1.7 are present in this model.
Reference:
1 . Baker MD (2005) Protein kinase C mediates up-regulation of tetrodotoxin-resistant, persistent Na+ current in rat and mouse sensory neurones. J Physiol 567:851-67 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Dorsal Root Ganglion (DRG) cell;
Channel(s): I Na,p; I Na,t; I K;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.1 SCN1A; Nav1.6 SCN8A; Nav1.7 SCN9A; Nav1.8 SCN10A; Nav1.9 SCN11A SCN12A;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Ion Channel Kinetics; Action Potentials; Signaling pathways; Nociception;
Implementer(s): Morse, Tom [Tom.Morse at Yale.edu];
Search NeuronDB for information about:  I Na,p; I Na,t; I K;
Files displayed below are from the implementation
: kf.mod is the fast K+ current from
: Baker 2005, parameter assignments and formula's from page 854

NEURON {
	SUFFIX kf
	NONSPECIFIC_CURRENT i
	RANGE gbar, ek
	RANGE tau_n, ninf
}

UNITS {
	(S) = (siemens)
	(mV) = (millivolts)
	(mA) = (milliamp)
}

PARAMETER {
	gbar = 3e-6 : =30e-9/(100e-12*1e8) (S/cm2) : 30(nS)/100(um)^2
	ek=-85 (mV)

: Baker 2005 values
	A_anF = 0.00798 (/ms) : A for alpha n
	B_anF = 72.2 (mV)
	C_anF = 1.1 (mV)

	A_bnF = 0.0142 (/ms) : A for beta n
	B_bnF = 55 (mV)
	C_bnF = 10.5 (mV)

: Bostok et al. 1991 values
:	A_anF = 0.129 (/ms) : A for alpha n
:	B_anF = -53 (mV)
:	C_anF = 10 (mV)

:	A_bnF = 0.324 (/ms) : A for beta n
:	B_bnF = -78 (mV)
:	C_bnF = 10 (mV)
}

ASSIGNED {
	v	(mV) : NEURON provides this
	i	(mA/cm2)
	g	(S/cm2)
	tau_n	(ms)
	ninf
}

STATE { n }

BREAKPOINT {
	SOLVE states METHOD cnexp
	g = gbar * n^4
	i = g * (v-ek)
}

INITIAL {
	: assume that equilibrium has been reached
	n = alphan(v)/(alphan(v)+betan(v))
}

DERIVATIVE states {
	rates(v)
	n' = (ninf - n)/tau_n
}

FUNCTION alphan(Vm (mV)) (/ms) {
	if (-Vm-B_anF != 0) {
		alphan=A_anF*(Vm+B_anF)/(1-exp((-Vm-B_anF)/C_anF))
	} else {
		alphan=A_anF*C_anF
	}
}

FUNCTION betan(Vm (mV)) (/ms) {
	if (Vm+B_bnF != 0) {
		betan=A_bnF*(-B_bnF-Vm)/(1-exp((Vm+B_bnF)/C_bnF))
	} else {
		betan=A_bnF*C_bnF
	}
}

FUNCTION rates(Vm (mV)) (/ms) {
	tau_n = 1.0 / (alphan(Vm) + betan(Vm))
	ninf = alphan(Vm) * tau_n
}

Loading data, please wait...