Models of Na channels from a paper on the PKC control of I Na,P (Baker 2005)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:85112
"The tetrodotoxin-resistant (TTX-r) persistent Na(+) current, attributed to Na(V)1.9, was recorded in small (< 25 mum apparent diameter) dorsal root ganglion (DRG) neurones cultured from P21 rats and from adult wild-type and Na(V)1.8 null mice. ... Numerical simulation of the up-regulation qualitatively reproduced changes in sensory neurone firing properties. ..." Note: models of NaV1.8 and NaV1.9 and also persistent and transient Na channels that collectively model Nav 1.1, 1.6, and 1.7 are present in this model.
Reference:
1 . Baker MD (2005) Protein kinase C mediates up-regulation of tetrodotoxin-resistant, persistent Na+ current in rat and mouse sensory neurones. J Physiol 567:851-67 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Dorsal Root Ganglion (DRG) cell;
Channel(s): I Na,p; I Na,t; I K;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.1 SCN1A; Nav1.6 SCN8A; Nav1.7 SCN9A; Nav1.8 SCN10A; Nav1.9 SCN11A SCN12A;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Ion Channel Kinetics; Action Potentials; Signaling pathways; Nociception;
Implementer(s): Morse, Tom [Tom.Morse at Yale.edu];
Search NeuronDB for information about:  I Na,p; I Na,t; I K;
Files displayed below are from the implementation
: nap.mod is a persistent Na+ current from
: Baker 2005, parameter assignments and formula's from page 854

NEURON {
	SUFFIX nap
	NONSPECIFIC_CURRENT i
	RANGE gbar, ena
}

UNITS {
	(S) = (siemens)
	(mV) = (millivolts)
	(mA) = (milliamp)
}

PARAMETER {
	gbar = 3.6e-8 : =0.36e-9/(100e-12*1e8) (S/cm2) : 18(nS)/100(um)^2
	ena=79.6 (mV)

	A_amp = 17.235 (/ms) : A for alpha m persis
	B_amp = 27.58 (mV)
	C_amp = -11.47 (mV)

	A_bmp = 17.235 (/ms) : A for beta m persis
	B_bmp = 86.2 (mV)
	C_bmp = 19.8 (mV)
}

ASSIGNED {
	v	(mV) : NEURON provides this
	i	(mA/cm2)
	g	(S/cm2)
	tau_m	(ms)
	minf
	hinf
}

STATE { m h }

BREAKPOINT {
	SOLVE states METHOD cnexp
	g = gbar * m^3
	i = g * (v-ena)
}

INITIAL {
	: assume that equilibrium has been reached
	m = alpham(v)/(alpham(v)+betam(v))
}

DERIVATIVE states {
	rates(v)
	m' = (minf - m)/tau_m
}

FUNCTION alpham(Vm (mV)) (/ms) {
	alpham=A_amp/(1+exp((Vm+B_amp)/C_amp))
}

FUNCTION betam(Vm (mV)) (/ms) {
	betam=A_bmp/(1+exp((Vm+B_bmp)/C_bmp))
}

FUNCTION rates(Vm (mV)) (/ms) {
	tau_m = 1.0 / (alpham(Vm) + betam(Vm))
	minf = alpham(Vm) * tau_m
}

Loading data, please wait...