Activity dependent conductances in a neuron model (Liu et al. 1998)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:93321
"... We present a model of a stomatogastric ganglion (STG) neuron in which several Ca2+-dependent pathways are used to regulate the maximal conductances of membrane currents in an activity-dependent manner. Unlike previous models of this type, the regulation and modification of maximal conductances by electrical activity is unconstrained. The model has seven voltage-dependent membrane currents and uses three Ca2+ sensors acting on different time scales. ... The model suggests that neurons may regulate their conductances to maintain fixed patterns of electrical activity, rather than fixed maximal conductances, and that the regulation process requires feedback systems capable of reacting to changes of electrical activity on a number of different time scales."
Reference:
1 . Liu Z, Golowasch J, Marder E, Abbott LF (1998) A model neuron with activity-dependent conductances regulated by multiple calcium sensors. J Neurosci 18:2309-20 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s):
Channel(s): I Na,t; I L high threshold; I T low threshold; I A; I K; I K,Ca; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Bursting; Temporal Pattern Generation; Homeostasis;
Implementer(s): Morse, Tom [Tom.Morse at Yale.edu];
Search NeuronDB for information about:  I Na,t; I L high threshold; I T low threshold; I A; I K; I K,Ca; I Potassium;
COMMENT
This file, g_kca.mod, implements the sensor equation (3) p. 2311
Liu et al. 1998 (Activity dependent conductances)
for the (Ca dependent K) KCa current
Tom M Morse 20070807

ENDCOMMENT

NEURON {
	SUFFIX gbarkca
	POINTER F, S, D
	RANGE gbarkca, tau, Fbar, Sbar, Dbar, A, B, C
: read gbarkca as g bar sub i with i=Kca
: tau is the time constant of activity regulation, and the other
: variables associated with eq. 3 p 2311
:
: below is a value that is expected to be assigned by hoc code
: that is then assigned as a starting value in the INIT block
	RANGE gbarkca_init
}

UNITS {
	(mA) = (milliamp)
}

PARAMETER {
	Fbar = 0.1 (1) : p2312 col 1 paragraph below middle of page
	Sbar = 0.1 (1)
	Dbar = 0.1 (1)
	tau = 5000 (ms) : p2312 col 1 paragraph at middle of page
	A = 0 : p2312, Table 1
	B = -1
	C = -1
}

ASSIGNED {
	F (1)
	S (1)
	D (1)
	gbarkca_init (mA/cm2)
}

INITIAL {
	gbarkca = gbarkca_init
}

STATE { gbarkca (mA/cm2) }

BREAKPOINT {
	SOLVE state METHOD cnexp
}

DERIVATIVE state {
	gbarkca' = ( A*(Fbar-F) + B*(Sbar-S) + C*(Dbar-D) ) * gbarkca / tau
}

Loading data, please wait...