Activity dependent conductances in a neuron model (Liu et al. 1998)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:93321
"... We present a model of a stomatogastric ganglion (STG) neuron in which several Ca2+-dependent pathways are used to regulate the maximal conductances of membrane currents in an activity-dependent manner. Unlike previous models of this type, the regulation and modification of maximal conductances by electrical activity is unconstrained. The model has seven voltage-dependent membrane currents and uses three Ca2+ sensors acting on different time scales. ... The model suggests that neurons may regulate their conductances to maintain fixed patterns of electrical activity, rather than fixed maximal conductances, and that the regulation process requires feedback systems capable of reacting to changes of electrical activity on a number of different time scales."
Reference:
1 . Liu Z, Golowasch J, Marder E, Abbott LF (1998) A model neuron with activity-dependent conductances regulated by multiple calcium sensors. J Neurosci 18:2309-20 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s):
Channel(s): I Na,t; I L high threshold; I T low threshold; I A; I K; I K,Ca; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Bursting; Temporal Pattern Generation; Homeostasis;
Implementer(s): Morse, Tom [Tom.Morse at Yale.edu];
Search NeuronDB for information about:  I Na,t; I L high threshold; I T low threshold; I A; I K; I K,Ca; I Potassium;
COMMENT
This file, kca.mod, implements the IKCa potassium current from 
Liu et al. 1998 (Activity dependent conductances) table p.2319
Tom M Morse 20070803
ENDCOMMENT

NEURON {
	SUFFIX kca
	NONSPECIFIC_CURRENT i
	USEION ca READ cai
	POINTER gbar
	RANGE i, Erev
}

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(molar) = (1/liter)
	(mM) = (millimolar)
	(um) = (micron)
	(S)  = (siemens)
}

PARAMETER {
	gbar (S/cm2) : = 2e-6	(S/cm2) < 0, 1e9 > : this value gets overwritten by activity dependent regulation
	Erev = -80 (mV)
: Note: concentrations in Liu et al. paper are in micromolar which needs to be
: converted to millimolar for use in these NEURON programs.  (These mod files
: expect the cai, cao variables to already be in millimolar
: these get overwritten when read in:
	cai (mM) :	= 2.4e-4 (mM)		: adjusted for eca=120 mV
	cao	= 3	(mM)  : p.2319 Liu et al. 1998 (for eca 120 comment above cao=2 mM (orig))
}

ASSIGNED {
	i (mA/cm2)
	v (mV)
	g (S/cm2)
	minf
	tau_m (ms)
}

STATE {	m }

BREAKPOINT {
	SOLVE states METHOD cnexp
	g = gbar * m^4
	i = g * (v - Erev)
}

INITIAL {
	: assume that v has been constant for a long time
	rates(v)
	m = minf
}
DERIVATIVE states {
	rates(v)
	m' = (minf - m)/tau_m
}

FUNCTION taum(Vm (mV)) (ms) {
	UNITSOFF
	taum = 90.3-75.1/(1+exp(-(Vm+46)/22.7))
	UNITSON
}

PROCEDURE rates(Vm(mV)) {
	tau_m = taum(Vm)
	UNITSOFF
: note the conversion of 3 uM (paper p. 2319 fig 10) to 3e-3 mM in below:
	minf = (cai/(cai+3e-3)) * (1/(1+exp(-(Vm+28.3)/12.6)))
	UNITSON
}

Loading data, please wait...