Rod photoreceptor (Barnes and Hille 1989, Publio et al. 2006, Kourennyi and Liu et al. 2004)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:95870
This a conductance-based model of a rod photoreceptor cell based on other modeling works (Barnes and Hille 1989 and Publio et al. 2006 and Kourennyi and Liu et al. 2004 ). In this model four types of ionic channels identified in the inner segment of the rod: nonselective cation channel (h), delayed rectifying potassium channel (Kv), noninactivating potassium channel (Kx) and calcium channel (Ca) was used. The model accurately reproduces the rod response when stimulated with a simulated photocurrent signal. We can show the effect of nonselective cation channel. The absence of this channel cause increasing the peak amplitude and the time to reach the peak of voltage response and absence of transient mode in this response.
References:
1 . Barnes S, Hille B (1989) Ionic channels of the inner segment of tiger salamander cone photoreceptors. J Gen Physiol 94:719-43 [PubMed]
2 . Kourennyi DE, Liu XD, Hart J, Mahmud F, Baldridge WH, Barnes S (2004) Reciprocal modulation of calcium dynamics at rod and cone photoreceptor synapses by nitric oxide. J Neurophysiol 92:477-83 [PubMed]
3 . Liu XD, Kourennyi DE (2004) Effects of tetraethylammonium on Kx channels and simulated light response in rod photoreceptors. Ann Biomed Eng 32:1428-42 [PubMed]
4 . Publio R, Oliveira RF, Roque AC (2006) A realistic model of rod photoreceptor for use in a retina network model Neurocomputing 69:1020-1024
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Retina photoreceptor cone GLU cell;
Channel(s): I Cl,Ca; I K,Ca; I Calcium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Ion Channel Kinetics; Calcium dynamics;
Implementer(s): Shahali, Mahboubeh [shahali222 at yahoo.com];
Search NeuronDB for information about:  Retina photoreceptor cone GLU cell; I Cl,Ca; I K,Ca; I Calcium; I Potassium;
: Rod  Photoreceptor Ca and Calcium  channel
: Ref. Kourenny and  Liu 2002   ABME 30 : 1196-1203
: Modification 2004-02-07
NEURON 
{
	SUFFIX Ca
	
	USEION Ca WRITE iCa VALENCE 2
        RANGE gCabar,VhalfCam,SCam
        RANGE VhalfCah,SCah
        RANGE eCa,aomCa,bomCa
        RANGE gammaohCa,deltaohCa


}

UNITS
{
	(mA) = (milliamp)
	(mV) = (millivolt)
	(mS) = (millimho)
	(mol)= (1)
	(M)  = (mol/liter)
	(uM) = (micro M)
}

PARAMETER
{
       
       : Calcium channel 
       gCabar = 2 (mS/cm2) <0,1e9> :different from ABME paper
       eCa =  40 (mV)
       aomCa = 50  (/s)  : changed from 3.10/s, 20/s
       bomCa = 50  (/s)
       gammaohCa = 1 (/s)
       deltaohCa =1 (/s)  
 
       VhalfCam=-20.0 (mV)
       VhalfCah=10 (mV)
       SCam =6.0      (mV) 
       
       SCah =9        (mV)   
     
}


STATE
{

	mCa
	hCa
	
}

ASSIGNED
{
	gCa (mho/cm2)
    
	v (mV)
	
	iCa (mA/cm2)

	infmCa
	taumCa  (ms) 
	


	infhCa
	tauhCa (ms)



}

INITIAL
{
	rate(v)
	mCa = infmCa
	hCa = infhCa

}




BREAKPOINT
{
	SOLVE states METHOD cnexp
	gCa = (0.001)*gCabar*mCa*hCa
	: g is in unit of S/cm2 ,i is in unit of mA/cm2 and v is in mV
	
	iCa = gCa*(v - eCa)
	: the current is in the unit of mA/cm2
	
	
}

DERIVATIVE states
{
	rate(v)
	mCa' = (infmCa - mCa)/taumCa
	hCa'= (infhCa-hCa)/tauhCa


}




FUNCTION alphamCa(v(mV))(/ms)
{ 
	alphamCa = 0.001*aomCa*exp( (v - VhalfCam)/(2*SCam)   )
}

FUNCTION betamCa(v(mV))(/ms)
{ 
	betamCa = 0.001*bomCa*exp( - ( v-VhalfCam)/(2*SCam) )
}
FUNCTION gammahCa(v(mV))(/ms)
{ 
	gammahCa = 0.001*gammaohCa*exp( (v - VhalfCah)/(2*SCah))
}

FUNCTION deltahCa(v(mV))(/ms)
{ 
	deltahCa = 0.001*deltaohCa*exp( - ( v-VhalfCah)/(2*SCah) )
}


PROCEDURE rate(v (mV))
{
        LOCAL a, b,c, d


	a = alphamCa(v)
	b = betamCa(v)
	taumCa = 1/(a + b)
	infmCa = a/(a + b)
	
	c = gammahCa(v)
	d = deltahCa(v)
	tauhCa = 1/(c + d)
	infhCa = d/(c + d)

}


Loading data, please wait...