A set of reduced models of layer 5 pyramidal neurons (Bahl et al. 2012)

 Download zip file 
Help downloading and running models
Accession:146026
These are the NEURON files for 10 different models of a reduced L5 pyramidal neuron. The parameters were obtained by automatically fitting the models to experimental data using a multi objective evolutionary search strategy. Details on the algorithm can be found at http://www.g-node.org/emoo and in Bahl et al. (2012).
Reference:
1 . Bahl A, Stemmler MB, Herz AV, Roth A (2012) Automated optimization of a reduced layer 5 pyramidal cell model based on experimental data. J Neurosci Methods 210:22-34 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Dendrite;
Brain Region(s)/Organism:
Cell Type(s): Neocortex U1 L5B pyramidal pyramidal tract GLU cell;
Channel(s): I Na,p; I Na,t; I K; I M; I h; I K,Ca; I Calcium; I A, slow;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Parameter Fitting; Simplified Models; Active Dendrites; Detailed Neuronal Models; Action Potentials; Methods; Calcium dynamics;
Implementer(s): Bahl, Armin [bahl at neuro.mpg.de];
Search NeuronDB for information about:  Neocortex U1 L5B pyramidal pyramidal tract GLU cell; I Na,p; I Na,t; I K; I M; I h; I K,Ca; I Calcium; I A, slow; 
TITLE Sodium persistent current for RD Traub, J Neurophysiol 89:909-921, 2003

COMMENT

	Implemented by Maciej Lazarewicz 2003 (mlazarew@seas.upenn.edu)

ENDCOMMENT

INDEPENDENT { t FROM 0 TO 1 WITH 1 (ms) }

UNITS { 
	(mV) = (millivolt) 
	(mA) = (milliamp) 
} 
NEURON { 
	SUFFIX nap
	USEION na READ ena WRITE ina
	RANGE gbar, ina, minf, mtau, gna, vshift
}

PARAMETER { 
	gbar = 0.0 	(pS/um2)
	vshift = 0
	v ena 		(mV)  
} 
ASSIGNED { 
	ina 		(mA/cm2) 
	minf 		(1)
	mtau 		(ms) 
	gna		(mho/cm2)
} 
STATE {
	m
}

BREAKPOINT { 
	SOLVE states METHOD cnexp
	gna = gbar * m
	ina = (1e-4)*gna * ( v - ena ) 
} 

INITIAL { 
	settables(v-vshift) 
	m = minf
	:m = 0
} 

DERIVATIVE states { 
	settables(v-vshift) 
	m' = ( minf - m ) / mtau 
}
UNITSOFF
 
PROCEDURE settables(v) { 
	TABLE minf, mtau FROM -120 TO 40 WITH 641

	minf  = 1 / ( 1 + exp( ( - v - 48 ) / 10 ) )
	if( v < -40.0 ) {
		mtau = 0.025 + 0.14 * exp( ( v + 40 ) / 10 )
	}else{
		mtau = 0.02 + 0.145 * exp( ( - v - 40 ) / 10 )
	}
}
UNITSON

Loading data, please wait...