Modeling the effects of dopamine on network synchronization (Komek et al. 2012)

 Download zip file 
Help downloading and running models
Accession:146734
Dopamine modulates cortical circuit activity in part through its actions on GABAergic interneurons, including increasing the excitability of fast-spiking interneurons. Though such effects have been demonstrated in single cells, there are no studies that examine how such mechanisms may lead to the effects of dopamine at a neural network level. In this study, we investigated the effects of dopamine on synchronization in two simulated neural networks; one biophysical model composed of Wang-Buzsaki neurons and a reduced model with theta neurons. In both models, we show that parametrically varying the levels of dopamine, modeled through the changes in the excitability of interneurons, reveals an inverted-U shaped relationship, with low gamma band power at both low and high dopamine levels and optimal synchronization at intermediate levels. Moreover, such a relationship holds when the external input is both tonic and periodic at gamma band range. Together, our results indicate that dopamine can modulate cortical gamma band synchrony in an inverted-U fashion and that the physiologic effects of dopamine on single fast-spiking interneurons can give rise to such non-monotonic effects at the network level.
Reference:
1 . K├Âmek K, Bard Ermentrout G, Walker CP, Cho RY (2012) Dopamine and gamma band synchrony in schizophrenia--insights from computational and empirical studies. Eur J Neurosci 36:2146-55 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism:
Cell Type(s): Abstract Wang-Buzsaki neuron; Abstract theta neuron;
Channel(s):
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s): Dopamine;
Simulation Environment: XPP;
Model Concept(s): Synchronization;
Implementer(s): Ermentrout, Bard [bard_at_pitt.edu]; Komek, Kubra [kkomek at andrew.cmu.edu];
Search NeuronDB for information about:  Dopamine;
# Theta neuron network with 50e and 20i cells with all-to-all
# connectivity and tonic input to both the e- and i-cells in a 
# batch format varying across the I_i parameters
#
# Specifying the low and high values of the range of the parameter
par I_ilo=-0.25,I_ihi=0.31
par ind
# Equation needed to calculate the specific values of the parameter
# based on the low and high values and the step size for the increments
!I_i=I_ilo+mod(ind,56)*(I_ihi-I_ilo)/56
# creating auxiliary variable to see what the actual value is
aux I_i0=I_i
# specify what you want to see in the output files in the order
only t,se,I_i0
#
# Parameters
par I_e=1
par gei=.4,gii=0.15,gee=0.1, gie=2
par tauz=50,gz=.2
par sige=0.5, sigi=.02
par taue=1, taui=3
#
#ODEs for e-cells, i-cells and adaptation
x[0..49]'=1-cos(x[j])+(1+cos(x[j]))*(I_e-gz*z[j]-gie*si+gee*se+sige*we[j])
z[0..49]'=sd(x[j])-z[j]/tauz
y[0..19]'=1-cos(y[j])+(1+cos(y[j]))*(I_i-gii*si+gei*se+sigi*wi[j])
# Synapses
se'=sum(0,49)of(sd(shift(x0,i')))/50-se/taue
si'=sum(0,19)of(sd(shift(y0,i')))/20-si/taui
global 1 x[0..49]-pi {x[j]=-pi}
global 1 y[0..19]-pi {y[j]=-pi}
#
# Initial Conditions
x[0..49](0)=ran(1)*2*pi-pi
y[0..19](0)=ran(1)*2*pi-pi
wiener we[0..49]
wiener wi[0..19]
sd(x)=exp(-b*(1-cos(x-2.5)))*b
par b=100
aux swgt=.8*se+.2*si
@ meth=euler,
@ total=1400,trans=400,maxstor=1000000
@ dt=0.02,nOut=10
@ xp=t,yp=se,xlo=600,xhi=1200,ylo=0,yhi=.5
# needed for the range set up
@ range=1,rangeover=ind,rangelow=0,rangehigh=56,rangestep=56
@ rangereset=yes
done

Loading data, please wait...