Modeling the effects of dopamine on network synchronization (Komek et al. 2012)

 Download zip file 
Help downloading and running models
Accession:146734
Dopamine modulates cortical circuit activity in part through its actions on GABAergic interneurons, including increasing the excitability of fast-spiking interneurons. Though such effects have been demonstrated in single cells, there are no studies that examine how such mechanisms may lead to the effects of dopamine at a neural network level. In this study, we investigated the effects of dopamine on synchronization in two simulated neural networks; one biophysical model composed of Wang-Buzsaki neurons and a reduced model with theta neurons. In both models, we show that parametrically varying the levels of dopamine, modeled through the changes in the excitability of interneurons, reveals an inverted-U shaped relationship, with low gamma band power at both low and high dopamine levels and optimal synchronization at intermediate levels. Moreover, such a relationship holds when the external input is both tonic and periodic at gamma band range. Together, our results indicate that dopamine can modulate cortical gamma band synchrony in an inverted-U fashion and that the physiologic effects of dopamine on single fast-spiking interneurons can give rise to such non-monotonic effects at the network level.
Reference:
1 . K├Âmek K, Bard Ermentrout G, Walker CP, Cho RY (2012) Dopamine and gamma band synchrony in schizophrenia--insights from computational and empirical studies. Eur J Neurosci 36:2146-55 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism:
Cell Type(s): Abstract Wang-Buzsaki neuron; Abstract theta neuron;
Channel(s):
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s): Dopamine;
Simulation Environment: XPP;
Model Concept(s): Synchronization;
Implementer(s): Ermentrout, Bard [bard_at_pitt.edu]; Komek, Kubra [kkomek at andrew.cmu.edu];
Search NeuronDB for information about:  Dopamine;
# Theta neuron model 50e and 20i cells with all-to-all 
# connectivity and periodic input to both the e- and i-cells
#
# Parameters
par I_e=0.4,I_i=0
par tauz=50,gz=.5
par sige=0.5,sigi=.01
par gie=3,gei=.4,gii=0.15,gee=2,
par taue=1,taui=3
#
# Periodic stimuli description with parameters
E(t)=heav(t-t_on)*heav(stim+t_on-t)
PO(t)=heav(d-t)
P(t)=PO(mod(t,per))
z'=(-z+p(t))/tau
I_x(t)=Ampx*z*E(t)
I_y(t)=Ampy*z*E(t)
par Ampx=70,Ampy=10,d=1,per=25,tau=20
par t_on=0,stim=1000
#
# ODEs for e-cells(x), i-cells(y) and adaptation(z)
x[0..49]'=1-cos(x[j])+(1+cos(x[j]))*(I_e+I_x(t)-gz*z[j]-gie*si+gee*se+sige*we[j])
z[0..49]'=sd(x[j])-z[j]/tauz
y[0..19]'=1-cos(y[j])+(1+cos(y[j]))*(I_i+I_y(t)-gii*si+gei*se+sigi*wi[j])
#
global 1 x[0..49]-pi {x[j]=-pi;out_put=1}
global 1 y[0..19]-pi {y[j]=-pi;out_put=1}
# Synapses
se'=sum(0,49)of(sd(shift(x0,i')))/50-se/taue
si'=sum(0,19)of(sd(shift(y0,i')))/20-si/taui
#
#Initial conditions
x[0..49](0)=ran(1)*2*pi-pi
y[0..19](0)=ran(1)*2*pi-pi
wiener we[0..49]
wiener wi[0..19]
sd(x)=exp(-b*(1-cos(x-2.5)))*b
par b=100
aux swgt=.8*se+.2*si
aux per_input=I_x(t)
@ dt=0.02,nOut=10
@ meth=euler,total=1400,trans=400,maxstor=1000000
@ yp=se,xlo=400,xhi=1400,ylo=0,yhi=.5
done

Loading data, please wait...