Survey of electrically evoked responses in the retina (Tsai et al 2017)

 Download zip file 
Help downloading and running models
Accession:262389
"Cones and horizontal cells are interconnected to adjacent cones and horizontal cells, respectively, with gap junctions. In particular, the horizontal cell gap junctional conductance is modulated by exogenous factors. What roles does this conductance play in the electrically evoked responses of horizontal cells? To address this question, we constructed a computational model consisting of the cone and horizontal cell layer..."
Reference:
1 . Tsai D, Morley JW, Suaning GJ, Lovell NH (2017) Survey of electrically evoked responses in the retina - stimulus preferences and oscillation among neurons. Sci Rep 7:13802 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Synapse; Extracellular;
Brain Region(s)/Organism: Retina;
Cell Type(s): Retina photoreceptor cone GLU cell; Retina horizontal cell;
Channel(s):
Gap Junctions: Gap junctions;
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Oscillations;
Implementer(s): Tsai, David [d.tsai at unsw.edu.au];
Search NeuronDB for information about:  Retina photoreceptor cone GLU cell;
TITLE Cone photoreceptor Ih
: Cone Photoreceptor Ih channel by using kinetics in Barnes' paper
: 
: Based on Publio et al. (2009)


NEURON {
    SUFFIX ConeIh
    NONSPECIFIC_CURRENT ih
    RANGE ghbar, gh, eh 
}

UNITS {
    (mA) = (milliamp)
    (mV) = (millivolt)
    (mS) = (millimho)
}

PARAMETER {
    : h channel
    ghbar = 3.5 (mS/cm2) <0,1e9>
    eh  = -32.5 (mV)
}

STATE {
    nh
}

ASSIGNED {
    v (mV)
    
    ih (mA/cm2)
    
    infh
    tauh   (ms)
    
    gh (mho/cm2)
}

INITIAL {
    rate(v)
    nh  = infh
}

BREAKPOINT {
    SOLVE states METHOD cnexp
    gh  = (0.001)*ghbar*(1-(1+3*nh)*(1-nh)^3)
    ih  = gh*(v - eh)
    
    : the current is in the unit of mA/cm2
}

DERIVATIVE states {
    rate(v)
    nh'  = (infh  - nh )/tauh
}

FUNCTION alphah(v(mV)) (/ms) { 
    alphah = 0.001*18/( exp  (  ( v+88)/12 ) + 1 )
}

FUNCTION betah(v(mV)) (/ms) { 
    betah = 0.001*18/( exp  ( - ( v+18)/19 ) + 1 )
}

PROCEDURE rate(v (mV)) { LOCAL a, b
    a = alphah(v)
    b = betah(v)
    tauh = 1/(a + b)
    infh = a/(a + b)
}


Loading data, please wait...