SCN1A gain-of-function in early infantile encephalopathy (Berecki et al 2019)

 Download zip file 
Help downloading and running models
Accession:264834
"OBJECTIVE: To elucidate the biophysical basis underlying the distinct and severe clinical presentation in patients with the recurrent missense SCN1A variant, p.Thr226Met. Patients with this variant show a well-defined genotype-phenotype correlation and present with developmental and early infantile epileptic encephalopathy that is far more severe than typical SCN1A Dravet syndrome. METHODS: Whole cell patch clamp and dynamic action potential clamp were used to study T226M Nav 1.1 channels expressed in mammalian cells. Computational modeling was used to explore the neuronal scale mechanisms that account for altered action potential firing. RESULTS: T226M channels exhibited hyperpolarizing shifts of the activation and inactivation curves and enhanced fast inactivation. Dynamic action potential clamp hybrid simulation showed that model neurons containing T226M conductance displayed a left shift in rheobase relative to control. At current stimulation levels that produced repetitive action potential firing in control model neurons, depolarization block and cessation of action potential firing occurred in T226M model neurons. Fully computationally simulated neuron models recapitulated the findings from dynamic action potential clamp and showed that heterozygous T226M models were also more susceptible to depolarization block. ..."
Reference:
1 . Berecki G, Bryson A, Terhag J, Maljevic S, Gazina EV, Hill SL, Petrou S (2019) SCN1A gain of function in early infantile encephalopathy. Ann Neurol 85:514-525 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism:
Cell Type(s):
Channel(s): I Sodium;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.1 SCN1A;
Transmitter(s):
Simulation Environment: NEURON; Python; BluePyOpt ;
Model Concept(s): Action Potentials; Epilepsy; Depolarization block; Development;
Implementer(s): Bryson, Alex [alexander.bryson at florey.edu.au];
Search NeuronDB for information about:  I Sodium;
/
modelDB_scn1a
mechanisms
Ca.mod *
Ca_HVA.mod *
Ca_LVAst.mod *
CaDynamics_E2.mod
Ih.mod *
Im.mod *
K_Pst.mod *
K_Tst.mod *
Nap_Et2.mod
NaTa_t.mod
NaTs2_t.mod
Nav11.mod
Nav11m.mod
SK_E2.mod
SKv3_1.mod *
                            
COMMENT

"NaV1.1" channel.
BBP 'fast' Na channel, but activation/inactivation vHalf and slope adjusted to fit experimental data.
Use this mechanism to 'mutate' given proportion of Nav1.1 channels.

ENDCOMMENT

:Reference :Colbert and Pan 2002

: Adapted by Werner Van Geit @ BBP, 2015 (with help from M.Hines):
: channel detects TTX concentration set by TTXDynamicsSwitch.mod


NEURON {
	SUFFIX Nav11m
	USEION na READ ena WRITE ina
	USEION ttx READ ttxo, ttxi VALENCE 1
	RANGE gNav11bar, gNav11, ina,mh,ms,hh,hs,tmh,thh
}

UNITS	{
	(S) = (siemens)
	(mV) = (millivolt)
	(mA) = (milliamp)
}

PARAMETER	{
	gNav11bar = 0.00001 (S/cm2)
	mh=-18.46 : activation vh
	ms=7.91   : activation slope
	hh=-48.8 : inactivation vh
	hs=6.25   : inactivation slope
	tmh=-25.04   : activation tau v-half
	thh=-55.53    : inactivation tau v-half
}

ASSIGNED {
	ttxo (mM)
	ttxi (mM)
	v	(mV)
	ena	(mV)
	ina	(mA/cm2)
	gNav11	(S/cm2)
	mInf
	mTau
	hInf
	hTau
}

STATE	{
	m
	h
}

BREAKPOINT	{
	SOLVE states METHOD cnexp
	gNav11 = gNav11bar*m*m*m*h
	ina = gNav11*(v-ena)
}

DERIVATIVE states	{
	if (ttxi == 0.015625 && ttxo > 1e-12) {
		mInf = 0.0
		mTau = 1e-12
		hInf = 1.0
		hTau = 1e-12
	} else {
		rates()
	}
	m' = (mInf-m)/mTau
	h' = (hInf-h)/hTau
}

INITIAL{
	if (ttxi == 0.015625 && ttxo > 1e-12) {
		mInf = 0.0
		mTau = 1e-12
		hInf = 1.0
		hTau = 1e-12
	} else {
		rates()
	}
	m = mInf
	h = hInf
}

PROCEDURE rates(){
  LOCAL qt
  qt = 2.3^((34-24)/10) : recordings at 24C

  UNITSOFF
    if(v == mh){
    	v = v+0.0001
    }
		mTau = (0.0876 + 0.35 * exp((-(tmh - v)^2)/ 340.13))/qt
		mInf = 1.0/(1.0+exp((mh-v)/ms))

    if(v == hh){
      v = v + 0.0001
    }
		hTau = (0.438 + 12.22 * exp((-(thh - v)^2)/ 547.24))/qt
		hInf = 1.0/(1.0+exp((v-hh)/hs))
	UNITSON
}

Loading data, please wait...