Molecular layer interneurons in cerebellum encode valence in associative learning (Ma et al 2020)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:266578
We used two-photon microscopy to study the role of ensembles of cerebellar molecular layer interneurons (MLIs) in a go-no go task where mice obtain a sugar water reward. In order to begin understanding the circuit basis of our findings in changes in lick behavior with chemogenetics in the go-no go associative learning olfactory discrimination task we generated a simple computational model of MLI interaction with PCs.
Reference:
1 . Ma M, Futia GL, De Souza FM, Ozbay BN, Llano I, Gibson EA, Restrepo D (2020) Molecular layer interneurons in the cerebellum encode for valence in associative learning Nature Communications, accepted
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Cerebellum; Mouse;
Cell Type(s): Cerebellum Purkinje GABA cell; Cerebellum interneuron stellate GABA cell;
Channel(s):
Gap Junctions:
Receptor(s): AMPA; GabaA;
Gene(s):
Transmitter(s): Gaba; Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Action Potentials; Detailed Neuronal Models;
Implementer(s): Simoes-de-Souza, Fabio [fabio.souza at ufabc.edu.br];
Search NeuronDB for information about:  Cerebellum Purkinje GABA cell; Cerebellum interneuron stellate GABA cell; GabaA; AMPA; Gaba; Glutamate;
/
MaEtAl2020
README.html
bkpkj.mod *
cad.mod *
cadiff.mod *
cae.mod *
cap2.mod *
captain.mod *
cat.mod *
cha.mod *
erg.mod *
gkca.mod *
Golgi_Ca_LVA.mod *
Golgi_KA.mod *
Golgi_KV.mod
Golgi_Na.mod *
hpkj.mod *
k23.mod *
ka.mod *
kc3.mod *
kd.mod *
kdyn.mod *
khh.mod *
km.mod *
kpkj.mod *
kpkj2.mod *
kpkjslow.mod *
kv1.mod *
leak.mod *
lkpkj.mod *
myexchanger.mod *
myexchangersoma.mod *
mypump.mod *
mypumpsoma.mod *
nadifl.mod *
narsg.mod *
newnew.mod *
pump.mod *
10480.tmp
2_compartment_template.hoc
full.ses *
lesbos.ses *
mosinit.hoc
mosinit_PC_SC_SminusCNO.hoc
mosinit_PC_SC_SminusSaline.hoc
mosinit_PC_SC_SplusCNO.hoc
mosinit_PC_SC_SplusSaline.hoc
PC_alx.swc
PF_template.hoc
Plot_results.m
SC_morphology.hoc
SC_template.hoc
SC_withoutaxon.swc
screenshot.png
                            
TITLE Low threshold calcium current Cerebellum Golgi Cell Model
:
:   Ca++ current responsible for low threshold spikes (LTS)
:   RETICULAR THALAMUS
:   Differential equations
:
:   Model of Huguenard & McCormick, J Neurophysiol 68: 1373-1383, 1992.
:   The kinetics is described by standard equations (NOT GHK)
:   using a m2h format, according to the voltage-clamp data
:   (whole cell patch clamp) of Huguenard & Prince, J Neurosci.
:   12: 3804-3817, 1992.  The model was introduced in Destexhe et al.
:   J. Neurophysiology 72: 803-818, 1994.
:   See http://www.cnl.salk.edu/~alain , http://cns.fmed.ulaval.ca
:
:    - Kinetics adapted to fit the T-channel of reticular neuron
:    - Q10 changed to 5 and 3
:    - Time constant tau_h fitted from experimental data
:    - shift parameter for screening charge
:
:   ACTIVATION FUNCTIONS FROM EXPERIMENTS (NO CORRECTION)
:
:   Reversal potential taken from Nernst Equation
:
:   Written by Alain Destexhe, Salk Institute, Sept 18, 1992
:

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
        SUFFIX Golgi_Ca_LVA
        USEION ca2 READ ca2i, ca2o WRITE ica2 VALENCE 2
        RANGE g, gca2bar, m_inf, tau_m, h_inf, tau_h, shift
	RANGE ica2, m ,h, ca2rev
	RANGE phi_m, phi_h
	RANGE v0_m_inf,v0_h_inf,k_m_inf,k_h_inf,C_tau_m
	RANGE A_tau_m,v0_tau_m1,v0_tau_m2,k_tau_m1,k_tau_m2
	RANGE C_tau_h ,A_tau_h ,v0_tau_h1,v0_tau_h2,k_tau_h1 ,k_tau_h2

    }

UNITS {
        (molar) = (1/liter)
        (mV) =  (millivolt)
        (mA) =  (milliamp)
        (mM) =  (millimolar)

        FARADAY = (faraday) (coulomb)
        R = (k-mole) (joule/degC)
}

PARAMETER {
        v               (mV)
        celsius (degC)
        eca2 (mV)
	   gca2bar  = 2.5e-4 (mho/cm2)
        shift   = 2     (mV)            : screening charge for Ca_o = 2 mM
        ca2i  (mM)           : adjusted for eca=120 mV
        ca2o  (mM)
	
	v0_m_inf = -50 (mV)
	v0_h_inf = -78 (mV)
	k_m_inf = -7.4 (mV)
	k_h_inf = 5.0  (mv)
	
	C_tau_m = 3
	A_tau_m = 1.0
	v0_tau_m1 = -25 (mV)
	v0_tau_m2 = -100 (mV)
	k_tau_m1 = 10 (mV)
	k_tau_m2 = -15 (mV)
	
	C_tau_h = 85
	A_tau_h = 1.0
	v0_tau_h1 = -46 (mV)
	v0_tau_h2 = -405 (mV)
	k_tau_h1 = 4 (mV)
	k_tau_h2 = -50 (mV)
	
    }
    

STATE {
        m h
}

ASSIGNED {
        ica2     (mA/cm2)
        ca2rev   (mV)
	g        (mho/cm2) 
        m_inf
        tau_m   (ms)
        h_inf
        tau_h   (ms)
        phi_m
        phi_h
}

BREAKPOINT {
        SOLVE ca2state METHOD cnexp
        ca2rev = (1e3) * (R*(celsius+273.15))/(2*FARADAY) * log (ca2o/ca2i)
        g = gca2bar * m*m*h
        ica2 = gca2bar * m*m*h * (v-ca2rev)
}

DERIVATIVE ca2state {
        evaluate_fct(v)

        m' = (m_inf - m) / tau_m
        h' = (h_inf - h) / tau_h
}

UNITSOFF
INITIAL {
:
:   Activation functions and kinetics were obtained from
:   Huguenard & Prince, and were at 23-25 deg.
:   Transformation to 36 deg assuming Q10 of 5 and 3 for m and h
:   (as in Coulter et al., J Physiol 414: 587, 1989)
:

        evaluate_fct(v)
        m = m_inf
        h = h_inf
}

PROCEDURE evaluate_fct(v(mV)) { 
:
:   Time constants were obtained from J. Huguenard
:
        phi_m = 5.0 ^ ((celsius-24)/10)
        phi_h = 3.0 ^ ((celsius-24)/10)
	
	TABLE m_inf, tau_m, h_inf, tau_h
	DEPEND shift, phi_m, phi_h FROM -100 TO 30 WITH 13000 
        m_inf = 1.0 / ( 1 + exp((v + shift - v0_m_inf)/k_m_inf) )
        h_inf = 1.0 / ( 1 + exp((v + shift - v0_h_inf)/k_h_inf) )
	
        tau_m = ( C_tau_m + A_tau_m / ( exp((v+shift - v0_tau_m1)/ k_tau_m1) + exp((v+shift - v0_tau_m2)/k_tau_m2) ) ) / phi_m
        tau_h = ( C_tau_h + A_tau_h / ( exp((v+shift - v0_tau_h1)/k_tau_h1) + exp((v+shift - v0_tau_h2)/k_tau_h2) ) ) / phi_h
}
UNITSON

Loading data, please wait...