ModelDB is moving. Check out our new site at https://modeldb.science. The corresponding page is https://modeldb.science/267293.

Simulations of modulation of HCN channels in L5PCs (Mäki-Marttunen and Mäki-Marttunen, 2022)

 Download zip file 
Help downloading and running models
Accession:267293
"... In this work, we build upon existing biophysically detailed models of thick-tufted layer V pyramidal cells and model the effects of over- and under-expression of Ih channels as well as their neuromodulation by dopamine (gain of Ih function) and acetylcholine (loss of Ih function). We show that Ih channels facilitate the action potentials of layer V pyramidal cells in response to proximal dendritic stimulus while they hinder the action potentials in response to distal dendritic stimulus at the apical dendrite. We also show that the inhibitory action of the Ih channels in layer V pyramidal cells is due to the interactions between Ih channels and a hot zone of low voltage-activated Ca2+ channels at the apical dendrite. Our simulations suggest that a combination of Ih-enhancing neuromodulation at the proximal apical dendrite and Ih-inhibiting modulation at the distal apical dendrite can increase the layer V pyramidal excitability more than any of the two neuromodulators alone..."
Reference:
1 . Mäki-Marttunen T, Mäki-Marttunen V (2022) Excitatory and inhibitory effects of HCN channel modulation on excitability of layer V pyramidal cells Plos Comp Biol [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Neocortex layer 5 pyramidal cell;
Channel(s):
Gap Junctions:
Receptor(s): AMPA; NMDA; Gaba;
Gene(s):
Transmitter(s): Acetylcholine; Dopamine; Glutamate; Gaba;
Simulation Environment: NEURON;
Model Concept(s): Neuromodulation;
Implementer(s): Maki-Marttunen, Tuomo [tuomomm at uio.no];
Search NeuronDB for information about:  AMPA; NMDA; Gaba; Acetylcholine; Dopamine; Gaba; Glutamate; 
TITLE AMPA and NMDA receptor with short-term plasticity 


COMMENT
Conductance-based AMPA-NMDA synaptic current with Wang-type of short-term synaptic depression
Implementation by Tuomo Maki-Marttunen, 2016
Tuomo 2021: removed depression
ENDCOMMENT


NEURON {

        POINT_PROCESS AMPANMDA  
        RANGE gAMPAmax, gNMDAmax, MgCon
	RANGE E_Glu, tau_sAMPA, tau_sNMDA, tau_xNMDA, alphas
        RANGE i, i_AMPA, i_NMDA, g_AMPA, g_NMDA, sAMPA, sNMDA, xNMDA
        NONSPECIFIC_CURRENT i, i_AMPA,i_NMDA

}

PARAMETER {

	gAMPAmax = 0.01  (uS)
	gNMDAmax = 0.007 (uS)
	MgCon = 0.69     
	mggate

	E_Glu = 0       (mV)
	tau_sAMPA = 2   (ms)
	tau_sNMDA = 100 (ms)
	tau_xNMDA = 2   (ms)
	alphas = 0.5    (kHz)

}

ASSIGNED {

        v (mV)
        i (nA)
	i_AMPA (nA)
	i_NMDA (nA)
        g_AMPA (uS)
	g_NMDA (uS)
}

STATE {

        sAMPA       : AMPA state variable to construct the single-exponential profile - decays with conductance tau_sAMPA
	sNMDA       : NMDA state variable to construct the dual-exponential profile - decays with conductance tau_sAMPA
        xNMDA       : NMDA state variable to construct the dual-exponential profile - decays with conductance tau_xAMPA
}

INITIAL{

	sAMPA = 0
	sNMDA = 0
	xNMDA = 0
        
}

BREAKPOINT {

        SOLVE state METHOD cnexp
        if (sNMDA > 1) { :Do not allow larger values than 1
          sNMDA = 1
        }
	mggate = 1 / (1 + exp(0.062 (/mV) * -(v)) * (MgCon / 3.57 (mM))) :mggate kinetics - Jahr & Stevens 1990
        g_AMPA = gAMPAmax*sAMPA          :compute time varying conductance
	g_NMDA = gNMDAmax*sNMDA * mggate :compute time varying conductance using mggate kinetics
        i_AMPA = g_AMPA*(v-E_Glu) :compute the AMPA driving force based on the time varying conductance, membrane potential, and AMPA reversal
	i_NMDA = g_NMDA*(v-E_Glu) :compute the NMDA driving force based on the time varying conductance, membrane potential, and NMDA reversal
	i = i_AMPA + i_NMDA
}

DERIVATIVE state{

        sAMPA' = -sAMPA/tau_sAMPA
	sNMDA' = -sNMDA/tau_sNMDA + alphas*xNMDA*(1-sNMDA)
        xNMDA' = -xNMDA/tau_xNMDA
}


:NET_RECEIVE (weight, Pv, Pr, u, tsyn (ms)){
NET_RECEIVE (weight){
	
        sAMPA = sAMPA + 1
	xNMDA = xNMDA + 1
        if (sAMPA > 1) { :Do not allow larger values than 1
          sAMPA = 1
        }
}

Loading data, please wait...