Complex CA1-neuron to study AP initiation (Wimmer et al. 2010)

 Download zip file 
Help downloading and running models
Accession:123927
Complex model of a pyramidal CA1-neuron, adapted from Royeck, M., et al. Role of axonal NaV1.6 sodium channels in action potential initiation of CA1 pyramidal neurons. Journal of neurophysiology 100, 2361-2380 (2008). It contains a biophysically realistic morphology comprising 265 compartments (829 segments) and 15 different distributed Ca2+- and/or voltage-dependent conductances.
Reference:
1 . Wimmer VC, Reid CA, Mitchell S, Richards KL, Scaf BB, Leaw BT, Hill EL, Royeck M, Horstmann MT, Cromer BA, Davies PJ, Xu R, Lerche H, Berkovic SF, Beck H, Petrou S (2010) Axon initial segment dysfunction in a mouse model of genetic epilepsy with febrile seizures plus. J Clin Invest 120:2661-71 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Hippocampus CA1 pyramidal GLU cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I N; I T low threshold; I p,q; I A; I K; I K,leak; I M; I h; I K,Ca; I Calcium;
Gap Junctions:
Receptor(s):
Gene(s): Nav SCN1B;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Detailed Neuronal Models; Epilepsy;
Implementer(s): Horstmann, Marie-Therese [mhorstma at uni-bonn.de];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; I Na,p; I Na,t; I L high threshold; I N; I T low threshold; I p,q; I A; I K; I K,leak; I M; I h; I K,Ca; I Calcium;
UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)

: hier eigene Befehle
        (molar) = (1/liter)
        (mM) = (millimolar)

	F = 96485 (coul)
	R = 8.3134 (joule/degC)
}

PARAMETER {
	v (mV)
	celsius 		(degC)
	PcanpqBar=.000154 (cm/s)
	ki=.00002 (mM)
	cai=5.e-5 (mM)
	cao = 10  (mM)
	q10m=11.45
	q10Ampl=2.1
}


NEURON {
	SUFFIX CAnpq
	USEION ca READ cai,cao WRITE ica
        RANGE PcanpqBar
        GLOBAL minf,taum
}

STATE {
	m
}

ASSIGNED {
	ica (mA/cm2)
        Pcanpq  (cm/s) 
        minf
        taum
}

INITIAL {
        rates(v)
        m = minf
}

UNITSOFF
BREAKPOINT {
	LOCAL qAmpl
	
	qAmpl = q10Ampl^((celsius - 21)/10)
	
	SOLVE states METHOD cnexp
	Pcanpq = qAmpl*PcanpqBar*m*m
	ica = Pcanpq*ghk(v,cai,cao)

}


FUNCTION ghk(v(mV), ci(mM), co(mM)) (mV) {
        LOCAL a

        a=2*F*v/(R*(celsius+273.15)*1000)
	
        ghk=2*F/1000*(co - ci*exp(a))*func(a)
}


FUNCTION func(a) {
	if (fabs(a) < 1e-4) {
		func = -1 + a/2
	}else{
		func = a/(1-exp(a))
	}
}

FUNCTION alpm(v(mV)) {
	:TABLE FROM -150 TO 150 WITH 200
	alpm = 0.1967*(-1.0*(v-15)+19.88)/(exp((-1.0*(v-15)+19.88)/10.0)-1.0)
}

FUNCTION betm(v(mV)) {
	:TABLE FROM -150 TO 150 WITH 200
	betm = 0.046*exp(-(v-15)/20.73)
}



DERIVATIVE states {    
        rates(v)
        m' = (minf - m)/taum
}

PROCEDURE rates(v (mV)) { :callable from hoc
        LOCAL a, qm
	
        TABLE taum, minf FROM -150 TO 150 WITH 3000
        
        qm = q10m^((celsius - 22)/10)
        a = alpm(v)
        taum = 1/((a + betm(v))*qm)

        minf = 1/(1+exp(-(v+11)/5.7)) ^0.5 
}

UNITSON











Loading data, please wait...