TRPM8-dependent dynamic response in cold thermoreceptors (Olivares et al. 2015)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:182988
This model reproduces the dynamic response of cold thermoreceptors, transiently changing the firing rate upon heating or cooling. It also displays the 'static' or adapted firing patterns observed in these receptors.
Reference:
1 . Olivares E, Salgado S, Maidana JP, Herrera G, Campos M, Madrid R, Orio P (2015) TRPM8-Dependent Dynamic Response in a Mathematical Model of Cold Thermoreceptor. PLoS One 10:e0139314 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Dorsal Root Ganglion (DRG) cell; Dorsal Root Ganglion cell: cold sensing;
Channel(s): I Na,p; I Na,t; I K; I K,Ca; I trp; I TRPM8;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; Python;
Model Concept(s): Bursting; Temporal Pattern Generation; Oscillations; Homeostasis; Temperature; Sensory coding;
Implementer(s): Orio, Patricio [patricio.orio at uv.cl];
Search NeuronDB for information about:  I Na,p; I Na,t; I K; I K,Ca; I trp; I TRPM8;
/
OlivaresEtAl2015
Neuron
data
dr.mod
ou.mod
sdsr.mod
trpm8.mod
mosinit.hoc
                            
TITLE TRPM8 current plus calcium adaptation
: based on Voets 2004 with some modifications to resemble data from Malkia 2007
: Written by Orio, P. & Olivares E.  - December 2014
:

NEURON {
    SUFFIX trpm8
    NONSPECIFIC_CURRENT im8
    RANGE caM8, DVinf, vhalf, DV
    RANGE p_ca, accel
    RANGE em8, gm8, am8, C, z
}


UNITS {
    R = (k-mole) (joule/degC)
    (mA) = (milliamp)
    (mV) = (millivolt)
    (mol) = (1)
    (molar) = (1/liter)
    (mM) = (millimolar)
} 

CONSTANT {
    F = 96500        (coulomb)        : moles do not appear in units
}


PARAMETER {
    gm8 =0.0035        (mho/cm2)
    dE = 9e3        (joule)
    C = 67
    z = 0.65

    em8 = 0            (mV)
    DVmin = 0        (mV)
    DVmax = 200            (mV)
    Kca = 0.0005        (mM)

    p_ca=0.01    
    tauca=15000        (ms)
    taudv = 80000    (ms)
    d = 1           (micron)
    accel = 1
    n = 1
}


STATE {
    caM8        (mM)
    DV            (mV)
}

INITIAL {
    caM8=0
    DV= DVinf
}

ASSIGNED {
    celsius    (degC)
    v       (mV)
    im8        (mA/cm2)
    vhalf    (mV)
    am8
    DVinf        (mV)
    
}

BREAKPOINT {
    SOLVE states METHOD cnexp

    vhalf=(1000)*(C*R*celsius - dE)/(z*F)+DV
    
    am8=1/(1+exp(-z*F*(v-vhalf)/((1000)*R*(celsius+273.15))))
    im8=gm8*am8*(v-em8)
}

DERIVATIVE states {
    caM8' = accel*( - p_ca * (10000) * im8 / (2 * F * d) - caM8 / tauca)
    DVinf = DVmin+(DVmax-DVmin)*(caM8)/(Kca+caM8)
    DV' = accel*(DVinf-DV)/taudv
}

Loading data, please wait...