Discharge hysteresis in motoneurons (Powers & Heckman 2015)

 Download zip file 
Help downloading and running models
Accession:183949
"Motoneuron activity is strongly influenced by the activation of persistent inward currents (PICs) mediated by voltage-gated sodium and calcium channels. ... It has recently been suggested that a number of factors other than PIC can contribute to delta F (firing rate differences between motoneurons) values, including mechanisms underlying spike frequency adaptation and spike threshold accommodation. In the present study, we used a set of compartmental models representing a sample of 20 motoneurons with a range of thresholds to investigate how several different intrinsic motoneuron properties can potentially contribute to variations in F values. ... Our results indicate that, although other factors can contribute, variations in discharge hysteresis and delta F values primarily reflect the contribution of dendritic PICs to motoneuron activation.
Reference:
1 . Powers RK, Heckman CJ (2015) Contribution of intrinsic motoneuron properties to discharge hysteresis and its estimation based on paired motor unit recordings. A simulation study. J Neurophysiol 114:184-198 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Spinal cord lumbar motor neuron alpha cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I K; I M; I K,Ca; I_AHP; I Calcium; I Sodium;
Gap Junctions:
Receptor(s):
Gene(s): Kv1.2 KCNA2; Kv1.9 Kv7.1 KCNQ1;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Spike Frequency Adaptation;
Implementer(s): Powers, Randy [rkpowers at u.washington.edu];
Search NeuronDB for information about:  Spinal cord lumbar motor neuron alpha cell; I Na,p; I Na,t; I L high threshold; I K; I M; I K,Ca; I Sodium; I Calcium; I_AHP;
/
Discharge_hysteresis
Model hoc files and output
README.txt
Gfluctdv.mod *
ghchan.mod *
kca2.mod *
KCNQ.mod *
kdrRL.mod *
km_hu.mod
kv1_gp.mod *
L_Ca.mod *
L_Ca_inact.mod *
mAHP.mod *
mAHPvt.mod
na3rp.mod *
naps.mod *
napsi.mod *
AHPlen.csv
FasterMis.csv
FR3cablepas.hoc
FRMot3dendNaHH.hoc
gramp.ses
HiDKCa.csv
init_3dend_gramp.hoc
LCai.csv
Napi.csv
pars2manyhocs.py *
ProxCa.csv
SetConductances2.hoc *
SlowM.csv
standard.csv
twobirampsdel.hoc *
                            
TITLE napsi		:modified to have slow inactivation described in Fleidervish and to make slope a global parameter
      			:further modified to have intermediate time course inactivation

NEURON {
	SUFFIX napsi
	USEION na READ ena WRITE ina
	RANGE  gbar, thegna, sh, ar,ari,minf,sinf,hinf,taui,taus
	GLOBAL mtau,vslope
}

PARAMETER {
	gbar = .0052085   	(mho/cm2)
	sh = 0  (mV)
	vslope=6.8   (mV)	:activation slope
	mtau = 1 (ms)
	ena		(mV)       :must be explicitly defined in hoc     
        a0s=0.001	(/ms)	
        b0s=0.0034	(/ms)
        asvh=-85	(mV) 
        bsvh=-17	(mV) 
        avs=30		(mV)
        bvs=10		(mV)
        ar=1		(1)		: 1=no inact., 0=max inact.
        a0i=0.01	(/ms)	
        b0i=0.034	(/ms)
        aivh=-85	(mV) 
        bivh=-17	(mV) 
        avi=30		(mV)
        bvi=10		(mV)
        ari=1		(1)		: 1=no inact., 0=max inact.
	celsius (degC)
	v 		(mV)
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(pS) = (picosiemens)
	(um) = (micron)
} 

ASSIGNED {
	ina 		(mA/cm2)
	thegna		(mho/cm2)
	minf 	
	sinf
	hinf
	taus (ms)
	taui (ms)
}
 

STATE { m s h}

UNITSOFF

BREAKPOINT {
    SOLVE states METHOD cnexp
	        		
	thegna =gbar*m*s*h   
	ina = thegna * (v - ena)
	} 

INITIAL {
	trates(v,ar,ari,sh)
	m=minf  
	s=sinf
	h=hinf
}

DERIVATIVE states {   
    	trates(v,ar,ari,sh)
        s' = (sinf - s)/taus
	m' = (minf-m)/mtau
	h' = (hinf-h)/taui
}

PROCEDURE trates(vm,a1,a2,sh2) {  
        LOCAL   c,ci  

	minf = (1/(1+exp(-(vm+52.3-sh2)/vslope)))      	
        taus = 1/(alps(vm)+bets(vm))
        taui = 1/(alpi(vm)+beti(vm))
	c=alps(vm)*taus
        sinf = c+a1*(1-c)
	ci=alpi(vm)*taui
        hinf = ci+a2*(1-ci)
 }




FUNCTION alps(v(mV)) {  
  alps = a0s*exp((asvh-v)/avs)
}

FUNCTION bets(v(mV)) {
  bets = b0s/(exp((bsvh-v)/bvs)+1)
}

FUNCTION alpi(v(mV)) {  
  alpi = a0i*exp((aivh-v)/avi)
}

FUNCTION beti(v(mV)) {
  beti = b0i/(exp((bivh-v)/bvi)+1)
}

UNITSON

Loading data, please wait...