Computer models of corticospinal neurons replicate in vitro dynamics (Neymotin et al. 2017)

 Download zip file 
Help downloading and running models
Accession:195615
"Corticospinal neurons (SPI), thick-tufted pyramidal neurons in motor cortex layer 5B that project caudally via the medullary pyramids, display distinct class-specific electrophysiological properties in vitro: strong sag with hyperpolarization, lack of adaptation, and a nearly linear frequency-current (FI) relationship. We used our electrophysiological data to produce a pair of large archives of SPI neuron computer models in two model classes: 1. Detailed models with full reconstruction; 2. Simplified models with 6 compartments. We used a PRAXIS and an evolutionary multiobjective optimization (EMO) in sequence to determine ion channel conductances. ..."
Reference:
1 . Neymotin SA, Suter BA, Dura-Bernal S, Shepherd GM, Migliore M, Lytton WW (2017) Optimizing computer models of corticospinal neurons to replicate in vitro dynamics. J Neurophysiol 117:148-162 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Neocortex;
Cell Type(s): Neocortex M1 L5B pyramidal pyramidal tract cell; Neocortex primary motor area pyramidal layer 5 corticospinal cell;
Channel(s): I A; I h; I_KD; I K,Ca; I L high threshold; I Na,t; I N; Ca pump; Kir;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; Python;
Model Concept(s): Parameter Fitting; Activity Patterns; Active Dendrites; Detailed Neuronal Models; Simplified Models;
Implementer(s): Suter, Benjamin ; Neymotin, Sam [samn at neurosim.downstate.edu]; Dura-Bernal, Salvador [salvadordura at gmail.com]; Forzano, Ernie ;
Search NeuronDB for information about:  Neocortex M1 L5B pyramidal pyramidal tract cell; I Na,t; I L high threshold; I N; I A; I h; I K,Ca; I_KD; Ca pump; Kir;
/
spidemo
data
readme.html
cadad.mod
cal2.mod
can_mig.mod
h_kole.mod
kap_BS.mod
kBK.mod
kdmc_BS.mod
kdr_BS.mod
misc.mod *
nax_BS.mod
savedist.mod
vecst.mod *
archfig.py
axonMorph.py
BS0284.ASC
BS0409.ASC
conf.py
Fig6.py
figure_1.png
misc.h
morph.py
mosinit.py
PTcell.BS0284.cfg *
PTcell.BS0409.cfg
PTcell.cfg *
sim.py
SPI6.cfg
SPI6.py
utils.py
                            
: from https://senselab.med.yale.edu/ModelDB/ShowModel.cshtml?model=168148&file=/stadler2014_layerV/kBK.mod
TITLE large-conductance calcium-activated potassium channel (BK)
	:Mechanism according to Gong et al 2001 and Womack&Khodakakhah 2002,
	:adapted for Layer V cells on the basis of Benhassine&Berger 2005.
	:NB: concentrations in mM
	
NEURON {
	SUFFIX kBK
	USEION k READ ek WRITE ik
	USEION ca READ cai
	RANGE gpeak, gkact, caPh, caPk, caPmax, caPmin
	RANGE caVhh, CaVhk, caVhmax, caVhmin, k, tau
        GLOBAL pinfmin : cutoff - if pinf < pinfmin, set to 0.; by default cutoff not used (pinfmin==0)
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(molar) = (1/liter)
	(mM) 	= (millimolar)
}


PARAMETER {
		:maximum conductance (Benhassine 05)
	gpeak   = 268e-4	(mho/cm2) <0, 1e9>
	
	                                    : Calcium dependence of opening probability (Gong 2001)
	caPh    = 2e-3     (mM)             : conc. with half maximum open probaility
	caPk    = 1                         : Steepness of calcium dependence curve
	caPmax  = 1                         : max and
	caPmin  = 0                         : min open probability
		
	                                    : Calcium dependence of Vh shift (Womack 2002)
	caVhh   = 2e-3    (mM)              : Conc. for half of the Vh shift
	caVhk   = -0.94208                  : Steepness of the Vh-calcium dependence curve
	caVhmax = 155.67 (mV)               : max and
	caVhmin = -46.08 (mV)               : min Vh
	
	                                    : Voltage dependence of open probability (Gong 2001)
	                                    : must not be zero
	k       = 17	(mV)
	
	                                    : Timeconstant of channel kinetics
	                                    : no data for a description of a calcium&voltage dependence
	                                    : some points (room temp) in Behassine 05 & Womack 02
	tau     = 1 (ms) <1e-12, 1e9>
	scale   = 100                       : scaling to incorporate higher ca conc near ca channels
        
        pinfmin = 0.0                       : cutoff for pinf - less than that set pinf to 0.0

} 	


ASSIGNED {
	v 		(mV)
	ek		(mV)
	ik 		(mA/cm2)
    	cai  		(mM)
	caiScaled	(mM)
	pinf		(1)
}


STATE {
        p
}

BREAKPOINT {
	SOLVE states METHOD cnexp
	ik = gpeak*p* (v - ek)
}

DERIVATIVE states {     
        rate(v, cai)
        p' =  (pinf - p)/tau
}

INITIAL {     
        rate(v, cai)
        p = pinf
}

PROCEDURE rate(v(mV), ca(mM))  {
        caiScaled = ca*scale	
        pinf = P0ca(caiScaled) / ( 1 + exp( (Vhca(caiScaled)-v)/k ) )
        if(pinf < pinfmin) { pinf = 0.0 }
}

FUNCTION P0ca(ca(mM)) (1) {
		
	if (ca < 1E-18) { 		:check for division by zero		
	P0ca = caPmin
	} else {
	P0ca = caPmin + ( (caPmax - caPmin) / ( 1 + (caPh/ca)^caPk ))
	}
}

FUNCTION Vhca(ca(mM)) (mV) {
		
	if (ca < 1E-18) {		:check for division by zero
	Vhca = caVhmax
	} else {
	Vhca = caVhmin + ( (caVhmax - caVhmin ) / ( 1 + ((caVhh/ca)^caVhk)) )
	}
}	


Loading data, please wait...