TTX-R Na+ current effect on cell response (Herzog et al 2001)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:86537
"Small dorsal root ganglion (DRG) neurons, which include nociceptors, express multiple voltage-gated sodium currents. In addition to a classical fast inactivating tetrodotoxin-sensitive (TTX-S) sodium current, many of these cells express a TTX-resistant (TTX-R) sodium current that activates near -70 mV and is persistent at negative potentials. To investigate the possible contributions of this TTX-R persistent (TTX-RP) current to neuronal excitability, we carried out computer simulations using the Neuron program with TTX-S and -RP currents, fit by the Hodgkin-Huxley model, that closely matched the currents recorded from small DRG neurons. ..." See paper for more and details.
Reference:
1 . Herzog RI, Cummins TR, Waxman SG (2001) Persistent TTX-resistant Na+ current affects resting potential and response to depolarization in simulated spinal sensory neurons. J Neurophysiol 86:1351-64 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Dorsal Root Ganglion (DRG) cell;
Channel(s): I Na,p; I Na,t; I K;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.1 SCN1A; Nav1.6 SCN8A; Nav1.7 SCN9A; Nav1.8 SCN10A; Nav1.9 SCN11A SCN12A;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Ion Channel Kinetics; Nociception;
Implementer(s): Morse, Tom [Tom.Morse at Yale.edu];
Search NeuronDB for information about:  I Na,p; I Na,t; I K;
: kdr.mod is the delayed rectifier K+ current from
: Herzoz, Cummins, and Waxman '01, parameter assignments and formula's
: from page 1353
: implemented by Tom Morse version 2/25/07

NEURON {
	SUFFIX kdr
	NONSPECIFIC_CURRENT i
	RANGE gbar, ek
	RANGE tau_n, n
}

UNITS {
	(S) = (siemens)
	(mV) = (millivolts)
	(mA) = (milliamp)
}

PARAMETER {
	gbar = 0.0021 (S/cm2)
	: ek=-70 (mV) : this does not represent value in paper
      ek = -92.34 (mV) : correction by Tom Andersson
: Baker 2005 values
	A_anF = 0.001265 (/ms) : 0.00798 Baker '05 : A for alpha n
	B_anF = 14.273 (mV) : 72.2 Baker '05
	C_anF = 10 (mV) : 1.1 Baker '05

: Baker '05 uses different (parameterized) function than below beta_n
	A_bnF = 0.125 (/ms): A for beta n
	B_bnF = 55 (mV)
	C_bnF = -2.5 (mV)

: Bostok et al. 1991 values
:	A_anF = 0.129 (/ms) : A for alpha n
:	B_anF = -53 (mV)
:	C_anF = 10 (mV)

:	A_bnF = 0.324 (/ms) : A for beta n
:	B_bnF = -78 (mV)
:	C_bnF = 10 (mV)
}

ASSIGNED {
	v	(mV) : NEURON provides this
	i	(mA/cm2)
	g	(S/cm2)
	tau_n	(ms)
	ninf
}

STATE { n }

BREAKPOINT {
	SOLVE states METHOD cnexp
	g = gbar * n
	i = g * (v-ek)
}

INITIAL {
	: assume that equilibrium has been reached
	n = alphan(v)/(alphan(v)+betan(v))
}

DERIVATIVE states {
	rates(v)
	n' = (ninf - n)/tau_n
}

FUNCTION alphan(Vm (mV)) (/ms) {
	if (-Vm-B_anF != 0) {
		alphan=A_anF*(Vm+B_anF)/(1-exp((-Vm-B_anF)/C_anF))
	} else {
		alphan=A_anF*C_anF
	}
}

FUNCTION betan(Vm (mV)) (/ms) {
	betan=A_bnF*exp((Vm+B_bnF)/C_bnF)
}

FUNCTION rates(Vm (mV)) (/ms) {
	tau_n = 1.0 / (alphan(Vm) + betan(Vm))
:	ninf = alphan(Vm) * tau_n : this line does not reflect p. 1353
      ninf = 1/(1+exp((Vm+14.62)/-18.38)) : correction by Tom Andersson
}

Loading data, please wait...