Mammalian Ventricular Cell (Beeler and Reuter 1977)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:97863
This classic model of ventricular myocardial fibres was implemented by Francois Gannier. "... Four individual components of ionic current were formulated mathematically in terms of Hodgkin-Huxley type equations. The model incorporates two voltage- and time-dependent inward currents, the excitatory inward sodium current, illa, and a secondary or slow inward current, is, primarily carried by calcium ions. A time-independent outward potassium current, iK1, exhibiting inward-going rectification, and a voltage- and time-dependent outward current, i.1, primarily carried by potassium ions, are further elements of the model...."
Reference:
1 . Beeler GW, Reuter H (1977) Reconstruction of the action potential of ventricular myocardial fibres. J Physiol 268:177-210 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Cardiac ventricular cell;
Channel(s): I K; I Sodium; I Calcium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Ion Channel Kinetics; Action Potentials;
Implementer(s): Gannier, Francois [francois.gannier at univ-tours.fr];
Search NeuronDB for information about:  I K; I Sodium; I Calcium; I Potassium;
TITLE Cardiac sodium current
: from BEELER & REUTER, J.Physiol, 1977

NEURON {
	SUFFIX INa
	USEION na READ ena WRITE ina
	RANGE  gnabar, gnac, ina, Tauact, Tauinactf, Tauinacts
	GLOBAL minf, hinf, ninf, mtau, htau, ntau
}

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(mM) = (milli/liter)
}

PARAMETER {
	gnabar=0.004 (S/cm2) <0,1e9> 
	gnac = 0.000003 (S/cm2)
	Tauact= 1 (ms) 
	Tauinactf=1 (ms) 
	Tauinacts=1 (ms)
}

STATE { : m h j
	m h n 
}

ASSIGNED {
	v (mV)
	celsius (degC) : 37
	ena (mV)
	ina (mA/cm2)
	minf hinf ninf
	mtau (ms)
	htau (ms)
	ntau (ms)  
}
LOCAL k
INITIAL { : m h j
	rates(v)
	m = minf
	h = hinf
	n = ninf
}

BREAKPOINT {
	SOLVE states METHOD derivimplicit
	ina = (gnabar*m*m*m*h*n + gnac)*(v - ena)
}

DERIVATIVE states {
	rates(v)
	m' = (minf - m)/mtau
	h' = (hinf - h)/htau
	n' = (ninf - n)/ntau
}
UNITSOFF
FUNCTION alp(v(mV),i) (/ms) { 
:LOCAL q10 :order m,h,j
	if (i==0) {
		alp = (- v - 47)/(exp(-0.1*(v + 47))-1)
	}else if (i==1){
		alp = 0.126*exp(-0.25*(v + 77))
	}else if (i==2){
		alp = 0.055*exp(-0.25*(v + 78))/(exp(-0.2*(v + 78))+1)
	}
}

FUNCTION bet(v(mV),i)(/ms) { 
:LOCAL q10 :order m,h,n
	if (i==0) {
		bet = 40*exp(-0.056*(v + 72))
	}else if (i==1){
		bet = 1.7/(exp(-0.082*(v + 22.5))+1)
	}else if (i==2){
		bet = 0.3/(exp(-0.1*(v + 32))+1)
	}
}

PROCEDURE rates(v) { : m h j
LOCAL a, b
	:TABLE minf, hinf, ninf, mtau, htau, ntau DEPEND celsius FROM -100 TO 100 WITH 200
	a = alp(v,0)  b=bet(v,0)
	mtau = 1/(a + b)
	minf = a/(a + b)
	a = alp(v,1)  b = bet(v,1)
	htau = 1/(a + b)
	hinf = a/(a + b)
	a = alp(v,2)  b=bet(v,2)
	ntau = 1/(a + b)
	ninf = a/(a + b)
}
UNITSON

Loading data, please wait...