D2 dopamine receptor modulation of interneuronal activity (Maurice et al. 2004)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:98005
"... Using a combination of electrophysiological, molecular, and computational approaches, the studies reported here show that D2 dopamine receptor modulation of Na+ currents underlying autonomous spiking contributes to a slowing of discharge rate, such as that seen in vivo. Four lines of evidence support this conclusion. ... Fourth, simulation of cholinergic interneuron pacemaking revealed that a modest increase in the entry of Na+ channels into the slow-inactivated state was sufficient to account for the slowing of pacemaker discharge. These studies establish a cellular mechanism linking dopamine and the reduction in striatal cholinergic interneuron activity seen in the initial stages of associative learning." See paper for more and details.
Reference:
1 . Maurice N, Mercer J, Chan CS, Hernandez-Lopez S, Held J, Tkatch T, Surmeier DJ (2004) D2 dopamine receptor-mediated modulation of voltage-dependent Na+ channels reduces autonomous activity in striatal cholinergic interneurons. J Neurosci 24:10289-301 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Neostriatum interneuron ACh cell;
Channel(s): I Na,t; I K; I h; I K,Ca; I Sodium; I Calcium; I Potassium;
Gap Junctions:
Receptor(s): D2;
Gene(s): D2 DRD2; HCN1; HCN2;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Action Potentials; Parkinson's;
Implementer(s): Held, Joshua [j-held at northwestern.edu];
Search NeuronDB for information about:  Neostriatum interneuron ACh cell; D2; I Na,t; I K; I h; I K,Ca; I Sodium; I Calcium; I Potassium;
: KV2_CH.MOD
: KV2 for Cholinergic Interneuron

NEURON {
	SUFFIX kv2_ch
	USEION k READ ek WRITE ik
	RANGE g, ik, an, bn, gbar
}

UNITS {
	(mV) = (millivolt)
	(S) = (siemens)
	(mA) = (milliamp)
}

PARAMETER {
	gbar = 1	(S/cm2)
}

ASSIGNED {
	v	(mV)
	ek	(mV)
	g	(S/cm2)
	ik	(mA/cm2)

	an	(1/ms)
	bn	(1/ms)
	kf1	(1/ms)
	kb1	(1/ms)
	kf2	(1/ms)
	kb2	(1/ms)
	kf3	(1/ms)
	kb3	(1/ms)
	kf4	(1/ms)
	kb4	(1/ms)
}

STATE {
	c1
	c2
	c3
	c4
	o
}

BREAKPOINT {
	SOLVE kin METHOD sparse
	g = gbar*o
	ik = g*(v-ek)
}

INITIAL {
	SOLVE kin STEADYSTATE sparse
}



KINETIC kin{
	rates(v)
	~ c4 <-> c3     (kf1,kb1)
	~ c3 <-> c2     (kf2,kb2)
	~ c2 <-> c1     (kf3,kb3)
	~ c1 <-> o      (kf4,kb4)
	CONSERVE c4+c3+c2+c1+o=1
}


PROCEDURE rates(v(millivolt)) {
	an = (51.743 (1/ms) - (0.612 (1/ms-mV))*v)/(exp((-84.54 (mV)+v)/-11.84 (mV)) - 1)
	bn = (0.0051 (1/ms) )/exp(v/22.02 (mV))

	kf1 = 4*an
	kb1 = bn
	kf2 = 3*an
	kb2 = 2*bn
	kf3 = 2*an
	kb3 = 3*bn
	kf4 = an
	kb4 = 4*bn
}

Loading data, please wait...