Nav1.6 sodium channel model in globus pallidus neurons (Mercer et al. 2007)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:105385
Model files for the paper Mercer JN, Chan CS, Tkatch T, Held J, Surmeier DJ. Nav1.6 sodium channels are critical to pacemaking and fast spiking in globus pallidus neurons.,J Neurosci. 2007 Dec 5;27(49):13552-66.
Reference:
1 . Mercer JN, Chan CS, Tkatch T, Held J, Surmeier DJ (2007) Nav1.6 sodium channels are critical to pacemaking and fast spiking in globus pallidus neurons. J Neurosci 27:13552-66 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Globus pallidus neuron;
Channel(s): I Na,p; I Na,t; I K; I h; I K,Ca; I Sodium; I Calcium; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.6 SCN8A;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Action Potentials; Parkinson's;
Implementer(s): Held, Joshua [j-held at northwestern.edu];
Search NeuronDB for information about:  I Na,p; I Na,t; I K; I h; I K,Ca; I Sodium; I Calcium; I Potassium;
NEURON {
	SUFFIX cal_gp
	USEION ca READ cai,cao WRITE ica
        RANGE  gbar,ica,g
	GLOBAL vhm, vcm
	GLOBAL Ctm, atm, btm, tm0, vhtm
        GLOBAL minf,tau
}

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	FARADAY = (faraday)  (kilocoulombs)
	R = (k-mole) (joule/degC)
	KTOMV = .0853 (mV/degC)
	(S) = (siemens)
	(mM) = (milli/liter)
}

PARAMETER {
	v		(mV)
	celsius	(degC)
	gbar = .003 	(S/cm2)
	ki = .001 	(mM)
	cai 		(mM)
	cao 		(mM)
        tfa = 1
	vhm = -40	(mV)
	vcm = 12	(mV)
	Ctm = 3		(ms)
	atm = 12	(mV)
	btm = 11	(mV)
	tm0 = 0		(ms)
	vhtm = -2	(mV)
}

STATE { m }

ASSIGNED {
	ica	(mA/cm2)
        g	(S/cm2)
        minf
        tau	(ms)
	a	(1/ms)
}

BREAKPOINT {
	SOLVE state METHOD cnexp
	g = gbar*m*m*h2(cai)
	ica  = g*ghk(v,cai,cao)
}

INITIAL {
	rate(v)
	m = minf
}

FUNCTION h2(cai(mM)) {
	h2 = ki/(ki+cai)
}

FUNCTION ghk(v(mV), ci(mM), co(mM)) (mV) {
        LOCAL nu,f

        f = KTF(celsius)/2
        nu = v/f
        ghk=-f*(1. - (ci/co)*exp(nu))*efun(nu)
}

FUNCTION KTF(celsius (degC)) (mV) {
        KTF = ((25 (mV) /293.15 (degC) )*(celsius + 273.15 (degC) ))
}

FUNCTION efun(z) {
	if (fabs(z) < 1e-4) {
		efun = 1 - z/2
	}else{
		efun = z/(exp(z) - 1)
	}
}

FUNCTION alp(v(mV)) (1/ms) {
	TABLE FROM -150 TO 150 WITH 200
	alp = 15.69 (1/mV-ms) *(-1.0*v+81.5 (mV) )/(exp((-1.0*v+81.5 (mV) )/10.0 (mV) )-1.0)
}

FUNCTION bet(v(mV)) (1/ms) {
	TABLE FROM -150 TO 150 WITH 200
	bet = 0.29 (1/ms) *exp(-v/10.86 (mV) )
}

DERIVATIVE state {
        rate(v)
        m' = (minf - m)/tau
}

PROCEDURE rate(v (mV)) { :callable from hoc
	LOCAL q10
	q10 = 3^((celsius - 22 (degC))/10 (degC) )
a    = alp(v)
        :tau  = 1/(tfa*(a + bet(v)))
        :minf = tfa*a*tau
	tau = q10*(Ctm/(exp((v-vhtm)/atm) + exp((vhtm-v)/btm)) + tm0)
	minf = 1/(1+exp(-(v-vhm)/vcm))
}

Loading data, please wait...