Afferent Integration in the NAcb MSP Cell (Wolf et al. 2005)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:112834
"We describe a computational model of the principal cell in the nucleus accumbens (NAcb), the medium spiny projection (MSP) neuron. The model neuron, constructed in NEURON, includes all of the known ionic currents in these cells and receives synaptic input from simulated spike trains via NMDA, AMPA, and GABAA receptors. ... results suggest that afferent information integration by the NAcb MSP cell may be compromised by pathology in which the NMDA current is altered or modulated, as has been proposed in both schizophrenia and addiction."
Reference:
1 . Wolf JA, Moyer JT, Lazarewicz MT, Contreras D, Benoit-Marand M, O'Donnell P, Finkel LH (2005) NMDA/AMPA ratio impacts state transitions and entrainment to oscillations in a computational model of the nucleus accumbens medium spiny projection neuron. J Neurosci 25:9080-95 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Nucleus accumbens spiny projection neuron;
Channel(s): I Na,p; I Na,t; I L high threshold; I N; I T low threshold; I A; I h; I K,Ca; I Krp; I R; I Q;
Gap Junctions:
Receptor(s): GabaA; AMPA; NMDA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Oscillations; Schizophrenia; Addiction;
Implementer(s): Wolf, John A. [johnwolf at warpmail.net]; Moyer, Jason [jtmoyer at seas.upenn.edu];
Search NeuronDB for information about:  GabaA; AMPA; NMDA; I Na,p; I Na,t; I L high threshold; I N; I T low threshold; I A; I h; I K,Ca; I Krp; I R; I Q;
/
nacb_msp
tau_tables
readme.html
AMPA.mod
bkkca.mod *
cadyn.mod *
caL.mod *
caL13.mod *
caldyn.mod
can.mod *
caq.mod *
car.mod *
cat.mod *
GABA.mod *
kaf.mod *
kas.mod *
kir.mod *
krp.mod *
naf.mod *
nap.mod *
NMDA.mod
skkca.mod *
stim.mod *
_run_me.hoc
all_tau_vecs.hoc *
baseline_values.txt *
basic_procs.hoc
create_mspcells.hoc *
current_clamp.ses *
make_netstims.hoc
mosinit.hoc *
msp_template.hoc
nacb_main.hoc
netstims_template.hoc *
screenshot.jpg
screenshot2.jpg
stimxout_jns_sqwave.dat
synapse_templates.hoc
                            
TITLE BK KCA channel for nucleus accumbens model - old version!

: large conductance kca channel

COMMENT Equations from 
		  Shao L.R., Halvorsrud R., Borg-Graham L., Storm J.F. The role
		  of BK-type Ca2_-dependent K+ channels in spike broadening
		  during repetitive firing in rat hippocampal pyramidal cells
		  J.Physiology (1999),521:135-146
		  
		  The Krasnow Institute
		  George Mason University

Copyright	  Maciej Lazarewicz, 2001
		  (mlazarew@gmu.edu)
		  All rights reserved.
ENDCOMMENT

NEURON {
	SUFFIX bkkca
	USEION k READ ek WRITE ik
	USEION ca READ cai
	RANGE  gkbar,ik, q
}

UNITS {
	(molar) = (1/liter)
	(mM)	= (millimolar)
	(S)  	= (siemens)
	(mA) 	= (milliamp)
	(mV) 	= (millivolt)
}

PARAMETER {
	turnOffinact = 1 (1)
    gkbar	= 0.001 (S/cm2)
    q = 1
	celsius		 (degC)
}

ASSIGNED {
        v       (mV)
        cai	(mM)
	ik	(mA/cm2)
	k1	(/ms)
	k2	(/ms)
	k3	(/ms)
	k4	(/ms)
	q10	(1)
	ek 	(mV)
}

STATE { cst ost ist }

BREAKPOINT { 
	SOLVE kin METHOD sparse
	ik = gkbar * ost * ( v - ek ) 
}

INITIAL {
	SOLVE kin STEADYSTATE sparse
}

KINETIC kin {
	rates(v)
	~cst<->ost  (k3,k4)
	~ost<->ist  (k1,0.0)
	~ist<->cst  (k2,0.0)
	CONSERVE cst+ost+ist=1
}

PROCEDURE rates( v(mV)) {
	 k1=alp( 0.1, v,  -10.0,   1.0 )
	 k2=alp( 0.1, v, -120.0, -10.0 )
	 k3=alpha( 0.001, 1.0, v, -20.0, 7.0 ) *1.0e8* ( cai*1.0(/mM) )^3
	 k4=alp( 0.01, v, -44.0,  -5.0 )
}

FUNCTION alpha( tmin(ms), tmax(ms), v(mV), vhalf(mV), k(mV) )(/ms){
        alpha = q / ( tmin + 1.0 / ( 1.0 / (tmax-tmin) + exp((v-vhalf)/k)*1.0(/ms) ) )
}

FUNCTION alp( tmin(ms), v(mV), vhalf(mV), k(mV) )(/ms){
        alp = q / ( tmin + exp( (v-vhalf) / k )*1.0(ms) )
}








Loading data, please wait...