Computer simulations of neuron-glia interactions mediated by ion flux (Somjen et al. 2008)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:113446
"... To examine the effect of glial K+ uptake, we used a model neuron equipped with Na+, K+, Ca2+ and Cl− conductances, ion pumps and ion exchangers, surrounded by interstitial space and glia. The glial membrane was either “passive”, incorporating only leak channels and an ion exchange pump, or it had rectifying K+ channels. We computed ion fluxes, concentration changes and osmotic volume changes. ... We conclude that voltage gated K+ currents can boost the effectiveness of the glial “potassium buffer” and that this buffer function is important even at moderate or low levels of excitation, but especially so in pathological states."
Reference:
1 . Somjen GG, Kager H, Wadman WJ (2008) Computer simulations of neuron-glia interactions mediated by ion flux. J Comput Neurosci 25:349-65 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Electrogenic pump; Glia;
Brain Region(s)/Organism:
Cell Type(s): Astrocyte;
Channel(s): I Na,p; I Na,t; I T low threshold; I A; I K; I K,Ca; Na/Ca exchanger; Na/K pump;
Gap Junctions:
Receptor(s): NMDA;
Gene(s):
Transmitter(s): Ions;
Simulation Environment: NEURON;
Model Concept(s): Epilepsy; Calcium dynamics; Sodium pump;
Implementer(s):
Search NeuronDB for information about:  NMDA; I Na,p; I Na,t; I T low threshold; I A; I K; I K,Ca; Na/Ca exchanger; Na/K pump; Ions;
TITLE kdrglia
: Kalium delayed rectifier
: twee gates met elk twee toestanden
: 
: uit: Traub et al.
: A branching dendritic model of a rodent CA3
: pyramidal neurone.

UNITS {
	(molar) = (1/liter)
	(mV) =	(millivolt)
	(mA) =	(milliamp)
	(mM) =	(millimolar)
}

INDEPENDENT {t FROM 0 TO 1 WITH 100 (ms)}

NEURON {
	SUFFIX kdrglia
	USEION k READ ek WRITE ik
	RANGE gkbar, gk, ik, qk
	GLOBAL scaletaun, shiftn
}

UNITS {
	:FARADAY	= (faraday) (coulomb)
	FARADAY		= 96485.309 (coul)
	R = (k-mole) (joule/degC)
	PI		= (pi) (1)
}

PARAMETER {
	gkbar=0		(mho/cm2)	: default max. perm.
	scaletaun=1.5
	shiftn=50	(mV)
}

ASSIGNED { 
	ik	(mA/cm2)
	v	(mV)
	ek	(mV)
	dt	(ms)
	gk	(S/cm2)
	diam	(um)
}

STATE { n c qk }

BREAKPOINT {
	SOLVE kstate METHOD sparse
	gk = gkbar*n*n*n*n
	ik = gk*(v-ek)
	:n  = 1 - c
}

INITIAL {
	n=n_inf(v)
	c=1-n
	gk = gkbar*n*n*n*n
	ik = gk*(v-ek)
	qk=0
}

LOCAL a1,a2

KINETIC kstate {
	a1 = a_n(v)
	a2 = a_c(v)
	~ c <-> n	(a1, a2)
	CONSERVE n + c = 1
	COMPARTMENT diam*diam*PI/4 { qk }

	~ qk << (-ik*diam *PI*(1e4)/FARADAY )
}
	
FUNCTION a_n(v(mV)) {
	TABLE DEPEND scaletaun, shiftn FROM -150 TO 150 WITH 200
	a_n = scaletaun*0.016*(35.1-v-shiftn-70)/(exp((35.1-v-shiftn-70)/5)-1)
}

FUNCTION a_c(v(mV)) {
	TABLE DEPEND scaletaun, shiftn FROM -150 TO 150 WITH 200
	a_c = scaletaun*0.25*exp((20-v-shiftn-70)/40)
}

FUNCTION n_inf(v(mV)) {
        n_inf = a_n(v) / ( a_n(v) + a_c(v) )
}

FUNCTION window(v(mV)) {
	window=gkbar*n_inf(v)^4*(v-ek)
}

Loading data, please wait...