A model of unitary responses from A/C and PP synapses in CA3 pyramidal cells (Baker et al. 2010)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:137259
The model was used to reproduce experimentally determined mean synaptic response characteristics of unitary AMPA and NMDA synaptic stimulations in CA3 pyramidal cells with the objective of inferring the most likely response properties of the corresponding types of synapses. The model is primarily concerned with passive cells, but models of active dendrites are included.
Reference:
1 . Baker JL, Perez-Rosello T, Migliore M, Barrionuevo G, Ascoli GA (2011) A computer model of unitary responses from associational/commissural and perforant path synapses in hippocampal CA3 pyramidal cells. J Comput Neurosci 31:137-58 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Synapse; Dendrite;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Hippocampus CA3 pyramidal GLU cell;
Channel(s):
Gap Junctions:
Receptor(s): AMPA; NMDA;
Gene(s):
Transmitter(s): Glutamate;
Simulation Environment: NEURON;
Model Concept(s):
Implementer(s): Baker, John L [jbakerb at gmu.edu];
Search NeuronDB for information about:  Hippocampus CA3 pyramidal GLU cell; AMPA; NMDA; Glutamate;
/
ca3-synresp
readme.html
cacumm.mod
cagk.mod *
cal2.mod *
can2.mod *
cat.mod *
distr.mod
exp2nmdar.mod
h.mod *
kadist.mod *
KahpM95.mod *
kaprox.mod *
kd.mod *
kdrca1.mod *
km.mod *
na3n.mod *
ama-c30573.CNG.hoc
ama-c31162.CNG.hoc
ama-c60361.CNG.hoc
ama-c62563.CNG.hoc
ama-c73164.CNG.hoc
ama-c81463.CNG.hoc
axon-common.hoc
bar-cell1zr.CNG.hoc
bar-cell2zr.CNG.hoc
bar-cell3zr.CNG.hoc
bar-cell4zr.CNG.hoc
bar-cell5zr.CNG.hoc
bar-cell6zr.CNG.hoc
bar-cell7zr.CNG.hoc
bar-cell8zr.CNG.hoc
demo.hoc
demo.png
demo.ses
demo-fig2a-raw-data.csv
demo-fig2a-raw-time.csv *
demo-fig2a-smoothed-data.csv
demo-fig2a-smoothed-time.csv *
mosinit.hoc
out-vc-ampar-c31162-ad67-022.csv
out-vc-ampar-c62563-ad2-01667.csv
out-vc-ampar-c62563-ad54-054.csv
out-vc-fastampar-c62563-ad2-01667.csv
out-vc-nmdar-c81463-ad87-082.csv
out-vc-nmdar-l51-ad7-036.csv
params-by-fig.csv
synresp.hoc
synresp-c30573.hoc
synresp-c31162.hoc
synresp-c60361.hoc
synresp-c62563.hoc
synresp-c73164.hoc
synresp-c81463.hoc
synresp-cell1zr.hoc
synresp-cell2zr.hoc
synresp-cell3zr.hoc
synresp-cell4zr.hoc
synresp-cell5zr.hoc
synresp-cell6zr.hoc
synresp-cell7zr.hoc
synresp-cell8zr.hoc
synresp-l24b.hoc
synresp-l51.hoc
synresp-l56a.hoc
tur-l24b.CNG.hoc
tur-l51.CNG.hoc
tur-l56a.CNG.hoc
                            
TITLE dual-exponential model of NMDA receptors

COMMENT

This provides a simple dual-exponential model of an NMDA
receptor synapse with a Jahr&Stevens Mg++ voltage dependency.

Changes were made by John Baker to the standard exp2syn.mod
file so that the voltage dependency is addressed. The mgblock
code was borrowed from a model by A. Destexhe.

The NMDA receptor is temperature sensitive. Any necesary
adjustment to the time constants should be done by
setting tau1 and tau2 via hoc.

Default values are more or less taken from Dalby and Mody,
J Neurophysiol 90: 786-797, 2003. No strong claims for 
physiological accuracy are made here.

--- (and now back to the original exp2syn comments) ---

Two state kinetic scheme synapse described by rise time tau1,
and decay time constant tau2. The normalized peak condunductance is 1.
Decay time MUST be greater than rise time.

The solution of A->G->bath with rate constants 1/tau1 and 1/tau2 is
 A = a*exp(-t/tau1) and
 G = a*tau2/(tau2-tau1)*(-exp(-t/tau1) + exp(-t/tau2))
	where tau1 < tau2

If tau2-tau1 -> 0 then we have a alphasynapse.
and if tau1 -> 0 then we have just single exponential decay.

The factor is evaluated in the
initial block such that an event of weight 1 generates a
peak conductance of 1.

Because the solution is a sum of exponentials, the
coupled equations can be solved as a pair of independent equations
by the more efficient cnexp method. 

ENDCOMMENT

NEURON {
	POINT_PROCESS Exp2NMDAR
	RANGE tau1, tau2, e, i
	NONSPECIFIC_CURRENT i

	RANGE g
	GLOBAL total

	RANGE mg
}

UNITS {
	(nA) = (nanoamp)
	(mV) = (millivolt)
	(uS) = (microsiemens)
}

PARAMETER {
	tau1=4 (ms) <1e-9,1e9>
	tau2=42 (ms) <1e-9,1e9>
	e=0	(mV)
	mg=1 (mM) : external magnesium concentration
}

ASSIGNED {
	v (mV)
	i (nA)
	g (uS)
	factor
	total (uS)
}

STATE {
	A (uS)
	B (uS)
}

INITIAL {
	LOCAL tp
	total = 0
	if (tau1/tau2 > .9999) {
		tau1 = .9999*tau2
	}
	A = 0
	B = 0
	tp = (tau1*tau2)/(tau2 - tau1) * log(tau2/tau1)
	factor = -exp(-tp/tau1) + exp(-tp/tau2)
	factor = 1/factor

	mgblock(v)
}

BREAKPOINT {
	SOLVE state METHOD cnexp

	g = B - A
	i = g*mgblock(v)*(v - e)
}

DERIVATIVE state {
	A' = -A/tau1
	B' = -B/tau2
}

NET_RECEIVE(weight (uS)) {
	state_discontinuity(A, A + weight*factor)
	state_discontinuity(B, B + weight*factor)
	total = total+weight
}

: The following is borrowed from Destexhe NMDAR model.
FUNCTION mgblock(v(mV)) {
	TABLE 
	DEPEND mg
	FROM -140 TO 80 WITH 1000

	: from Jahr & Stevens

	mgblock = 1 / (1 + exp(0.062 (/mV) * -v) * (mg / 3.57 (mM)))
}


Loading data, please wait...