Linear vs non-linear integration in CA1 oblique dendrites (Gómez González et al. 2011)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:144450
The hippocampus in well known for its role in learning and memory processes. The CA1 region is the output of the hippocampal formation and pyramidal neurons in this region are the elementary units responsible for the processing and transfer of information to the cortex. Using this detailed single neuron model, it is investigated the conditions under which individual CA1 pyramidal neurons process incoming information in a complex (non-linear) as opposed to a passive (linear) manner. This detailed compartmental model of a CA1 pyramidal neuron is based on one described previously (Poirazi, 2003). The model was adapted to five different reconstructed morphologies for this study, and slightly modified to fit the experimental data of (Losonczy, 2006), and to incorporate evidence in pyramidal neurons for the non-saturation of NMDA receptor-mediated conductances by single glutamate pulses. We first replicate the main findings of (Losonczy, 2006), including the very brief window for nonlinear integration using single-pulse stimuli. We then show that double-pulse stimuli increase a CA1 pyramidal neuron’s tolerance for input asynchrony by at last an order of magnitude. Therefore, it is shown using this model, that the time window for nonlinear integration is extended by more than an order of magnitude when inputs are short bursts as opposed to single spikes.
Reference:
1 . Gómez González JF, Mel BW, Poirazi P (2011) Distinguishing Linear vs. Non-Linear Integration in CA1 Radial Oblique Dendrites: It's about Time. Front Comput Neurosci 5:44 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Hippocampus CA1 pyramidal GLU cell;
Channel(s): I Na,p; I CAN; I Sodium; I Calcium; I Potassium; I_AHP;
Gap Junctions:
Receptor(s): NMDA;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Active Dendrites; Detailed Neuronal Models; Synaptic Integration;
Implementer(s):
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; NMDA; I Na,p; I CAN; I Sodium; I Calcium; I Potassium; I_AHP;
/
CA1_Gomez_2011
mechanism
x86_64
ampa.mod *
cad.mod
cal.mod
calH.mod
can.mod *
car.mod
cat.mod
d3.mod *
gabaa.mod *
gabab.mod
h.mod
hha_old.mod
hha2.mod
ican.mod
ipulse1.mod *
ipulse2.mod *
kadist.mod
kaprox.mod
kca.mod
kct.mod
KdBG.mod
km.mod
nap.mod *
netstim.mod *
netstimmm.mod *
nmda.mod *
NMDAb.mod
somacar.mod
                            
                             TITLE Slow Ca-dependent cation current
                             :
                             :   Ca++ dependent nonspecific cation current ICAN
                             :   Differential equations
                             :
                             :   Model based on a first order kinetic scheme
                             :
                             :       + n cai <->     (alpha,beta)
                             :
                             :   Following this model, the activation fct will be half-activated at 
                             :   a concentration of Cai = (beta/alpha)^(1/n) = cac (parameter)
                             :
                             :   The mod file is here written for the case n=2 (2 binding sites)
                             :   ---------------------------------------------
                             :
                             :   Kinetics based on: Partridge & Swandulla, TINS 11: 69-72, 1988.
                             :
                             :   This current has the following properties:
                             :      - inward current (non specific for cations Na, K, Ca, ...)
                             :      - activated by intracellular calcium
                             :      - NOT voltage dependent
                             :
                             :   A minimal value for the time constant has been added
                             :
                             :   Ref: Destexhe et al., J. Neurophysiology 72: 803-818, 1994.
                             :   See also:  http://www.cnl.salk.edu/~alain , http://cns.fmed.ulaval.ca
                             :

                             INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

                             NEURON {
                                     SUFFIX ican
                                     USEION n READ en WRITE in VALENCE 1
                                     USEION ca READ cai
                                     RANGE gbar, m_inf, tau_m, in
                                     GLOBAL beta, cac, taumin
                             }


                             UNITS {
                                     (mA) = (milliamp)
                                     (mV) = (millivolt)
                                     (molar) = (1/liter)
                                     (mM) = (millimolar)
                             }


                             PARAMETER {
                                     v               (mV)
                                     celsius = 36    (degC)
                                     en      = -20   (mV)            : reversal potential
                                     cai     	     (mM)           : initial [Ca]i
                                     gbar    = 0.00025 (mho/cm2)
                                     beta    = 0.001 :0.002 (1/ms)          : backward rate constant
                                     cac     = 0.01  (mM)            : middle point of activation fct
                                     taumin  = 0.1   (ms)            : minimal value of time constant
                             }


                             STATE {
                                     m
                             }

                             ASSIGNED {
                                     in      (mA/cm2)
                                     m_inf
                                     tau_m   (ms)
                                     tadj
                             }

                             BREAKPOINT { 
                                     SOLVE states METHOD euler
                                     in = gbar * m*m * (v - en)
                             }

                             DERIVATIVE states { 
                                     evaluate_fct(v,cai)

                                     m' = (m_inf - m) / tau_m
                             }

                             UNITSOFF
                             INITIAL {
                             :
                             :  activation kinetics are assumed to be at 22 deg. C
                             :  Q10 is assumed to be 3
                             :
                                     tadj = 3.0 ^ ((celsius-22.0)/10)

                                     evaluate_fct(v,cai)
                                     m = m_inf
                             }


                             PROCEDURE evaluate_fct(v(mV),cai(mM)) {  LOCAL alpha2

                                     alpha2 = beta * (cai/cac)^2

                                     tau_m = 1 / (alpha2 + beta) / tadj
                                     m_inf = alpha2 / (alpha2 + beta)

                                     if(tau_m < taumin) { tau_m = taumin }   : min value of time cst
                             }
                             UNITSON

Loading data, please wait...