Inferior Olive, subthreshold oscillations (Torben-Nielsen, Segev, Yarom 2012)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:144502
The Inferior Olive is a brain structure in which neurons are solely connected to each other through gap-junctions. Its behavior is characterized by spontaneous subthreshold oscillation, frequency changes in the subthreshold oscillation, stable phase differences between neurons, and propagating waves of activity. Our model based on actual IO topology can reproduce these behaviors and provides a mechanistic explanation thereof.
Reference:
1 . Torben-Nielsen B, Segev I, Yarom Y (2012) The generation of phase differences and frequency changes in a network model of inferior olive subthreshold oscillations. PLoS Comput Biol 8:e1002580 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network;
Brain Region(s)/Organism:
Cell Type(s): Inferior olive neuron;
Channel(s): I T low threshold;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s): Gaba;
Simulation Environment: NEURON;
Model Concept(s): Oscillations;
Implementer(s): Torben-Nielsen, Ben [btorbennielsen at gmail.com];
Search NeuronDB for information about:  I T low threshold; Gaba;
COMMENT
Na channel from Schweighofer et al 1999.
The referred model is an inferior olive neuron

B. Torben-Nielsen @ HUJI, 21-10-2010
ENDCOMMENT

NEURON {
       SUFFIX iona
       USEION na READ ena WRITE ina
       RANGE gbar,g,i,minf,hinf,tauh,m : now i can access these variables
}

UNITS {
      (S) = (siemens)
      (mS) = (millisiemens)
      (mV) = (millivolt)
      (mA) = (milliamp)
}

PARAMETER {
	  gbar = 70 (mS/cm2)
	  ena = 55 (mV)
}

ASSIGNED {
	 v (mV)
	 ina (mA/cm2)
	 i (mA/cm2)
	 g (mS/cm2)
	 minf 
	 hinf 
	 tauh (ms)
}

STATE {
      h
}

INITIAL {
	rates(v)
	h = hinf
}

BREAKPOINT {
	   rates(v)
	   SOLVE states METHOD cnexp
	   g = gbar *minf*minf*minf*h
	   i = g * (v - ena)*(0.001)
	   ina = i
}

DERIVATIVE states {
	   h' = (hinf -h)/tauh
}

PROCEDURE rates(v (mV)) {
	  LOCAL a_h, b_h, a_m,b_m
	  UNITSOFF
	  if(fabs(v+41.0) < 1e-6) {
	    a_m=(0.1*(v+41.000001)) / ( 1-exp( -(v+41.000001)/10 ) )
	  } else {
	    a_m=(0.1*(v+41)) / ( 1-exp( -(v+41)/10 ) )
	  }
	  b_m=9.0*exp( -(v+66)/20 )
	  minf=a_m/(a_m+b_m)
	  
	  a_h=5.0*exp( -(v+60)/15 )
	  b_h=(v+50) / ( 1-exp( -(v+50)/10 ) )
	  hinf=a_h/(a_h+b_h)
	  tauh=250/( a_h+b_h ) : was 170, 250
	  UNITSON
}

Loading data, please wait...