Calcium waves and mGluR-dependent synaptic plasticity in CA1 pyr. neurons (Ashhad & Narayanan 2013)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:150551
A morphologically realistic, conductance-based model equipped with kinetic schemes that govern several calcium signalling modules and pathways in CA1 pyramidal neurons
Reference:
1 . Ashhad S, Narayanan R (2013) Quantitative interactions between the A-type K+ current and inositol trisphosphate receptors regulate intraneuronal Ca2+ waves and synaptic plasticity. J Physiol 591:1645-69 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Synapse; Channel/Receptor; Dendrite;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Hippocampus CA1 pyramidal GLU cell;
Channel(s): I Na,t; I L high threshold; I T low threshold; I A; I K; Ca pump;
Gap Junctions:
Receptor(s): AMPA; NMDA; mGluR; IP3;
Gene(s):
Transmitter(s): Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Active Dendrites; Synaptic Plasticity; Signaling pathways; Calcium dynamics; G-protein coupled; Calcium waves;
Implementer(s): Narayanan, Rishikesh [rishi at iisc.ac.in]; Ashhad, Sufyan [soofy at mbu.iisc.ernet.in];
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; AMPA; NMDA; mGluR; IP3; I Na,t; I L high threshold; I T low threshold; I A; I K; Ca pump; Glutamate;
/
AshhadNarayanan2013
Readme.html
cal4.mod
Calamp.mod
caltype.mod
camax.mod
cat.mod
ghknmda.mod
ip3dif.mod
kadist.mod *
kaprox.mod *
kdrca1.mod
mglur.mod
na3.mod
nax.mod *
Wghkampa.mod
CalciumWave.hoc
distance.hoc
Fig4F-G.hoc
Fig6C-F.hoc
mosinit.hoc
n123.hoc
n123_all.dis
n123_all.rdis
ObliquePath.hoc
oblique-paths.hoc
parameters.hoc
screenshot4F.png
screenshot4G.png
screenshot6C-F.png
                            
: Authors: Ashhad S and Narayanan R,  2013 

INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}

NEURON {
	POINT_PROCESS mGLUR
	RANGE G, C, lastrelease
	RANGE Cmax, Cdur, Deadtime, K1, K2, initmGluR
	USEION ip3 WRITE iip3 VALENCE 1
}

UNITS {
	(mM) = (milli/liter)
	(uM)=  (micro/liter)
        (mA)    = (milliamp) 

}

PARAMETER {	

	initmGluR=0.3e-3 (mM): Bhalla & Iyenger Science  1999

	Cmax	= 1	(mM)		: max transmitter concentration
	Deadtime = 1	(ms)		: mimimum time between release events

	K1	= 0.28	(/ms uM)	: forward binding rate to receptor from Bhalla et al
	K2	= 0.016 (/ms)		: backward (unbinding) rate of receptor from Bhalla et al
	K_PLC = 5 (uM)			:total concentration of PLC
	K_PIP2 = 160 (uM)		:total concentration of PIP2
	K_G=25 (uM)
							:kplc and Vmax describe aPLC catalyzing IP3 production from PIP2
	kfplc = 0.83(/ms)
	kbplc = 0.68 (/ms) : 0.1/ms in the paper; added to Vmax1=0.58/ms in the paper
	Vmax1 = 0.58 (/ms)
							:D5 and D6 describe Glu_mGluR catalyzing G_alpha production, Km2=(D6f+D5B)/D5f
	D5f = 15 (/ms)
	D5b = 7.2 (/ms)
	D6f = 1.8(/ms)
	Vmax2 = 1.8 (/ms)
	Km2 = 0.6 (uM)
							:G2 describe aG binding to PLC
	G2f = 100 (/ms)
	G2b = 100 (/ms)
							:degradation of aG (D7f) and IP3 (G9f)
	D7f =9  (/ms)
	G9f = 0.75(/ms)  :4 in original paper
	Cdur=2	(ms)			: transmitter duration (rising phase)
}


ASSIGNED {
	C		(mM)		: transmitter concentration
	lastrelease	(ms)		: time of last spike
	iip3 		(mA/cm2)
}



STATE {
	aG				: fraction of activated G-protein
	aPLC_aG
	aPLC_PIP2
	Glu_mGluR
	GG_mGluR
	ip3
	degip3
	mGluR
	PLC
	PIP2
	G
}


INITIAL {
	Glu_mGluR = 0
	GG_mGluR = 0
   	aPLC_aG=0 :0.0035 
	aPLC_PIP2=0
	aG =0: 0.0007
   	iip3= 0
   	ip3= 0
	G=K_G-(aG+GG_mGluR+aPLC_aG+aPLC_PIP2)
	PLC=K_PLC-(aPLC_aG+aPLC_PIP2)
	PIP2=K_PIP2-(aPLC_PIP2+ip3)
	mGluR=initmGluR
	lastrelease = -1e8
}

BREAKPOINT {
	evaluateC()
	SOLVE bindkin METHOD sparse
}


KINETIC bindkin {
	~ mGluR <-> Glu_mGluR (C*K1, K2)
	~ Glu_mGluR + G <-> GG_mGluR (D5f,D5b)
	~ GG_mGluR <-> aG+mGluR (D6f,0)
	~ aG <-> G (D7f,0)
	~ aG+PLC <-> aPLC_aG (G2f, G2b)
	~ aPLC_aG+PIP2 <-> aPLC_PIP2 (kfplc,kbplc)
	~ aPLC_PIP2 <-> ip3 (Vmax1,0)
  	~ ip3 <-> degip3 (G9f,0)
		
	:CONSERVE G+aG+GG_mGluR+aPLC_aG+aPLC_PIP2=K_G
	:CONSERVE PLC+aPLC_aG+aPLC_PIP2=K_PLC
	:CONSERVE PIP2+aPLC_PIP2+ip3=K_PIP2

		iip3= ip3
}

PROCEDURE evaluateC()
		{
			LOCAL q
			q = ((t - lastrelease) - Cdur)		: time since last release ended
			if (q >= 0 && q <= Deadtime && C == Cmax) {	: in dead time after release
			C = 0.
			}
	}

NET_RECEIVE (weight (umho)) 
		{ 
			LOCAL q
			q = ((t - lastrelease) - Cdur)		: time since last release ended

			: Spike has arrived, ready for another release?

		if (q > Deadtime) {
		C = Cmax			: start new release
		lastrelease = t
		} 
}

Loading data, please wait...