Calcium response prediction in the striatal spines depending on input timing (Nakano et al. 2013)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:151458
We construct an electric compartment model of the striatal medium spiny neuron with a realistic morphology and predict the calcium responses in the synaptic spines with variable timings of the glutamatergic and dopaminergic inputs and the postsynaptic action potentials. The model was validated by reproducing the responses to current inputs and could predict the electric and calcium responses to glutamatergic inputs and back-propagating action potential in the proximal and distal synaptic spines during up and down states.
Reference:
1 . Nakano T, Yoshimoto J, Doya K (2013) A model-based prediction of the calcium responses in the striatal synaptic spines depending on the timing of cortical and dopaminergic inputs and post-synaptic spikes. Front Comput Neurosci 7:119 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Synapse;
Brain Region(s)/Organism:
Cell Type(s): Neostriatum medium spiny direct pathway GABA cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I A; I K; I K,leak; I K,Ca; I CAN; I Sodium; I Calcium; I Potassium; I A, slow; I Krp; I R; I Q; I Na, leak; I Ca,p; Ca pump;
Gap Junctions:
Receptor(s): D1; AMPA; NMDA; Glutamate; Dopaminergic Receptor; IP3;
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Reinforcement Learning; STDP; Calcium dynamics; Reward-modulated STDP;
Implementer(s): Nakano, Takashi [nakano.takashi at gmail.com];
Search NeuronDB for information about:  Neostriatum medium spiny direct pathway GABA cell; D1; AMPA; NMDA; Glutamate; Dopaminergic Receptor; IP3; I Na,p; I Na,t; I L high threshold; I A; I K; I K,leak; I K,Ca; I CAN; I Sodium; I Calcium; I Potassium; I A, slow; I Krp; I R; I Q; I Na, leak; I Ca,p; Ca pump;
/
Nakano_FICN_model
stim_files2
tau_tables
readme.html
AMPA.mod
bkkca.mod *
cadyn.mod
caL.mod
caL13.mod
caldyn.mod
can.mod
caq.mod
car.mod *
cat.mod
damsg.mod
ER.mod
GABA.mod *
kaf.mod *
kas.mod *
kir.mod
krp.mod *
MGLU.mod
naf.mod
nap.mod *
NMDA.mod
skkca.mod *
stim.mod *
_control.hoc
_IVsaveplot.hoc
_paper_condition.hoc
_plot_post02.hoc
_plot_pre_spine.hoc
_reset.hoc
_run_me.hoc
_saveIVplot.hoc
_saveplots.hoc
_timed_input_1AP_spine_post.hoc
_timed_input_Glu.hoc
all_tau_vecs.hoc *
baseline_values.txt
basic_procs.hoc
create_mspcells.hoc *
current_clamp.ses
fig4a.png
make_netstims.hoc
mosinit.hoc
msp_template.hoc
nacb_main.hoc
netstims_template.hoc *
posttiming.txt
set_synapse.hoc
set_synapse_caL.hoc
set_synapse_caL13.hoc
set_synapse_can.hoc
set_synapse_caq.hoc
set_synapse_ER.hoc
set_synapse_kir.hoc
set_synapse_naf.hoc
set_synapse_NMDA.hoc
stimxout_jns_sqwave_noinput.dat
synapse_templates.hoc
                            
TITLE T-type calcium channel for nucleus accumbens neuron 
: see comments at end of file

UNITS {
	(mV) = (millivolt)
	(mA) = (milliamp)
	(S) = (siemens)
	(molar) = (1/liter)
	(mM) = (millimolar)
	FARADAY = (faraday) (coulomb)
	R = (k-mole) (joule/degC)
}

NEURON {
	SUFFIX cat
	USEION cal READ cali, calo WRITE ical VALENCE 2
	RANGE pcatbar, ical
}

PARAMETER {
	pcatbar = 7.6e-7(cm/s)		: vh = -100, step to -30 mV

	mvhalf = -51.73	(mV)		: McRory 2001, fig 7
	mslope = -6.53	(mV)		: McRory 2001, fig 7
	mshift = 0	(mV)
	
	hvhalf = -80	(mV)		: Churchill 1998, fig 3
	hslope = 6.7	(mV)		: Churchill 1998, fig 3
	hshift = 0	(mV)
	
	qfact = 3				: both m & h recorded at 22 C
}					

ASSIGNED { 
    v 		(mV)
    ical 	(mA/cm2)
    ecal		(mV)
    
    celsius	(degC)
    cali		(mM)
    calo		(mM)

    minf
    hinf
}

STATE {
    m h
}

BREAKPOINT {
    SOLVE states METHOD cnexp
    ical  = ghk(v,cali,calo) * pcatbar * m * m * m * h	: Wang 1991
}

INITIAL {
    settables(v)
    m = minf:0.1
    h = 0.76 :hinf :0.76:0.06
}

DERIVATIVE states {  
	settables(v)
	m' = (minf - m) / (mtau(v)/qfact)
	h' = (hinf - h) / (htau(v)/qfact)
}

FUNCTION_TABLE mtau(v(mV))	(ms)		: McRory 2001, Fig 6B
FUNCTION_TABLE htau(v(mV))	(ms)		: McRory 2001, Fig 6E

PROCEDURE settables( v (mV) ) {
	TABLE minf, hinf DEPEND mshift, hshift
        	FROM -100 TO 100 WITH 201
			minf = 1  /  ( 1 + exp( (v-mvhalf-mshift) / mslope) )
			hinf = 1  /  ( 1 + exp( (v-hvhalf-hshift) / hslope) ) 
}


::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

: ghk() borrowed from cachan.mod share file in Neuron
FUNCTION ghk(v(mV), ci(mM), co(mM)) (.001 coul/cm3) {
	LOCAL z, eci, eco
	z = (1e-3)*2*FARADAY*v/(R*(celsius+273.15))
	eco = co*efun(z)
	eci = ci*efun(-z)
	:high cao charge moves inward
	:negative potential charge moves inward
	ghk = (.001)*2*FARADAY*(eci - eco)
}

FUNCTION efun(z) {
	if (fabs(z) < 1e-4) {
		efun = 1 - z/2
	}else{
		efun = z/(exp(z) - 1)
	}
}



COMMENT
Churchill D, Macvicar BA (1998) Biophysical and pharmacological
characterization of voltage-dependent Ca2+ channels in neurons isolated
from rat nucleus accumbens. J Neurophysiol 79:635-647.

McRory JE, Santi CM, Hamming KS, Mezeyova J, Sutton KG, Baillie DL, Stea
A, Snutch TP (2001) Molecular and functional characterization of a
family of rat brain T-type calcium channels. J Biol Chem 276:3999-4011.

Wang XJ, Rinzel J, Rogawski MA (1991) A model of the T-type calcium
current and the low-threshold spike in thalamic neurons. J Neurophysiol
66:839-850.

Koch, C., and Segev, I., eds. (1998). Methods in Neuronal Modeling: From
Ions to Networks, 2 edn (Cambridge, MA, MIT Press).

Hille, B. (1992). Ionic Channels of Excitable Membranes, 2 edn
(Sunderland, MA, Sinauer Associates Inc.).



localization is not known (to me) - so gcatbar is calculated with cat in
both soma and dendrites

This is the low-threshold inactivating current in fig 3 from Churchill.

See McRory 2001 - I'm using alpha G values for minf.  For one, the
striatum seems to have all three types of subunits in equal amounts
according (Fig 3), and G seems to represent the average of all three.
Second, the inactivation inf values for G match Churchill's (fig. 3)
values most closely of all three.  For both taus i'm using the I subunit
b/c it seems to match churchill's data best (visually).

I tried fitting the tau(v) curve using Wang's method, and got impressive
results, but couldn't get matlab to reproduce the right curves.  Might
be worth investigating.

Make sure that cat_vec.hoc, taum_cat.txt, tauh_cat.txt, and vtau_cat.txt
are in the same directory.  cat_vec.hoc reads the three text files into
tables to hold the tau(v) values: taum_cat and tauh_cat have the mtau
and htau values at the respective voltages in vtau_cat.

eca should = 100 mV, based on Nernst Eq, [ca]i = 100uM, [ca]o = 5mM
be sure to set eca in the hoc file for every section



The standard HH model uses a linear approximation to the driving force
for an ion: (Vm - ez).  This is ok for na and k, but not ca - calcium
rectifies at high potentials because 
	1. internal and external concentrations of ca are so different,
	making outward current flow much more difficult than inward 
	2. calcium is divalent so rectification is more sudden than for na
	and k. (Hille 1992, pg 107)

Accordingly, we need to replace the HH formulation with the GHK model,
which accounts for this phenomenon.  The GHK equation is eq 6.6 in Koch
1998, pg 217 - it expresses Ica in terms of Ca channel permeability
(Perm,ca) times a mess. The mess can be circumvented using the ghk
function below, which is included in the Neuron share files.  Perm,ca
can be expressed in an HH-like fashion as 
	Perm,ca = pcabar * mca * mca 	(or however many m's and h's)
where pcabar has dimensions of permeability but can be thought of as max
conductance (Koch says it should be about 10^7 times smaller than the HH
gbar - dont know) and mca is analagous to m (check out Koch 1998 pg 144)

Calcium current can then be modeled as 
	ica = pcabar * mca * mca * ghk()

ENDCOMMENT


Loading data, please wait...