Sympathetic Preganglionic Neurone (Briant et al. 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:151482
A model of a sympathetic preganglionic neurone of muscle vasoconstrictor-type.
Reference:
1 . Briant LJ, Stalbovskiy AO, Nolan MF, Champneys AR, Pickering AE (2014) Increased intrinsic excitability of muscle vasoconstrictor preganglionic neurons may contribute to the elevated sympathetic activity in hypertensive rats. J Neurophysiol 112:2756-78 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Spinal cord lumbar motor neuron alpha ACh cell; Spinal cord sympathetic preganglionic neuron;
Channel(s): I Na,t; I L high threshold; I N; I A; I K; I K,Ca; I_AHP;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON; MATLAB;
Model Concept(s): Action Potential Initiation; Activity Patterns; Bursting; Ion Channel Kinetics; Temporal Pattern Generation; Parameter Fitting; Action Potentials; Parameter sensitivity;
Implementer(s):
Search NeuronDB for information about:  Spinal cord lumbar motor neuron alpha ACh cell; I Na,t; I L high threshold; I N; I A; I K; I K,Ca; I_AHP;
/
SPN_ModelDB
hoc_code
MATLAB_code
README.txt
borgka.mod
borgkdr.mod
cadifus2.mod
cagk.mod *
cal2.mod *
can2.mod
gap.mod
gapcalcium.mod
kadist.mod *
kahp.mod *
kaprox.mod *
na3.mod
ActivationProtocol_GKA.dat
ActivationProtocol_IA.dat
ActivationProtocol_V.dat
Cell.hoc
ClampFiddy.dat
ClampFiddy_vhalfm.dat
ClampFiddy_ZetaK.dat
ClampFiddy_ZetaM.dat
ClampHundred.dat
ClampHundred_vhalfm.dat
ClampHundred_ZetaK.dat
ClampHundred_ZetaM.dat
CurrentMagnitude_GKA.dat
CurrentMagnitude_IA.dat
CurrentMagnitude_V.dat
EPSCs_Filtered.txt
InactivationProtocol_GKA.dat
InactivationProtocol_IA.dat
InactivationProtocol_V.dat
init.hoc
mosinit.hoc *
                            
TITLE na3
: Na current 
: from Jeff M.
:  ---------- modified -------M.Migliore may97

NEURON {
	SUFFIX na3
	USEION na READ ena WRITE ina
	RANGE  gbar, ar2, pert, h, s, m, pert1, pert2
	GLOBAL minf, hinf, mtau, htau, sinf, taus,qinf, thinf
}

PARAMETER {
	gbar = 0.010   	(mho/cm2)	
	pert=0 (mV)
	pert1=0 (mV)
	pert2=0 (mV)
	tha  =  -30	(mV)		: v 1/2 for act	
	qa   = 7.2	(mV)		: act slope (4.5)		
	Ra   = 0.4	(/ms)		: open (v)		
	Rb   = 0.124 	(/ms)		: close (v)		

	thi1  = -45	(mV)		: v 1/2 for inact 	
	thi2  = -45 	(mV)		: v 1/2 for inact 	
	qd   = 1.5	(mV)	        : inact tau slope
	qg   = 1.5      (mV)
	mmin=0.02	
	hmin=0.5			
	q10=2
	Rg   = 0.01 	(/ms)		: inact recov (v) 	
	Rd   = .03 	(/ms)		: inact (v)	
	qq   = 10        (mV)
	tq   = -55      (mV)

	thinf  = -50 	(mV)		: inact inf slope	
	qinf  = 4 	(mV)		: inact inf slope 

        vhalfs=-60	(mV)		: slow inact.
        a0s=0.0003	(ms)		: a0s=b0s
        zetas=12	(1)
        gms=0.2		(1)
        smax=10		(ms)R
        vvh=-58		(mV) 
        vvs=2		(mV)
        ar2=1		(1)		: 1=no inact., 0=max inact.
	ena		(mV)            : must be explicitly def. in hoc
	celsius
	v 		(mV)
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(pS) = (picosiemens)
	(um) = (micron)
} 

ASSIGNED {
	ina 		(mA/cm2)
	thegna		(mho/cm2)
	minf 		hinf 		
	mtau (ms)	htau (ms) 	
	sinf (ms)	taus (ms)
}
 

STATE { m h s}

BREAKPOINT {
        SOLVE states METHOD cnexp
        thegna = gbar*m*m*m*h*s
	ina = thegna * (v - ena)
} 

INITIAL {
	trates(v,ar2)
	m=minf  
	h=hinf
	s=sinf
}


FUNCTION alpv(v(mV)) {
         alpv = 1/(1+exp((v-vvh)/vvs))
}
        
FUNCTION alps(v(mV)) {  
  alps = exp(1.e-3*zetas*(v-vhalfs)*9.648e4/(8.315*(273.16+celsius)))
}

FUNCTION bets(v(mV)) {
  bets = exp(1.e-3*zetas*gms*(v-vhalfs)*9.648e4/(8.315*(273.16+celsius)))
}

LOCAL mexp, hexp, sexp

DERIVATIVE states {   
        trates(v,ar2)      
        m' = (minf-m)/mtau
        h' = (hinf-h)/htau
        s' = (sinf - s)/taus
}

PROCEDURE trates(vm,a2) {  
        LOCAL  a, b, c, qt
        qt=q10^((celsius-24)/10)
	a = trap0(vm,tha,Ra,qa)
	b = trap0(-vm,-tha,Rb,qa)
	mtau = 1/(a+b)/qt
        if (mtau<mmin) {mtau=mmin}
	minf = a/(a+b)

	a = trap1(vm,thi1,Rd,qd)
	b = trap1(-vm,-thi2,Rg,qg)
	htau =  1/(a+b)/qt
        if (htau<hmin) {htau=hmin}
	hinf = 1/(1+exp((vm-thinf+pert1)/qinf))
	c=alpv(vm)
        sinf = c+a2*(1-c)
        taus = bets(vm)/(a0s*(1+alps(vm)))
        if (taus<smax) {taus=smax}
}

FUNCTION trap0(v,th,a,q) {
	if (fabs(v-th) > 1e-6) {
	        trap0 = a * (v - th + pert) / (1 - exp(-(v - th + pert)/q))
	} else {
	        trap0 = a * q
 	}
}	

FUNCTION trap1(v,th,a,q) {
	if (fabs(v-th) > 1e-6) {
	        trap1 = a * (v - th + pert2) / (1 - exp(-(v - th + pert2)/q))
	} else {
	        trap1 = a * q
 	}
}

Loading data, please wait...