Spine head calcium in a CA1 pyramidal cell model (Graham et al. 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:154732
"We use a computational model of a hippocampal CA1 pyramidal cell to demonstrate that spine head calcium provides an instantaneous readout at each synapse of the postsynaptic weighted sum of all presynaptic activity impinging on the cell. The form of the readout is equivalent to the functions of weighted, summed inputs used in neural network learning rules. Within a dendritic layer, peak spine head calcium levels are either a linear or sigmoidal function of the number of coactive synapses, with nonlinearity depending on the ability of voltage spread in the dendrites to reach calcium spike threshold. ..."
Reference:
1 . Graham BP, Saudargiene A, Cobb S (2014) Spine head calcium as a measure of summed postsynaptic activity for driving synaptic plasticity. Neural Comput 26:2194-222 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s):
Channel(s):
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Synaptic Integration;
Implementer(s): Graham, Bruce [B.Graham at cs.stir.ac.uk];
/
GrahamEtAl2014
Cells
Results
readme.html
burststim2.mod *
cad.mod
cagk.mod
carF.mod
distca.mod
distr.mod *
h.mod *
kadist.mod *
kaprox.mod *
kca.mod *
kdrca1.mod *
km.mod
na3n.mod *
naxn.mod *
nmdaca.mod *
burst_cell.hoc *
CA1PC.hoc
mosinit.hoc
randomlocation.hoc
ranstream.hoc *
run_batsyn.hoc
run_PC.hoc
screenshot1.png
screenshot2.png
screenshot3.png
setup_PC.hoc
synstim.ses
                            
TITLE decay of internal calcium concentration
:
: Internal calcium concentration due to calcium currents and pump.
: Differential equations.
:
: Simple model of ATPase pump with 3 kinetic constants (Destexhe 92)
:     Cai + P <-> CaP -> Cao + P  (k1,k2,k3)
: A Michaelis-Menten approximation is assumed, which reduces the complexity
: of the system to 2 parameters: 
:       kt = <tot enzyme concentration> * k3  -> TIME CONSTANT OF THE PUMP
:	kd = k2/k1 (dissociation constant)    -> EQUILIBRIUM CALCIUM VALUE
: The values of these parameters are chosen assuming a high affinity of 
: the pump to calcium and a low transport capacity (cfr. Blaustein, 
: TINS, 11: 438, 1988, and references therein).  
:
: Units checked using "modlunit" -> factor 10000 needed in ca entry
:
: VERSION OF PUMP + DECAY (decay can be viewed as simplified buffering)
:
: All variables are range variables
:
:
: This mechanism was published in:  Destexhe, A. Babloyantz, A. and 
: Sejnowski, TJ.  Ionic mechanisms for intrinsic slow oscillations in
: thalamic relay neurons. Biophys. J. 65: 1538-1552, 1993)
:
: Written by Alain Destexhe, Salk Institute, Nov 12, 1992
:
: This file was modified by Yiota Poirazi (poirazi@LNC.usc.edu) on April 18, 2001 to account for the sharp
: Ca++ spike repolarization observed in: Golding, N. Jung H-Y., Mickus T. and Spruston N
: "Dendritic Calcium Spike Initiation and Repolarization are controlled by distinct potassium channel
: subtypes in CA1 pyramidal neurons". J. of Neuroscience 19(20) 8789-8798, 1999.
:
:  factor 10000 is replaced by 10000/18 needed in ca entry
:  taur --rate of calcium removal-- is replaced by taur*7 (7 times faster)

: Code tidied to make clear the instantaneous buffer capacity (BPG 21-6-11)

: 20150524 NTC
: Changed integration method from euler to derivimplicit
: which is appropriate for simple ion accumulation mechanisms.
: See
: Integration methods for SOLVE statements
: http://www.neuron.yale.edu/phpBB/viewtopic.php?f=28&t=592

NEURON {
	SUFFIX cad
	USEION ca READ ica, cai WRITE cai	
        RANGE ca
	GLOBAL depth,cainf,taur,bcap
}

UNITS {
	(molar) = (1/liter)			: moles do not appear in units
	(mM)	= (millimolar)
	(um)	= (micron)
	(mA)	= (milliamp)
	(msM)	= (ms mM)
	FARADAY = (faraday) (coulomb)
}


PARAMETER {
	depth	= .1	(um)		: depth of shell
:	taur	= 200	(ms)		: rate of calcium removal
	taur	= 28.6	(ms)		: rate of calcium removal (Poirazzi)
	bcap	= 17	(1)		: buffer capacity
	cainf	= 100e-6(mM)
	cai		(mM)
}

STATE {
	ca		(mM) 
}

INITIAL {
	ca = cainf
}

ASSIGNED {
	ica		(mA/cm2)
	drive_channel	(mM/ms)
}
	
BREAKPOINT {
        SOLVE state METHOD derivimplicit : not euler
    : see http://www.neuron.yale.edu/phpBB/viewtopic.php?f=28&t=592
}

DERIVATIVE state { 

	drive_channel =  - (10000) * ica / (2 * FARADAY * depth)
	if (drive_channel <= 0.) { drive_channel = 0.  }   : cannot pump inward 
         
	:ca' = drive_channel + (cainf-ca)/taur
        ca' = drive_channel/(1+bcap) + (cainf-ca)/taur
	cai = ca
}














Loading data, please wait...