Spine head calcium in a CA1 pyramidal cell model (Graham et al. 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:154732
"We use a computational model of a hippocampal CA1 pyramidal cell to demonstrate that spine head calcium provides an instantaneous readout at each synapse of the postsynaptic weighted sum of all presynaptic activity impinging on the cell. The form of the readout is equivalent to the functions of weighted, summed inputs used in neural network learning rules. Within a dendritic layer, peak spine head calcium levels are either a linear or sigmoidal function of the number of coactive synapses, with nonlinearity depending on the ability of voltage spread in the dendrites to reach calcium spike threshold. ..."
Reference:
1 . Graham BP, Saudargiene A, Cobb S (2014) Spine head calcium as a measure of summed postsynaptic activity for driving synaptic plasticity. Neural Comput 26:2194-222 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s):
Channel(s):
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Synaptic Integration;
Implementer(s): Graham, Bruce [B.Graham at cs.stir.ac.uk];
/
GrahamEtAl2014
Cells
Results
readme.html
burststim2.mod *
cad.mod
cagk.mod
carF.mod
distca.mod
distr.mod *
h.mod *
kadist.mod *
kaprox.mod *
kca.mod *
kdrca1.mod *
km.mod
na3n.mod *
naxn.mod *
nmdaca.mod *
burst_cell.hoc *
CA1PC.hoc
mosinit.hoc
randomlocation.hoc
ranstream.hoc *
run_batsyn.hoc
run_PC.hoc
screenshot1.png
screenshot2.png
screenshot3.png
setup_PC.hoc
synstim.ses
                            
TITLE CaGk
: Calcium activated mAHP K channel.
: From Moczydlowski and Latorre (1983) J. Gen. Physiol. 82
: Code updated to run with CVODE (BPG 20-8-09)

UNITS {
	(molar) = (1/liter)
}

UNITS {
	(mV) =	(millivolt)
	(mA) =	(milliamp)
	(mM) =	(millimolar)
}

INDEPENDENT {t FROM 0 TO 1 WITH 100 (ms)}

NEURON {
	SUFFIX kmAHP
	USEION ca READ cai
	USEION k READ ek WRITE ik
	RANGE gkbar, ik
	GLOBAL oinf, tau
}

UNITS {
	FARADAY = (faraday)  (kilocoulombs)
	R = 8.313424 (joule/degC)
}

PARAMETER {
	v		(mV)
	dt		(ms)
	ek		(mV)
	celsius = 20	(degC)
	gkbar = 0.01	(mho/cm2)	: Maximum Permeability
	cai = 1e-3	(mM)
	d1 = 0.84
	d2 = 1.0
	k1 = 0.18	(mM)
	k2 = 0.011	(mM)
	bbar = 0.28	(/ms)
	abar = 0.48	(/ms)
}
COMMENT
the preceding two numbers were switched on 8/19/92 in response to a bug
report by Bartlett Mel. In the paper the kinetic scheme is
C <-> CCa (K1)
CCa <-> OCa (beta2,alpha2)
OCa <-> OCa2 (K4)
In this model abar = beta2 and bbar = alpha2 and K4 comes from d2 and k2
I was forcing things into a nomenclature where alpha is the rate from
closed to open. Unfortunately I didn't switch the numbers.
ENDCOMMENT

ASSIGNED {
	ik		(mA/cm2)
	oinf
	tau		(ms)
}

STATE {	o }		: fraction of open channels

BREAKPOINT {
	SOLVE state METHOD derivimplicit
	ik = gkbar*o*(v - ek) : potassium current induced by this channel
}

:LOCAL fac

DERIVATIVE state {
	rate(v, cai)
	:o = o + fac*(oinf - o)
	o' = (oinf - o) / tau
}

INITIAL {           : initialize the following parameter using rate()
	rate(v, cai)
	o = oinf
}

FUNCTION alp(v (mV), ca (mM)) (1/ms) { :callable from hoc
	alp = abar/(1 + exp1(k1,d1,v)/ca)
}

FUNCTION bet(v (mV), ca (mM)) (1/ms) { :callable from hoc
	bet = bbar/(1 + ca/exp1(k2,d2,v))
}  

FUNCTION exp1(k (mM), d, v (mV)) (mM) { :callable from hoc
	exp1 = k*exp(-2*d*FARADAY*v/R/(273.15 + celsius))
}

PROCEDURE rate(v (mV), ca (mM)) { :callable from hoc
	LOCAL a
	a = alp(v,ca)
	tau = 1/(a + bet(v, ca)) : estimation of activation tau
	oinf = a*tau             : estimation of activation steady state value
	:fac = (1 - exp(-dt/tau))
}

Loading data, please wait...