Intrinsic sensory neurons of the gut (Chambers et al. 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:155796
A conductance base model of intrinsic neurons neurons in the gastrointestinal tract. The model contains all the major voltage-gated and calcium-gated currents observed in these neurons. This model can reproduce physiological observations such as the response to multiple brief depolarizing currents, prolonged depolarizing currents and hyperpolarizing currents. This model can be used to predict how different currents influence the excitability of intrinsic sensory neurons in the gut.
Reference:
1 . Chambers JD, Bornstein JC, Gwynne RM, Koussoulas K, Thomas EA (2014) A detailed, conductance-based computer model of intrinsic sensory neurons of the gastrointestinal tract. Am J Physiol Gastrointest Liver Physiol 307:G517-32 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Channel/Receptor;
Brain Region(s)/Organism:
Cell Type(s): Gastrointestinal tract intrinsic sensory neuron;
Channel(s): I Na,p; I Na,t; I K,leak; I K,Ca; I CAN; I Mixed; I Na, leak; Ca pump;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.3 SCN3A; Nav1.7 SCN9A; Nav1.9 SCN11A SCN12A;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Detailed Neuronal Models; Action Potentials; Calcium dynamics;
Implementer(s): Chambers, Jordan [jordandchambers at gmail.com];
Search NeuronDB for information about:  I Na,p; I Na,t; I K,leak; I K,Ca; I CAN; I Mixed; I Na, leak; Ca pump;
TITLE C-type potasium current 
: Taken from RD Traub, J Neurophysiol 89:909-921, 2003
: Implemented by Maciej Lazarewicz 2003 (mlazarew@seas.upenn.edu)
: Adapted calcium dependence by Jordan Chambers 2012 (jordandchambers@gmail.com)

INDEPENDENT { t FROM 0 TO 1 WITH 1 (ms) }

UNITS { 
	(mV) = (millivolt) 
	(mA) = (milliamp) 
	(mM) = (milli/liter)
}
 
NEURON { 
	SUFFIX kca_fast
	USEION k READ ek WRITE ik
	USEION ca READ cai
	RANGE  gbar, ik, jikcaf, jk1, jk2
}

PARAMETER { 
	gbar = 3e-2 	(mho/cm2)
	v (mV) 
	ek 		(mV)  
	cai		(mM)
	cac = 6e-4 (mM)
	cas = 7.5e-5 (mM)
	v1 = 50
	v2 = 53.5
	s1 = 11
	s2 = 27
	eK=  -95 (mV)
	jikcaf		(mA/cm2)
	jk1
	jk2
	aspeed = 1
	bspeed = 1
} 

ASSIGNED { 
	ik 		(mA/cm2) 
	alpha (/ms) beta	(/ms)
}
 
STATE {
	m
}

BREAKPOINT { 
     SOLVE states METHOD cnexp
     jk1 = 1/(1+exp(((cac-cai)/cas)))
     jk2 = gbar*m*(v-ek)
     ik = gbar*m*(1/(1+exp(((cac-cai)/cas))))*(v-ek)
     jikcaf = ik
}
 
INITIAL { 
	settables(v) 
	m = alpha / ( alpha + beta )
	m = 0
}
 
DERIVATIVE states { 
	settables(v) 
	m' = alpha * ( 1 - m ) - beta * m 
}

UNITSOFF 

PROCEDURE settables(v(mV)) { 
	TABLE alpha, beta FROM -120 TO 40 WITH 641

	if( v <= -10.0 ) {
		alpha = 2 / 37.95 * ( exp( ((v + v1)/s1) - ((v + v2)/s2)))

		: Note that there is typo in the paper - missing minus sign in the front of 'v'
		beta  = 2 * exp((- v - v2)/s2) - alpha
	}else{
		alpha = 2 * exp(( - v - v2)/s2)
		beta  = 0
	}
	: speed-up of C kinetics here.
	alpha = alpha * aspeed
	beta  = beta  * bspeed
}

UNITSON

Loading data, please wait...