Intrinsic sensory neurons of the gut (Chambers et al. 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:155796
A conductance base model of intrinsic neurons neurons in the gastrointestinal tract. The model contains all the major voltage-gated and calcium-gated currents observed in these neurons. This model can reproduce physiological observations such as the response to multiple brief depolarizing currents, prolonged depolarizing currents and hyperpolarizing currents. This model can be used to predict how different currents influence the excitability of intrinsic sensory neurons in the gut.
Reference:
1 . Chambers JD, Bornstein JC, Gwynne RM, Koussoulas K, Thomas EA (2014) A detailed, conductance-based computer model of intrinsic sensory neurons of the gastrointestinal tract. Am J Physiol Gastrointest Liver Physiol 307:G517-32 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell; Channel/Receptor;
Brain Region(s)/Organism:
Cell Type(s): Gastrointestinal tract intrinsic sensory neuron;
Channel(s): I Na,p; I Na,t; I K,leak; I K,Ca; I CAN; I Mixed; I Na, leak; Ca pump;
Gap Junctions:
Receptor(s):
Gene(s): Nav1.3 SCN3A; Nav1.7 SCN9A; Nav1.9 SCN11A SCN12A;
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Detailed Neuronal Models; Action Potentials; Calcium dynamics;
Implementer(s): Chambers, Jordan [jordandchambers at gmail.com];
Search NeuronDB for information about:  I Na,p; I Na,t; I K,leak; I K,Ca; I CAN; I Mixed; I Na, leak; Ca pump;
TITLE nav13
: Na current 
: modified from Jeff Magee. M.Migliore may97
: added sh to account for higher threshold M.Migliore, Apr.2002

NEURON {
	SUFFIX nav13
	USEION na READ ena WRITE ina
	RANGE  gbar, ar2, sh, thegna, jina13
	GLOBAL minf, hinf, mtau, htau, sinf, taus,qinf, thinf
	THREADSAFE minf, hinf, mtau, htau, sinf, taus,qinf, thinf
}

PARAMETER {
	sh   = 8	(mV)
	gbar = 1e-1   	(mho/cm2)	
								
	tha  =  -37.5	(mV)		: v 1/2 for act	
	qa   = 4.5	(mV)		: act slope (4.5)		
	Ra   = 0.4	(/ms)		: open (v)		
	Rb   = 0.135 	(/ms)		: close (v)		

	thi1  = -30	(mV)		: v 1/2 for inact 	
	thi2  = -30 	(mV)		: v 1/2 for inact 	
	qd   = 1.5	(mV)	        : inact tau slope
	qg   = 1.5      (mV)
	mmin=0.02	
	hmin=0.5			
	q10=2
	Rg   = 0.01 	(/ms)		: inact recov (v) 	
	Rd   = 0.03 	(/ms)		: inact (v)	
	qq   = 10        (mV)
	tq   = -50      (mV)

	thinf  = -55 	(mV)		: inact inf slope	
	qinf  = 4 	(mV)		: inact inf slope 

        vhalfs=-60	(mV)		: slow inact.
        a0s=0.0003	(ms)		: a0s=b0s
        zetas=12	(1)
        gms=0.2		(1)
        smax=10		(ms)
        vvh=-58		(mV) 
        vvs=2		(mV)
        ar2=1		(1)		: 1=no inact., 0=max inact.
	ena		(mV)	
	Ena = 55	(mV)            : must be explicitly def. in hoc
	celsius
	v 		(mV)
	jina13 		(mA/cm2)
}


UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)
	(pS) = (picosiemens)
	(um) = (micron)
} 

ASSIGNED {
	ina 		(mA/cm2)
	thegna		(mho/cm2)
	minf 		
	hinf 		
	mtau 		(ms)	
	htau 		(ms) 	
	sinf 		(ms)	
	taus 		(ms)
}
 

STATE { m h s}

BREAKPOINT {
        SOLVE states METHOD cnexp
        thegna = gbar*m*m*m*h*s
	ina = thegna * (v - ena)
	jina13 = ina
} 

INITIAL {
	trates(v,ar2,sh)
	m=minf  
	h=hinf
	s=sinf
}


FUNCTION alpv(v(mV)) {
        alpv = 1/(1+exp((v-vvh-sh)/vvs))
}
        
FUNCTION alps(v(mV)) {  
  	alps = exp(1.e-3*zetas*(v-vhalfs-sh)*9.648e4/(8.315*(273.16+celsius)))
}

FUNCTION bets(v(mV)) {
  	bets = exp(1.e-3*zetas*gms*(v-vhalfs-sh)*9.648e4/(8.315*(273.16+celsius)))
}

LOCAL mexp, hexp, sexp

DERIVATIVE states {   
        trates(v,ar2,sh)      
        m' = (minf-m)/mtau
        h' = (hinf-h)/htau
        s' = (sinf - s)/taus
}

PROCEDURE trates(vm,a2,sh2) {  
        LOCAL  a, b, c, qt
        qt=q10^((celsius-24)/10)
	a = trap0(vm,tha+sh2,Ra,qa)
	b = trap0(-vm,-tha-sh2,Rb,qa)
	mtau = 1/(a+b)/qt
        if (mtau<mmin) {mtau=mmin}
	minf = a/(a+b)

	a = trap0(vm,thi1,Rd,qd) : +sh2 raus
	b = trap0(-vm,-thi2,Rg,qg) : - sh2 raus
	htau =  1/(a+b)/qt
        if (htau<hmin) {htau=hmin}
	hinf = 1/(1+exp((vm-thinf)/qinf)): -sh2 raus
	c=alpv(vm)
        sinf = c+a2*(1-c)
        taus = bets(vm)/(a0s*(1+alps(vm)))
        if (taus<smax) {taus=smax}
}

FUNCTION trap0(v,th,a,q) {
	if (fabs(v-th) > 1e-6) {
	        trap0 = a * (v - th) / (1 - exp(-(v - th)/q))
	} else {
	        trap0 = a * q
 	}
}	

Loading data, please wait...