Pyramidal neuron, fast, regular, and irregular spiking interneurons (Konstantoudaki et al 2014)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:168310
This is a model network of prefrontal cortical microcircuit based primarily on rodent data. It includes 16 pyramidal model neurons, 2 fast spiking interneuron models, 1 regular spiking interneuron model and 1 irregular spiking interneuron model. The goal of the paper was to use this model network to determine the role of specific interneuron subtypes in persistent activity
Reference:
1 . Konstantoudaki X, Papoutsi A, Chalkiadaki K, Poirazi P, Sidiropoulou K (2014) Modulatory effects of inhibition on persistent activity in a cortical microcircuit model. Front Neural Circuits 8:7 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Realistic Network; Neuron or other electrically excitable cell;
Brain Region(s)/Organism:
Cell Type(s): Neocortex fast spiking (FS) interneuron; Neocortex spiking regular (RS) neuron; Neocortex spiking low threshold (LTS) neuron; Neocortex spiking irregular interneuron;
Channel(s): I Na,p; I Na,t; I L high threshold; I T low threshold; I A; I K; I h; I_Ks; I_KD;
Gap Junctions:
Receptor(s): GabaA; GabaB; AMPA; NMDA;
Gene(s):
Transmitter(s): Gaba; Glutamate;
Simulation Environment: NEURON;
Model Concept(s): Activity Patterns; Synchronization; Active Dendrites;
Implementer(s): Sidiropoulou, Kyriaki [sidirop at imbb.forth.gr]; Konstantoudaki, Xanthippi [xeniakons at gmail.com];
Search NeuronDB for information about:  GabaA; GabaB; AMPA; NMDA; I Na,p; I Na,t; I L high threshold; I T low threshold; I A; I K; I h; I_Ks; I_KD; Gaba; Glutamate;
/
KonstantoudakiEtAl2014
experiment
data
ampa.mod *
ampain.mod *
cadyn.mod *
cadynin.mod *
cal.mod *
calc.mod *
calcb.mod *
can.mod *
cancr.mod *
canin.mod *
car.mod *
cat.mod *
catcb.mod *
gabaa.mod *
gabaain.mod *
gabab.mod *
h.mod *
hcb.mod *
hin.mod *
ican.mod *
iccb.mod *
iccr.mod *
icin.mod *
iks.mod *
ikscb.mod *
ikscr.mod *
iksin.mod *
kadist.mod *
kadistcr.mod *
kadistin.mod *
kaprox.mod *
kaproxcb.mod *
kaproxin.mod *
kca.mod *
kcain.mod *
kct.mod *
kctin.mod *
kdr.mod *
kdrcb.mod *
kdrcr.mod *
kdrin.mod *
naf.mod *
nafcb.mod *
nafcr.mod *
nafin.mod *
nafx.mod *
nap.mod *
netstim.mod *
NMDA.mod *
NMDAIN.mod *
sinclamp.mod *
cb.hoc
cr.hoc
ExperimentControl.hoc *
final.hoc
incell.hoc
net.hoc
pfc_pc_temp.hoc
run
run_orig
                            


NEURON	{ 
  ARTIFICIAL_CELL NetStim1
  RANGE y
  RANGE interval, number, start
  RANGE noise, burstP


}

PARAMETER {
	interval	= 10 (ms) <1e-9,1e9>: time between spikes (msec)
	number 		= 10
        start		= 100 (ms)	: start of first spike
	noise		= 0 <0,1>	: amount of randomeaness (0.0 - 1.0)
	burstP		= 100 (ms)      : period of bursts or recursive events

}

ASSIGNED {
	y
	event (ms)
	on
	end (ms)
}

PROCEDURE seed(x) {
	set_seed(x)
}

INITIAL {
	on = 0
	y = 0
:	i = 0
	if (noise < 0) {
		noise = 0
	}
	if (noise > 1) {
		noise = 1
	}
	if (start >= 0 && number > 0) {
		: randomize the first spike so on average it occurs at
		: start + noise*interval
		event = start + invl(interval) - interval*(1. - noise)
		: but not earlier than 0
		if (event < 0) {
			event = 0
		}

		net_send(event, 3)
		net_send(event + burstP, 3)
		
		
	}
	
}
PROCEDURE init_sequence(t(ms)) { 
	if (number > 0) {
		on = 1
		event = t
		end = t + 1e-6 + invl(interval)*(number-1)
	}
}

FUNCTION invl(mean (ms)) (ms) {
	if (mean <= 0.) {
		mean = .01 (ms) : I would worry if it were 0.
	}
	if (noise == 0) {
		invl = mean
	}else{
		invl = (1. - noise)*mean + noise*mean*exprand(1)
	}
}

PROCEDURE event_time() {
	if (number > 0) {
		event = event + invl(interval)
	}
	if (event > end) {
		on = 0
	}
}

NET_RECEIVE (w) {
	if (flag == 0) { : external event
		if (w > 0 && on == 0) { : turn on spike sequence
			init_sequence(t)
			net_send(0, 1)
		}else if (w < 0 && on == 1) { : turn off spiking
			on = 0
		}
	}
	if (flag == 3) { : from INITIAL
		if (on == 0) {
			init_sequence(t)
			net_send(0, 1)
		}
	}
	if (flag == 1 && on == 1) {
		y = 2
		net_event(t)
		event_time()
		if (on == 1) {
			net_send(event - t, 1)
		}
		net_send(.1, 2)
	}
	if (flag == 2) {
		y = 0
	}
}

COMMENT
Presynaptic spike generator
---------------------------

This mechanism has been written to be able to use synapses in a single
neuron receiving various types of presynaptic trains.  This is a "fake"
presynaptic compartment containing a spike generator.  The trains
of spikes can be either periodic or noisy (Poisson-distributed)

Parameters;
   noise: 	between 0 (no noise-periodic) and 1 (fully noisy)
   interval: 	mean time between spikes (ms)
   number: 	mean number of spikes

Written by Z. Mainen, modified by A. Destexhe, The Salk Institute

Modified by Michael Hines for use with CVode
The intrinsic bursting parameters have been removed since
generators can stimulate other generators to create complicated bursting
patterns with independent statistics (see below)

Modified by Michael Hines to use logical event style with NET_RECEIVE
This stimulator can also be triggered by an input event.
If the stimulator is in the on=0 state and receives a positive weight
event, then the stimulator changes to the on=1 state and goes through
its entire spike sequence before changing to the on=0 state. During
that time it ignores any positive weight events. If, in the on=1 state,
the stimulator receives a negative weight event, the stimulator will
change to the off state. In the off state, it will ignore negative weight
events. A change to the on state immediately fires the first spike of
its sequence.

ENDCOMMENT


Loading data, please wait...