CA1 pyramidal neuron (Combe et al 2018)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:244416
"Gamma oscillations are thought to play a role in learning and memory. Two distinct bands, slow (25-50 Hz) and fast (65-100 Hz) gamma, have been identified in area CA1 of the rodent hippocampus. Slow gamma is phase-locked to activity in area CA3 and presumably driven by the Schaffer collaterals. We used a combination of computational modeling and in vitro electrophysiology in hippocampal slices of male rats to test whether CA1 neurons responded to Schaffer collateral stimulation selectively at slow gamma frequencies, and to identify the mechanisms involved. Both approaches demonstrated that in response to temporally precise input at Schaffer collaterals, CA1 pyramidal neurons fire preferentially in the slow gamma range regardless of whether the input is at fast or slow gamma frequencies, suggesting frequency selectivity in CA1 output with respect to CA3 input. In addition, phase-locking, assessed by the vector strength, was more precise for slow gamma than fast gamma input. ..."
Reference:
1 . Combe CL, Canavier CC, Gasparini S (2018) Intrinsic Mechanisms of Frequency Selectivity in the Proximal Dendrites of CA1 Pyramidal Neurons. J Neurosci 38:8110-8127 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Hippocampus;
Cell Type(s): Hippocampus CA1 pyramidal GLU cell;
Channel(s): I Na,p; I Na,t; I L high threshold; I T low threshold; I A; I K; I M; I h; I K,Ca; I Calcium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Gamma oscillations;
Implementer(s): Canavier, CC;
Search NeuronDB for information about:  Hippocampus CA1 pyramidal GLU cell; I Na,p; I Na,t; I L high threshold; I T low threshold; I A; I K; I M; I h; I K,Ca; I Calcium;
/
CombeEtAl2018
experiment
lib
pc2b
template
readme.html
cad.mod
cagk.mod
cal.mod *
calH.mod
car.mod
cat.mod
d3.mod *
exp2i.mod *
h.mod
kadist.mod
kaprox.mod
kca.mod
kcasimple.mod
kdr.mod
km.mod
na3.mod
na3dend.mod
na3notrunk.mod
nap.mod
nax.mod
netstims.mod
nmdanet.mod
somacar.mod
stim2.mod *
cell-setup.hoc
fixnseg.hoc
init.hoc
mosinit.hoc *
multisyn.hoc
print.ses
screenshot1.png
screenshot2.png
screenshot3.png
screenshot4.png
simplestim.hoc
trunk.ses
                            
TITLE Slow Ca-dependent potassium current
                            :
                            :   Ca++ dependent K+ current IC responsible for slow AHP
                            :   Differential equations
                            :
                            :   Model based on a first order kinetic scheme
                            :
                            :       + n cai <->     (alpha,beta)
                            :
                            :   Following this model, the activation fct will be half-activated at 
                            :   a concentration of Cai = (beta/alpha)^(1/n) = cac (parameter)
                            :
                            :   The mod file is here written for the case n=2 (2 binding sites)
                            :   ---------------------------------------------
                            :
                            :   This current models the "slow" IK[Ca] (IAHP): 
                            :      - potassium current
                            :      - activated by intracellular calcium
                            :      - NOT voltage dependent
                            :
                            :   A minimal value for the time constant has been added
                            :
                            :   Ref: Destexhe et al., J. Neurophysiology 72: 803-818, 1994.
                            :   See also: http://www.cnl.salk.edu/~alain , http://cns.fmed.ulaval.ca
                            :   modifications by Yiota Poirazi 2001 (poirazi@LNC.usc.edu)
			    :   taumin = 0.5 ms instead of 0.1 ms	

                            NEURON {
                                    SUFFIX kca
                                    USEION k READ ek WRITE ik
                                    USEION ca READ cai
                                    RANGE cac, gk, gbar, m_inf, tau_m,ik
                                    GLOBAL beta
                            }


                            UNITS {
                                    (mA) = (milliamp)
                                    (mV) = (millivolt)
                                    (molar) = (1/liter)
                                    (mM) = (millimolar)
                            }


                            PARAMETER {
                                    v               (mV)
                                    celsius = 36    (degC)
                                    ek      = -80   (mV)
                                    cai     = 2.4e-5 (mM)           : initial [Ca]i
                                    gbar    = 0.01   (mho/cm2)
                                    beta    = 0.03   (1/ms)          : backward rate constant
                                    cac     = 0.025  (mM)            : middle point of activation fct
       				    taumin  = 5    (ms)            : minimal value of the time cst
                                    gk
                                  }


                            STATE {m}        : activation variable to be solved in the DEs       

                            ASSIGNED {       : parameters needed to solve DE 
                                    ik      (mA/cm2)
                                    m_inf
                                    tau_m   (ms)
                                    tadj
                            }
                            BREAKPOINT { 
                                    SOLVE states METHOD derivimplicit
                                    gk = gbar*m*m*m     : maximum channel conductance
                                    ik = gk*(v - ek)    : potassium current induced by this channel
                            }

                            DERIVATIVE states { 
                                    evaluate_fct(v,cai)
                                   m' = (m_inf - m) / tau_m
                            }

                            UNITSOFF
                            INITIAL {
                            :
                            :  activation kinetics are assumed to be at 22 deg. C
                            :  Q10 is assumed to be 3
                            :
                                    tadj = 3 ^ ((celsius-22.0)/10) : temperature-dependent adjastment factor
                                    evaluate_fct(v,cai)
                                    m = m_inf
                            }

                            PROCEDURE evaluate_fct(v(mV),cai(mM)) {  LOCAL car
                                    car = (cai/cac)^2
                                    m_inf = car / ( 1 + car )      : activation steady state value
                                    tau_m =  1 / beta / (1 + car) / tadj
                                    if(tau_m < taumin) { tau_m = taumin }   : activation min value of time cst
                            }
                            UNITSON

Loading data, please wait...