Determinants of the intracellular and extracellular waveforms in DA neurons (Lopez-Jury et al 2018)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:244599
To systematically address the contribution of AIS, dendritic and somatic compartments to shaping the two-component action potentials (APs), we modeled APs of male mouse and rat dopaminergic neurons. A parsimonious two-domain model, with high (AIS) and lower (dendro-somatic) Na+ conductance, reproduced the notch in the temporal derivatives, but not in the extracellular APs, regardless of morphology. The notch was only revealed when somatic active currents were reduced, constraining the model to three domains. Thus, an initial AIS spike is followed by an actively generated spike by the axon-bearing dendrite (ABD), in turn followed mostly passively by the soma. Larger AISs and thinner ABD (but not soma-to-AIS distance) accentuate the AIS component.
Reference:
1 . López-Jury L, Meza RC, Brown MTC, Henny P, Canavier CC (2018) Morphological and Biophysical Determinants of the Intracellular and Extracellular Waveforms in Nigral Dopaminergic Neurons: A Computational Study. J Neurosci 38:8295-8310 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Extracellular; Dendrite; Neuron or other electrically excitable cell;
Brain Region(s)/Organism: Basal ganglia;
Cell Type(s): Substantia nigra pars compacta DA cell;
Channel(s): I Calcium; I K,Ca; Na/K pump; I L high threshold; I T low threshold; I A; I N; I Na,t; I K;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Action Potential Initiation; Pacemaking mechanism; Temporal Pattern Generation; Oscillations; Extracellular Fields;
Implementer(s): Lopez-Jury, Luciana [lucianalopezjury at gmail.com]; Canavier, CC;
Search NeuronDB for information about:  Substantia nigra pars compacta DA cell; I Na,t; I L high threshold; I N; I T low threshold; I A; I K; I K,Ca; I Calcium; Na/K pump;
/
DAnotch_AIS
images
README.html
cabal.mod *
nabalan.mod *
newcachan.mod *
newkca.mod *
newleak.mod
pump.mod *
slowhh3.mod
xtra.mod
anatscale.hoc *
calcrxc.hoc
cellrig.ses
field.hoc *
fixnseg.hoc *
iclampc.ses
initxrec.hoc
interpxyz.hoc *
morph_mouse.hoc
morph_rat.hoc
mosinit.hoc
msgic.hoc
parameters.hoc
rigc.ses
setpointers.hoc *
varstep.ses
vrecc.ses
                            
: $Id: xtra.mod,v 1.4 2014/08/18 23:15:25 ted Exp ted $

COMMENT
This mechanism is intended to be used in conjunction 
with the extracellular mechanism.  Pointers specified 
at the hoc level must be used to connect the 
extracellular mechanism's e_extracellular and i_membrane 
to this mechanism's ex and im, respectively.

xtra does three useful things:

1. Serves as a target for Vector.play() to facilitate 
extracellular stimulation.  Assumes that one has initialized 
a Vector to hold the time sequence of the stimulus current.
This Vector is to be played into the GLOBAL variable is 
(GLOBAL so only one Vector.play() needs to be executed), 
which is multiplied by the RANGE variable rx ("transfer 
resistance between the stimulus electrode and the local 
node").  This product, called ex in this mechanism, is the 
extracellular potential at the local node, i.e. is used to 
drive local e_extracellular.

2. Reports the contribution of local i_membrane to the 
total signal that would be picked up by an extracellular 
recording electrode.  This is computed as the product of rx, 
i_membrane (called im in this mechanism), and the surface area 
of the local segment, and is reported as er.  The total 
extracellularly recorded potential is the sum of all er_xtra 
over all segments in all sections, and is to be computed at 
the hoc level, e.g. with code like

func fieldrec() { local sum
  sum = 0
  forall {
    if (ismembrane("xtra")) {
      for (x,0) sum += er_xtra(x)
    }
  }
  return sum
}

Bipolar recording, i.e. recording the difference in potential 
between two extracellular electrodes, can be achieved with no 
change to either this NMODL code or fieldrec(); the values of 
rx will reflect the difference between the potentials at the 
recording electrodes caused by the local membrane current, so 
some rx will be negative and others positive.  The same rx 
can be used for bipolar stimulation.

Multiple monopolar or bipolar extracellular recording and 
stimulation can be accommodated by changing this mod file to 
include additional rx, er, and is, and changing fieldrec() 
to a proc.

3. Allows local storage of xyz coordinates interpolated from 
the pt3d data.  These coordinates are used by hoc code that 
computes the transfer resistance that couples the membrane 
to extracellular stimulating and recording electrodes.


Prior to NEURON 5.5, the SOLVE statement in the BREAKPOINT block 
used METHOD cvode_t so that the adaptive integrators wouldn't miss 
the stimulus.  Otherwise, the BREAKPOINT block would have been called 
_after_ the integration step, rather than from within cvodes/ida, 
causing this mechanism to fail to deliver a stimulus current 
when the adaptive integrator is used.

With NEURON 5.5 and later, this mechanism abandons the BREAKPOINT 
block and uses the two new blocks BEFORE BREAKPOINT and  
AFTER SOLVE, like this--

BEFORE BREAKPOINT { : before each cy' = f(y,t) setup
  ex = is*rx*(1e6)
}
AFTER SOLVE { : after each solution step
  er = (10)*rx*im*area
}

This ensures that the stimulus potential is computed prior to the 
solution step, and that the recorded potential is computed after.
ENDCOMMENT

NEURON {
	SUFFIX xtra
	RANGE rx, er
	RANGE x, y, z
	GLOBAL is
	POINTER im, ex
}

PARAMETER {
	: default transfer resistance between stim electrodes and axon
	rx = 1 (megohm) : mV/nA
	x = 0 (1) : spatial coords
	y = 0 (1)
	z = 0 (1)
}

ASSIGNED {
	v (millivolts)
	is (milliamp)
	ex (millivolts)
	im (milliamp/cm2)
	er (microvolts)
	area (micron2)
}

INITIAL {
	ex = is*rx*(1e6)
	er = (10)*rx*im*area
: this demonstrates that area is known
: UNITSOFF
: printf("area = %f\n", area)
: UNITSON
}

: Use BREAKPOINT for NEURON 5.4 and earlier
: BREAKPOINT {
:	SOLVE f METHOD cvode_t
: }
:
: PROCEDURE f() {
:	: 1 mA * 1 megohm is 1000 volts
:	: but ex is in mV
:	ex = is*rx*(1e6)
:	er = (10)*rx*im*area
: }

: With NEURON 5.5 and later, abandon the BREAKPOINT block and PROCEDURE f(),
: and instead use BEFORE BREAKPOINT and AFTER SOLVE

BEFORE BREAKPOINT { : before each cy' = f(y,t) setup
  ex = is*rx*(1e6)
}
AFTER SOLVE { : after each solution step
  er = (10)*rx*im*area
}


Loading data, please wait...