Cerebellum Purkinje cell: dendritic ion channels activated by climbing fibre (Ait Ouares et al 2019)

 Download zip file   Auto-launch 
Help downloading and running models
Accession:244679
"In cerebellar Purkinje neuron (PN) dendrites, the transient depolarisation associated with a climbing fibre (CF) EPSP activates voltage-gated Ca2+ channels (VGCCs), voltage-gated K+ channels (VGKCs) and Ca2+ activated SK and BK K+ channels. The resulting membrane potential (Vm) and Ca2+ transients play a fundamental role in dendritic integration and synaptic plasticity of parallel fibre inputs. Here we report a detailed investigation of the kinetics of dendritic Ca2+ and K+ channels activated by CF-EPSPs, based on optical measurements of Vm and Ca2+ transients and on a single-compartment NEURON model reproducing experimental data. ... "
Reference:
1 . Ait Ouares K, Filipis L, Tzilivaki A, Poirazi P, Canepari M (2019) Two Distinct Sets of Ca2+ and K+ Channels Are Activated at Different Membrane Potentials by the Climbing Fiber Synaptic Potential in Purkinje Neuron Dendrites. J Neurosci 39:1969-1981 [PubMed]
Model Information (Click on a link to find other models with that property)
Model Type: Dendrite;
Brain Region(s)/Organism: Cerebellum;
Cell Type(s): Cerebellum Purkinje GABA cell;
Channel(s): I Calcium; I K,Ca; I Potassium;
Gap Junctions:
Receptor(s):
Gene(s):
Transmitter(s):
Simulation Environment: NEURON;
Model Concept(s): Simplified Models; Calcium dynamics; Active Dendrites;
Implementer(s): Filipis, Luiza [luizafilipu at gmail.com];
Search NeuronDB for information about:  Cerebellum Purkinje GABA cell; I K,Ca; I Calcium; I Potassium;
TITLE A current
 
COMMENT
A-type VGKC. Starting from the formulation of A-type VGKCs channels in De Schutter and Bower,
1994, the kinetic parameters were modified in line with modifications of T-type VGCCs to account for
behaviours at hyperpolarised states. The density was corrected at intermediate states to account
for partial inactivation.

    Current Model Reference: Karima Ait Ouares , Luiza Filipis , Alexandra Tzilivaki , Panayiota Poirazi , Marco Canepari (2018) Two distinct sets of Ca 2+ and K + channels 
are activated at different membrane potential by the climbing fibre synaptic potential in Purkinje neuron dendrites. 

PubMed link: 

Contact: Filipis Luiza (luiza.filipis@univ-grenoble-alpes.fr)
ENDCOMMENT
 
UNITS {
        (mA) = (milliamp)
        (mV) = (millivolt)
}
 
NEURON {
        SUFFIX KA1
	USEION k WRITE ik
        RANGE  gkbar, gk, minf, hinf, mexp, hexp, ik, vh1, vm1, vm2, t1,t2
} 
 
INDEPENDENT {t FROM 0 TO 1 WITH 1 (ms)}
 
PARAMETER {
        v (mV)
        celsius = 37 (degC)
        dt (ms)
        gkbar	= .015 (mho/cm2)
        ek	= -85 (mV)
	mon = 1
	hon = 1
    vh1=85 (mV)
    vm1 (mV)
    vm2 (mV)
    t1=0.3
    t2=50
}
 
STATE {
        m h
}
 
ASSIGNED {
        ik (mA/cm2)
        gk minf hinf mexp hexp 
}
 
BREAKPOINT {
        SOLVE states
        gk = gkbar *m*m*m* m*h 
	ik = gk* (v-ek)
}
 
UNITSOFF
 
INITIAL {
	rates(v,vm1,vm2)
	m = minf
	h = hinf
}

PROCEDURE states() {  :Computes state variables m, h
        rates(v,vm1,vm2)      :             at the current v and dt.
        m = mon * (m + mexp*(minf-m))
        h = hon * (h + hexp*(hinf-h))
}
 
PROCEDURE rates(v, vm1,vm2) {  :Computes rate and other constants at current v.
                      :Call once from HOC to initialize inf at resting v.
        LOCAL  q10, tinc, alpha, beta, sum
        
        q10 = 3^((celsius - 37)/10)
        tinc = -dt * q10
                :"m" potassium activation system
        alpha = 1.4/(1+exp((v+vm1)/(-12)))
        beta =  0.49/(1+exp((v+vm2)/4))
        sum = alpha + beta
        minf = (alpha/sum)*(1/(1+exp(-t1*(v+t2))))
        mexp = 1 - exp(tinc*sum)
                :"h" potassium inactivation system
        alpha = 0.0175/(1+exp((v+vh1)/8))
        beta = 1.3/(1+exp((v+13)/(-10)))
        sum = (alpha + beta)
        hinf = alpha/sum
       
        hexp = 1 - exp(tinc*sum)
}

 
UNITSON


Loading data, please wait...